Hook führt zu System Exception

[s.h.a.r.k]

Oh je... Ich habe jetzt mal etliches ausprobiert und bin auf des Rätsels Lösung gestoßen. Ich habe ein const bei dem Parameter für MakeProcInstance eingeführt gehabt und genau hier liegt das Problem. Ich hab hier mal die auskommentierte Version:

Delphi-Quellcode:

class function TApGeneral.MakeProcInstance({const} M: TMethod): Pointer;
begin
  // allocate memory
  GetMem(Result, 15);
  asm
    // MOV ECX,
    MOV BYTE PTR [EAX], $B9
    MOV ECX, M.Data
    MOV DWORD PTR [EAX+$1], ECX
    // POP EDX
    MOV BYTE PTR [EAX+$5], $5A
    // PUSH ECX
    MOV BYTE PTR [EAX+$6], $51
    // PUSH EDX
    MOV BYTE PTR [EAX+$7], $52
    // MOV ECX,
    MOV BYTE PTR [EAX+$8], $B9
    MOV ECX, M.Code
    MOV DWORD PTR [EAX+$9], ECX
    // JMP ECX
    MOV BYTE PTR [EAX+$D], $FF
    MOV BYTE PTR [EAX+$E], $E1
  end;
end;

Nur verstehe ich noch nicht so recht, warum das das Problem war, denn die Daten in M sind doch die gleichen...

[jaenicke]

Schau dir einfach einmal den generierten Assemblercode an.

Aber davon abgesehen verstehe ich auch nicht wirklich was da Assembler verloren hat. Sinnvoller wäre dort sowieso reiner Object Pascal Code, dann gibt es da auch keine solchen Probleme:

Delphi-Quellcode:

function MakeProcInstance(const M: TMethod): Pointer;
begin
  GetMem(Result, 7 + 2 * SizeOf(Pointer));
  PByte(Result)^ := $B9;
  Inc(PByte(Result));
  PPointer(Result)^ := M.Data;
  Inc(PPointer(Result));
  PLongInt(Result)^ := $B952515A;
  Inc(PLongInt(Result));
  PPointer(Result)^ := M.Code;
  Inc(PPointer(Result));
  PByte(Result)^ := $FF;
  Inc(PByte(Result));
  PByte(Result)^ := $E1;
  Dec(PByte(Result), 6 + 2 * SizeOf(Pointer));
end;

[s.h.a.r.k]

Bin nicht unbedingt der beste Freund von ASM, da ich auch nur kleine Teile davon bisher gelernt habe, somit fehlt mir der Überblick an sich. Hatte in Delphi auch noch nie eine Zeile in ASM gecodet

Habe daher den Code auch nie wirklich hinterfragt, sondern lediglich genutzt, da andere berichtet hatten, dass er funktioniert Sind diese "Konstanten" ($B9, $B952515A, $FF, $E1), die du da teilweise schreibst, eigentlich OpCodes?

[jaenicke]

Richtig, das sind Assemblerbefehle. Die werden an die neu reservierte Speicherstelle geschrieben, die dann als Prozedurpointer als Callback übergeben wird. Daraufhin wird dann beim Aufruf des Callbacks genau dieser Code ausgeführt.

// EDIT:
Die Befehle im Originalkommentar sind übrigens die Mnemonics zu den Befehlen, die da geschrieben werden, die hätte ich vielleicht wieder übernehmen sollen.

[s.h.a.r.k]

Zitat von jaenicke:

// EDIT:
Die Befehle im Originalkommentar sind übrigens die Mnemonics zu den Befehlen, die da geschrieben werden, die hätte ich vielleicht wieder übernehmen sollen.

Wie meinen?!

[jaenicke]

Mnemonics sind die für den Menschen lesbaren Befehle wie MOV oder ADD. Stattdessen wurden vorher die Zahlen direkt geschrieben, aber das war halt irgendwie unpraktisch. Deshalb wurden als Gedächtnisstützen (daher mnemonics) MOV, ADD usw. eingeführt, die der Assembler (also das Tool, das die übersetzt) erst in die entsprechenden Zahlen umwandelt.

[s.h.a.r.k]

Achso... ich habe dein Edit leicht falsch verstanden -- du meinstest ja nur die Kommentare Ich meinte, dass du was anderes für die Assemblerefehle schreiben wolltest.