String buchstabenweise in array einlesen

[zeras]

Du musst dir irgendwo merken, wie oft ein Buchstabe vorgekommen ist. Dazu vielleicht ein Array definieren, welche sich die Anzahl merken kann. Dann ist noch zu klären, ob du Großbuchstaben anderst behandelst als Kleinbuchstaben.

Versuche es doch einmal so (nicht optimiert):

Delphi-Quellcode:

procedure TForm11.Button1Click(Sender: TObject);
var i,laenge :integer;
    wort :string;
    BS_array: array ['a'..'z'] of byte;
    c    : char;

begin
 wort := 'hallo';
 laenge := Length(wort);

 for c:=low(BS_array) to high(BS_array) do BS_array[c]:=0;


 For i := 1 to (laenge) do begin
   c := wort[i];
   BS_array[wort[i]] := BS_array[wort[i]] +1;
  end;
end;

[basti2011]

Also erstmal danke für die vielen Antworten,

Ich bin im ersten Jahr und benutze momentan Delphi 7.
Daher sind mir ziemlich viele Komponenten und funktionen die genannt wurden sehr unbekannt

Besonders mit den Begriffen - value, high , low - kann ich nicht wirklich was damit anfangen und es ist so dass ich momentan für einen Test lerne und dieses Beispiel zur Übung bekommen hab

Der genaue Aufgabenlaut wäre : Schreib ein Programm welches ein eingegebenes Wort buchstabenweise in ein dyn. Array einliest. Nach Eingabe eines Buchstabens soll ausgegeben werden wie oft dieser Buchstabe im eingegebenen Wort vorkommt.

Groß und klein Buchstaben ist vollkommen egal eigentlich es geht rein um die Funktionlität dessen was in der Angabe steht.

Also vielleicht ergibt sich noch ne "einfache" Lösungsmöglichkeit die im Grunde genommen nur ein dyn. Array, eine For - Schleife und eine Function für die Überprüfung behinhaltet , weil viel weiter sind wir mit dem Stoff nicht.

[DeddyH]

Delphi-Quellcode:

L := Length(String);
SetLength(Array, L);
for i := 1 to L do
  Array[i - 1] := String[i];

Strings beginnen mit dem Index 1, dynamische Arrays hingegen mit 0, daher muss im obigen Code von i 1 abgezogen werden. Zum Auswerten kannst Du ja dann ein statisches Array['A'..'Z']: of integer verwenden, mit 0 füllen und je Buchstaben bei Fund um 1 erhöhen. Das ist zwar immer noch case-sensitive, aber das bekommst Du schon hin, es gibt ja Wandlungsfunktionen

[s.h.a.r.k]

Es geht auch noch schneller Zeitersparnis ist je nach Stringlänge sehr hoch:

Delphi-Quellcode:

function StrToArray(Value: String): TCharArray;
var
  L : Integer;
begin
  L := Length(Value);
  SetLength(Result, L);
  if (L > 0) then
    Move(PChar(Value)^, Result[0], L * SizeOf(Char));
end;

Hier mal ein kleiner Benchmark (QuadCore Q6600):

Code:

Rounds: 10000000

Length: 21
naive: 2428ms
optimized: 1128ms
Time Saved: 54%

Length: 168
naive: 9179ms
optimized: 1831ms
Time Saved: 80%

Eine CountDiverseChars-Methode kommt auch bald

[basti2011]

Vielen Dank ich werds trotz eher geringem Verständnis einfach durchprobieren

[DeddyH]

Ich hatte das bewusst möglichst einfach gehalten, aber manche Egos scheinen einfach stärker zu sein

[Stevie]

Zitat von DeddyH:

Ich hatte das bewusst möglichst einfach gehalten, aber manche Egos scheinen einfach stärker zu sein

Hätte er Delphi 2010 oder höher könnte er auch das hier machen:

Delphi-Quellcode:

  ShowMessageFmt('"%s" kommt %d mal in "%s" vor', [Edit2.Text,
    TDelegateEnumerable<Char>.Create(
      procedure
      var
        c: Char;
      begin
        for c in Edit1.Text do Yield<Char>(c);
      end).Where(
    function(c: Char): Boolean
    begin
      Result := SameText(c, Edit2.Text);
    end).Count,
    Edit1.Text]);

Sorry, ich konnte nicht widerstehen.

[Bjoerk]

Vermutlich meint dein Lehrer lediglich das:

Delphi-Quellcode:

type
  TCharArray = array of Char;


function LowerCaseChar (const C: char): char;
begin
  Result:= C;
  if (Result in ['A'..'Z', 'Ä', 'Ö', 'Ü']) then
    Inc(Byte(Result), 32);
end;


function FindChar (const S: TCharArray; const C: char): integer;
var
  I: integer;
begin
  Result:= 0;

  for I:= 0 to Length(S)-1 do
    if S[I] = C then Inc(Result);
end;


procedure TForm1.Edit2Change(Sender: TObject);
var
  I, L1, L2, N: integer;
  C: char;
  S: TCharArray;
begin
  Label1.Caption:= '';

  L1:= Length(Edit1.Text);
  L2:= Length(Edit2.Text);

  if ((L1 > 0) and (L2 > 0)) then
  begin
    SetLength(S, L1);

    for I:= 1 to L1 do
      S[I-1]:= LowerCaseChar(Edit1.Text[I]);

    C:= LowerCaseChar(Edit2.Text[1]);

    N:= FindChar(S, C);
    Label1.Caption:= 'Buchstabe ' + C + ' kommt ' + IntToStr(N)+' mal vor.';

    SetLength(S, 0);
  end;
end;

[DeddyH]

Tragt nur ruhig ein wenig mehr zur Verwirrung bei, ich halte mich jetzt da raus.

[himitsu]

FillChar ist doch keine extreme Optimierung?

Und den Rest kann man sich aus jedem guten Delphi-Lehrbuch rausholen.

Gut, das For-In ist vielleicht neu und es geht nicht in vielen älternen Delphiversionen, aber zu Extremoptimiert würde ich auch das nicht zählen.

Zitat von zeras:

Versuche es doch einmal so (nicht optimiert):

Delphi-Quellcode:

procedure TForm11.Button1Click(Sender: TObject);
var i,laenge :integer;
    wort :string;
    BS_array: array ['a'..'z'] of byte;
    c    : char;

begin
 wort := 'hallo';
 laenge := Length(wort);

 for c:=low(BS_array) to high(BS_array) do BS_array[c]:=0;

 For i := 1 to (laenge) do begin
   c := wort[i];
   BS_array[wort[i]] := BS_array[wort[i]] +1;
  end;
end;

Wozu das C in der letzen Schleife, wenn es dann nicht genutzt wird?
Ich vermute mal du wolltest BS_array[c] := BS_array[c] +1; schreiben.

PS: gegenüber einiger anderer Codes hier ist mein Cod sogar fehlerunanfälliger.

z.B. das array ['a'..'z'] of byte; im gerade gezeigten Code kann zu einem Pufferüberlauf führen,
wenn in wort nicht nur Kleinebuchstaben von A bis Z vorkommen.
Schließlich ist fast immer die Index- und Bereichsprüfung deaktiviert.

Das Array[Char] ist beim Unicode zwar ein 1/4 MB groß, aber dafür liegen garantiert alle Zeichen irgendwo in dessen Bereich.