Datensätze im DBGrid farbig hinterlegen!

[LuckyStrike4life]

Morgen,
Änderungswunsch in letzter Minute.

Die DBGrids meines Programmes geben die Hauptdatenbank wieder. Diese sind recht lang, da es viele Felder gibt. Ich lasse immer nur die relevanten Daten anzeigen.

Nun gut, ein Mitarbeiter wies mich darauf hin - es sei besser wenn man umgehend erkennen würde, ob ein Datensatz vom Chef angenommen bzw. abgelehnt wurde.

Nun meine Frage - und es ist wichtig für mich - gibt es eine Möglichkeit einzelne Datensätze eines DBGrids einzufärben (z.B. Hintergrund grün, oder schrift grün)? Und wenn ja, kann ich das abhängig machen von einer Spalte (d.h. wenn im Datensatz die Bestätigung "angenommen" bzw. "abgelehnt" steht)?

Ich glaube das geht nicht, zumindest wüsste ich nicht wie. Aber es wäre perfekt. Abgabe ist am Freitag, bis dahin muss ich eine gute Lösung haben.

[Robert_G]

OnDrawCell...

klick

[LuckyStrike4life]

Zitat von GeorgeWNewbie:

OnDrawCell...

klick

Danke,
allerdings geht es nicht um einen StringGrid sondern DBGrid, der DBGrid hat das Ereignis OnDrawCell nicht, sondern nur OnDrawColumnCell und OnDrawDataCell.

Gehts trotzdem? Und wenn ja, welches Ereignis soll ich wählen?
Edit:
Vermutlich ColumnCell, sollte dann ja die ganze Spalte einfärben... .

[Memo]

Zitat von LuckyStrike4life:

OnDrawColumnCell

Da könntest du mit Canvas.Font.Color rumspielen.

[Robert_G]

Einfach mal im OI in das Event klicken und die Zaubertaste drücken...

Zitat von Delphi OH:

Note: If the Columns property has a State property of csDefault, the OnDrawDataCell event occurs before the OnDrawColumnCell. The OnDrawDataCell event is obsolete, and only included for backward compatibility. Do not set both an OnDrawDataCell event handler and an OnDrawColumnCell event handler.

Kleines Beispiel:
Es färbt eine Spalte rot. Ausgewählte Zellen dieser Spalte sind orange.

Delphi-Quellcode:

  With DBGrid1.Canvas Do
  Begin
    If Column.Index = 2 Then
    Begin
      If gdSelected In state Then
        Brush.Color := $000080FF
      Else
        Brush.Color := clRed;
    End
    Else
    Begin
      If gdSelected In state Then
        Brush.Color := $00EFD3C6
      Else
        Brush.Color := clWhite;
    End;
    Font.Color := clBlack;
  End;

  DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, state);

Nachtrag:
Ich hatte mich verguckt und OnDrawDataCell benutzt -> korrigiert.
Ausrede: Ich benutze kein DBGrid

[LuckyStrike4life]

Okay,
verstehe... .
Dein Beispielcode Hinterlegt eine Spalte des Grids - ja nach dem Column.Index.
Aber wie könnte man jetzt eine Zeile farbig hinterlegen?

Und das müsste man ja noch von einem Feld der jeweiligen Spalte (Datensatz) abhängig machen.

[eddy]

Hallo LuckyStrike4life,

nachfolgender Code wird von mir in ähnlicher Form genutzt und funktioniert:

Code:

{
In einem DBGrid soll die Hintergrund- und Schriftfarbe in den Zeilen in Abhängigkeit eines Zellwertes unter Nutzung von OnDrawColumnCell geändert. 

Beispiel: 

wenn Feldx den Text 'SUMME' enthält, dann zeichne diese Zeile mit gelber Schrift auf blauen Grund, wenn diese Zeile aber die aktuelle ist, dann verwende die Standardfarben
}
 
procedure TFAuf.dbg32DrawColumnCell(Sender: TObject; const Rect: TRect; 
  DataCol: Integer; Column: TColumn; State: TGridDrawState); 
