String buchstabenweise in array einlesen

[s.h.a.r.k]

Es geht auch noch schneller Zeitersparnis ist je nach Stringlänge sehr hoch:

Delphi-Quellcode:

function StrToArray(Value: String): TCharArray;
var
  L : Integer;
begin
  L := Length(Value);
  SetLength(Result, L);
  if (L > 0) then
    Move(PChar(Value)^, Result[0], L * SizeOf(Char));
end;

Hier mal ein kleiner Benchmark (QuadCore Q6600):

Code:

Rounds: 10000000

Length: 21
naive: 2428ms
optimized: 1128ms
Time Saved: 54%

Length: 168
naive: 9179ms
optimized: 1831ms
Time Saved: 80%

Eine CountDiverseChars-Methode kommt auch bald

[basti2011]

Vielen Dank ich werds trotz eher geringem Verständnis einfach durchprobieren

[DeddyH]

Ich hatte das bewusst möglichst einfach gehalten, aber manche Egos scheinen einfach stärker zu sein

[Stevie]

Zitat von DeddyH:

Ich hatte das bewusst möglichst einfach gehalten, aber manche Egos scheinen einfach stärker zu sein

Hätte er Delphi 2010 oder höher könnte er auch das hier machen:

Delphi-Quellcode:

  ShowMessageFmt('"%s" kommt %d mal in "%s" vor', [Edit2.Text,
    TDelegateEnumerable<Char>.Create(
      procedure
      var
        c: Char;
      begin
        for c in Edit1.Text do Yield<Char>(c);
      end).Where(
    function(c: Char): Boolean
    begin
      Result := SameText(c, Edit2.Text);
    end).Count,
    Edit1.Text]);

Sorry, ich konnte nicht widerstehen.

[Luckie]

Also, wenn ihr ihn verwirren wollt, dann habt ihr das sehr wahrscheinlich mittlerweile geschafft.

[Stevie]

Zitat von Luckie:

Also, wenn ihr ihn verwirren wollt, dann habt ihr das sehr wahrscheinlich mittlerweile geschafft.

Du meinst dich, nicht ihn, oder?

Zitat von himitsu:

Nur noch Begin und End ersetzt und man hätte einen typischen C-Code

Pff, du erkennst ja nur nicht die Kapazität und Flexibilität dieses Codes

[himitsu]

Nur noch Begin und End ersetzt und man hätte einen typischen C-Code

[mkinzler]

Ihr seid schon komische Vögel, der Te offenbart, dass ihm das grundlegende Verständnis fehlt und ihr offenbart ihm eure "speziallösungen", die er bestimmt nicht versteht.

[DeddyH]

Meine Rede

[Blup]

Einfach an die Aufgabenstellung halten, offensichtlich soll der Umgang mit dyn. Array geübt werden:

Zitat:

Schreib ein Programm welches ein eingegebenes Wort buchstabenweise in ein dyn. Array einliest.

Delphi-Quellcode:

type
  TCharDynArray = array of Char;

function StringToDynArray(const AValue: string): TCharDynArray;
begin
  // Strings beginnen bei Index 1, Arrays bei 0   => wichtiges Lernziel
  SetLength(Result, Length(AValue));
  for i := 0 to Length(Result) - 1 do
    Result[i] := AValue[i + 1];
end;

Zitat:

Nach Eingabe eines Buchstabens soll ausgegeben werden wie oft dieser Buchstabe im eingegebenen Wort vorkommt.

Delphi-Quellcode:

// Array-Parameter immer als "const" oder "var" übergeben, sonst wird beim Funktionsaufruf eine Kopie angelegt
function GetBuchstabenAnzahl(const ACharDynArray: TCharDynArray; AValue: Char): Integer;
begin
  Result := 0;
  for i := 0 to Length(ACharDynArray) - 1 do
  begin
    if ACharDynArray[i] = AValue then
      Result := Result + 1;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  a: TCharDynArray;
  s: string;
  n: Integer;
begin
  // Text der durchsucht werden soll
  s := edit1.text;
  if Length(s) = 0 then
  begin
    MessageBox('Geben Sie einen Text an der durchsucht werden soll!', Caption);
    Exit;
  end;
  a := StringToDynArray(s);

  // Buchstabe der gesucht wird
  s := edit2.text;
  if Length(s) = 0 then
  begin
    MessageBox('Geben Sie einen Buchstaben an der gesucht werden soll!', Caption);
    Exit;
  end;
  
  if Length(s) > 1 then
  begin
    MessageBox('Geben Sie nur einen Buchstaben an der gesucht werden soll!', Caption);
    edit2.text := '';
    Exit;
  end;

  n := GetBuchstabenAnzahl(a, s[1]);
  s := Format('Der Buchstabe %s ist %d mal enthalten.', [s, n]);
  MessageBox(s, Caption);
end;