Hilfestellung zu meinem Speicherleck

[DeddyH]

Zitat:

Delphi-Quellcode:

  finally
    sl := nil;
    sl.Free;
  end;

Überleg einmal, was Du hier machst. Selbst, wenn Du es umdrehst, bekommst Du Kummer, da ja dann Result freigegeben wurde. Mach besser aus der Funktion eine Prozedur, die die Stringliste als Parameter entgegennimmt und befüllt.

[delphinub23]

Das ist meine Routine, die die TStringlists (Global definiert und einmal Form.Create angelegt -- Form.Destroy zerstört diese auch wieder) benötigt.

Delphi-Quellcode:

procedure TFmMainModule.InitializeListview(const Processes: TStrings; const PIDs: TStrings; const Affinities: TStrings);
var
  Index: integer;
  i: Integer;
begin
  try
    lvProcessList.Items.BeginUpdate;
    try
      lvProcessList.Clear;
      ImageList.Clear;
      // reset TImageList index value
      Index := 0;

      // get processes
      ProcessInformation[0] := Processes;
      // pids
      ProcessInformation[1] := PIDs;
      // affinities
      ProcessInformation[2] := Affinities;
      // icons
      for i := 0 to Pred(ProcessInformation[0].Count) do
      begin
        SetExeIconToImageList(Imagelist, Index, StrToInt(PIDs.Strings[i]));
        Inc(Index);
      end;
    finally
      lvProcessList.Items.Count := ProcessInformation[0].Count;
      lvProcessList.AlphaSort;
      lvProcessList.Items.EndUpdate;
    end;
  except
    MessageDlg('Could not initialize application!', mtError, [mbOk], 0);
    Application.Terminate;
  end;
end;

@ DeddyH:

Zitat:

Zitat:

Delphi-Quellcode:

   finally
     sl := nil;
     sl.Free;
   end;

Wenn ich nur .Free rufe, dann bekomme ich eine Exception. Darum diese komische Variante

[DeddyH]

Und was hat das mit der oben geposteten Routine zu tun?

[delphinub23]

Na die obere Routine besorgt die Prozesse als TStringList. Die übergebe ich dann an eine weitere Funktion, die die Prozesse filtert (UserName).

Das Resultat übergebe ich dann an die zuletzt gepostete Routine.


Wieso verbraucht meine Applikation immer mehr Speicher?

[DeddyH]

Nochmal: GetAllRunningProcs erzeugt je Aufruf eine neue Instanz von TStringlist. Ich sehe aber nicht, wo diese wieder freigegeben wird. Daher mein Rat, die Liste außerhalb zu erzeugen und an die Routine zu übergeben, dann kannst Du sie auch wieder freigeben, da Du es nur mit einer Instanz zu tun hast.

[delphinub23]

Moment, ich kann dir gerade nicht folgen:

Meine erzeugte TStringList wird doch am Ende freigegeben, oder etwa nicht?

Delphi-Quellcode:

function TProcessHandler.GetAllRunningProcs: TStringList;
// returns all currently running processes
var
  s: string;
  sl: TStringList;
begin
  Result := nil;
  sl := TStringList.Create;   // <--- HIER erzeuge ich es...
  try
    hProcSnap := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
    if (hProcSnap <> INVALID_HANDLE_VALUE) then
    begin
      pe32.dwSize := SizeOf(ProcessEntry32);
      if (Process32First(hProcSnap, pe32)) then
      begin
        s := pe32.szExeFile;
        sl.Add(s);
        while Process32Next(hProcSnap, pe32) do
        begin
          s := pe32.szExeFile;
          sl.Add(s);
        end;
      end;
      Result := sl;
    end;
    CloseHandle(hProcSnap);
  finally
    sl := nil;  // <--- HIER &
    sl.Free;    // <--- HIER wird´s doch wieder gelöscht?
  end;
end;

[DeddyH]

Du setzt sie doch vorher auf nil, wie willst Du sie denn wieder freigeben? Wie gesagt, wenn Du die Befehle umdrehst zeigt Result dann nach dem Freigeben auf eine nicht mehr existente Instanz, das ist also auch nicht die Lösung. Versuch es doch einmal so:

Delphi-Quellcode:

procedure TProcessHandler.GetAllRunningProcs(ResultList: TStrings);
// returns all currently running processes
var
  s: string;
//  User: string;
begin
// User := GetEnvironmentVariable('USERNAME');
  if Assigned(ResultList) then
    begin
      ResultList.BeginUpdate;
      try
        ResultList.Clear;
        hProcSnap := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
        if (hProcSnap <> INVALID_HANDLE_VALUE) then
        begin
          pe32.dwSize := SizeOf(ProcessEntry32);
          if (Process32First(hProcSnap, pe32)) then
          begin
            s := pe32.szExeFile;
    // if GetUsernameByExeName(s) = User then
              ResultList.Add(s);
            while Process32Next(hProcSnap, pe32) do
            begin
              s := pe32.szExeFile;
    // if GetUsernameByExeName(s) = User then
                ResultList.Add(s);
            end;
          end;
        end;
        CloseHandle(hProcSnap);
      finally
        ResultList.EndUpdate;
      end;
    end;
end;

Der Prozedur übergibst Du dann einfach die zu füllende Stringliste.

[nuclearping]

Zitat von delphinub23:

@ DeddyH:

Zitat:

Zitat:

Delphi-Quellcode:

   finally
     sl := nil;
     sl.Free;
   end;

Wenn ich nur .Free rufe, dann bekomme ich eine Exception. Darum diese komische Variante

Du bekommst die Exception, weil du in der Funktion Result die TStringList sl zuweist. Result := sl. Result und sl sind damit das gleiche, das gleiche Objekt, der gleiche Speicher. Wenn du nun sl.Free machst, machst du auch gleichzeitig Result.Free und deswegen hats geknallt.

[DeddyH]

Korrekt, das hatte ich ja auch bereits 2 mal erklärt