const 
  parr : array[0..2] of string =(cRAB, cZSM, cA); 
var 
  s : string; 
begin 
  // die zelle ist markiert und/oder selektiert 
  // dann sollen die Standard-Farben verwendet werden (weiß auf navy) 
  if (gdSelected in State) or (gdFocused in State) then exit; 

  { ansonsten soll die Farbe in Abhängigkeit eines Strings der    
    angezeigten Datenbank geändert werden 
    Hinweis: die Farben sind hier nur zu Testzwecken ohne Rücksicht 
             darauf, ob sie zueinander passen, frei gewählt worden} 
  s := TabPP.FieldByName('PosArt').AsString; 
  // Number of String - ermöglicht case-Auswertung von Strings 
  // -1, wenn s nicht in Array vorhanden ist sonst 0 für's Erste, usw. 
  case NofStr(s, parr) of 
     0:  begin 
           dbg32.Canvas.Brush.Color := clBlue; 
           dbg32.Canvas.Font.Color := clYellow; 
         end; 
     1:  begin 
           dbg32.Canvas.Brush.Color := clRed; 
           dbg32.Canvas.Font.Color := clAqua; 
         end; 
     2:  if TabPP.FieldByName('SummenKopf').AsBoolean then begin 
           dbg32.Canvas.Brush.Color := clGreen; 
         end; 
   end; 
  dbg32.DefaultDrawColumnCell(Rect, DataCol, Column, State); 
end; 

{liefert 0 ... n zurück, wenn s in sarr gefunden wurde, -1, wenn nicht}
function NofStr( s : string; sarr : array of string) : integer;
var
  erg, i : integer;
begin
  erg := -1;
  s := uppercase(s);
  for i := 0 to high(sarr) do begin
    if s = uppercase(sarr[i]) then begin
      erg := i;
      break;
    end;
  end;
  Result := erg;
end;

Wie Du die Auswahl triffst, welche Zeile wie gefärbt werden soll, bleibt Deinen Kriterien überlassen. Ich greife auf eine Colortabelle zu, die der Anwender nach seinen Wünschen definieren kann.

mfg
eddy

[LuckyStrike4life]

Danke Eddy,

ich hab dein Programmcode erstmal auf mein Beispielprogramm umgeschrieben.

Nur bei
  case NofStr (s, parr) of häng ich n wenig fest.
Delphi sagt zu der Zeile

Zitat:

[Fehler] Unit1.pas(50): Undefinierter Bezeichner: 'NofStr'

Nun gut,
als was soll man NofStr deklarieren? Angenommen ich mach n String draus, dann meint Delphi
[Fehler] Unit1.pas(51): Operator oder Semikolon fehlt und setzt den Zeiger zwischen ( und s.

[Treffnix]

NofStr ist eine Function und kein String. Steht doch mit in eddys Source.

Zitat:

Delphi-Quellcode:

[..]
{liefert 0 ... n zurück, wenn s in sarr gefunden wurde, -1, wenn nicht} 
function NofStr( s : string; sarr : array of string) : integer; 
var 
  erg, i : integer; 
begin 
  erg := -1; 
  s := uppercase(s); 
  for i := 0 to high(sarr) do begin 
    if s = uppercase(sarr[i]) then begin 
      erg := i; 
      break; 
    end; 
  end; 
  Result := erg; 
end;

Wenn du das so übernommen hast musst du die Function nur noch entweder im Interface-Teil deiner Unit Eintragen function NofStr( s : string; sarr : array of string) : integer; oder über die andere Funktion verschieben, in der der Aufruf stattfindet.

[Robert_G]

Hi LuckyStrike.
Die Funktion hatte Eddy hier schon einmal vorgestellt:
(im Zweifelsfall einfach die DP-Suche probieren...) Klick

Nachtrag:
Boah, das muss an dieser unmenschlich frühen Morgenstunde liegen ( ) -> die hatte ich im obenstehenden Code gar nicht gesehen.