Hook führt zu System Exception

[s.h.a.r.k]

Ich habe gerade echt ein nettes Problem und habe keine Ahnung, warum dieses Problem auftritt. Ich habe ewig gebraucht um den Fehler zu finden, da er verzögert auftritt -- ich glaube, dass es zu dem Zeitpunkt statt findet, zum der Hook auf die erste Nachricht reagieren soll. So registriere ich den Hook:

Delphi-Quellcode:

procedure TMyHook.InstallMessageHook();
var
  Method: TMethod;
begin
  if (FHookHandle <> 0) then
    raise Exception.Create('Hook is already installed. Please uninstall hook first.');
  Method.Code := @TMyHook.HookProc;
  Method.Data := Self;
  FHookMethodPointer := MakeProcInstance(Method);
  FHookHandle := SetWindowsHookEx(WH_CALLWNDPROC, FHookMethodPointer, 0, GetCurrentThreadId());
  if (FHookHandle = 0) then
    RaiseLastOSError();
end;

function TMyHook.HookProc(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LResult; stdcall;
var
  P: PCWPStruct;
begin
  case nCode < HC_ACTION of
    True:
      Result := CallNextHookEx(FHookHandle, nCode, wParam, lParam);
  else
    if (lParam <> 0) and (Assigned(FParentForm)) and (Assigned(FChildForm)) then
    begin
      P := PCWPStruct(lParam);
      if (P.message in [WM_WINDOWPOSCHANGING, SW_MAXIMIZE, SW_MINIMIZE]) and (P.hwnd = FParentForm.Handle) then
        ReadjustChildForm();
    end;
    Result := CallNextHookEx(FHookHandle, nCode, wParam, lParam);
  end;
end;

Ist daran schon etwas falsch? Ich sehe jedenfalls kein Problem. Wenn ich das Programm jedenfalls ausführe, dann endet es irgendwann in einer system exception und ich lande im CPU-Fenster der IDE. Ich glaube, dass das Problem mit WH_CALLWNDPROC zusammenhängt. Komisch ist aber, dass es früher funktioniert hat

Code:

---------------------------
Benachrichtigung über Debugger-Problem
---------------------------
In Projekt C:\Users\Armin\Documents\RAD Studio\Projekte\tmp\HookDemo\Project1.exe trat ein Problem mit folgender Meldung auf: 'system exception (code 0xc000041d) at 0x72a64cad'. Prozess angehalten. Mit Einzelne Anweisung oder Start fortsetzen.
---------------------------
OK   
---------------------------

Vielleicht kennt jemand das Problem ja, oder hat Ideen -- ich bin um jede froh!

-- Edit: Anbei mal eine Demo.

[jaenicke]

Deine TMethod Variable ist lokal deklariert. Dennoch übergibst du deren Speicherbereich via MakeProcInstance an die Hookbehandlung. Vermute ich jedenfalls, oder was macht diese Funktion bei dir? Es gibt da auch welche mit diesem Namen, die Speicher reservieren, das würde natürlich gehen.

(Es gibt auch noch eine alte API-Funktion, die so heißt, aber die hat ja keinen Effekt mehr. Und die, die bei Delphi dabei ist, ignoriert den Instanzzeiger einfach soweit ich weiß.)

Andere Vermutung:
Je nach Umsetzung von MakeProcInstance fehlt vielleicht einfach der Zeiger auf Self, so dass deine Zugriffe auf die privaten Felder fehlschlagen.

// EDIT:
Ok, hab in das Archiv geschaut, da wird ja Speicher reserviert, das werde ich heute Abend mal anschauen. Das kann aber auch einfach am Betriebssystem oder am Antivirenprogramm liegen, da dort Code in den Speicher geschrieben und ausgeführt wird...

// EDIT2:
Die Exception kommt aus ShowWindow in der USER32.DLL, insofern ist das vermutlich genau die Stelle, an der der Hook drankommt, ja.

// EDIT3:
Jedenfalls liegt es daran, denn wenn man eine normale Prozedur nimmt, klappt es absolut problemlos.

[s.h.a.r.k]

Wie schon gesagt, es hatte ja schon mal funktioniert, daher bin ich im Moment etwas verwirrt. Diese MakeProcInstance Methoden habe ich mal aus dem Forum hier kopiert und daran eigentlich nie was geändert, jedenfalls nicht, dass ich wüsste. Ich muss mal schauen, ob es evtl. an dieser Methode liegt... Das erscheint mir im Moment echt das wahrscheinlichste.

[s.h.a.r.k]

Oh je... Ich habe jetzt mal etliches ausprobiert und bin auf des Rätsels Lösung gestoßen. Ich habe ein const bei dem Parameter für MakeProcInstance eingeführt gehabt und genau hier liegt das Problem. Ich hab hier mal die auskommentierte Version:

Delphi-Quellcode:

class function TApGeneral.MakeProcInstance({const} M: TMethod): Pointer;
begin
  // allocate memory
  GetMem(Result, 15);
  asm
    // MOV ECX,
    MOV BYTE PTR [EAX], $B9
    MOV ECX, M.Data
    MOV DWORD PTR [EAX+$1], ECX
    // POP EDX
    MOV BYTE PTR [EAX+$5], $5A
    // PUSH ECX
    MOV BYTE PTR [EAX+$6], $51
    // PUSH EDX
    MOV BYTE PTR [EAX+$7], $52
    // MOV ECX,
    MOV BYTE PTR [EAX+$8], $B9
    MOV ECX, M.Code
    MOV DWORD PTR [EAX+$9], ECX
    // JMP ECX
    MOV BYTE PTR [EAX+$D], $FF
    MOV BYTE PTR [EAX+$E], $E1
  end;
end;

Nur verstehe ich noch nicht so recht, warum das das Problem war, denn die Daten in M sind doch die gleichen...

[jaenicke]

Schau dir einfach einmal den generierten Assemblercode an.

Aber davon abgesehen verstehe ich auch nicht wirklich was da Assembler verloren hat. Sinnvoller wäre dort sowieso reiner Object Pascal Code, dann gibt es da auch keine solchen Probleme:

Delphi-Quellcode:

function MakeProcInstance(const M: TMethod): Pointer;
begin
  GetMem(Result, 7 + 2 * SizeOf(Pointer));
  PByte(Result)^ := $B9;
  Inc(PByte(Result));
  PPointer(Result)^ := M.Data;
  Inc(PPointer(Result));
  PLongInt(Result)^ := $B952515A;
  Inc(PLongInt(Result));
  PPointer(Result)^ := M.Code;
  Inc(PPointer(Result));
  PByte(Result)^ := $FF;
  Inc(PByte(Result));
  PByte(Result)^ := $E1;
  Dec(PByte(Result), 6 + 2 * SizeOf(Pointer));
end;

[s.h.a.r.k]

Bin nicht unbedingt der beste Freund von ASM, da ich auch nur kleine Teile davon bisher gelernt habe, somit fehlt mir der Überblick an sich. Hatte in Delphi auch noch nie eine Zeile in ASM gecodet

Habe daher den Code auch nie wirklich hinterfragt, sondern lediglich genutzt, da andere berichtet hatten, dass er funktioniert Sind diese "Konstanten" ($B9, $B952515A, $FF, $E1), die du da teilweise schreibst, eigentlich OpCodes?