Den Panel mit Pfeil-Tasten bewegen

[thomas2009]

Hallo

ich möchte einen Panel mit Pfeil Tasten bewegen

Delphi-Quellcode:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
if (Key = 39) then
    Panel1.Left:= Panel1.Left+10;

Keypreview ist schon auf true gesetzt aber passiert nichts !

Was passiert,durch das drücken auf Pfeiltasten, wechselt sicht das Fokus von Cotroll zu Controll!

woran kan das liegen ?

[s.h.a.r.k]

Klappt bei mir ohne Probleme.

[Matze]

Dann setze mal z.B. 2 Buttons aufs Formular. Schon geht es nicht mehr.
Ich weiß auf die Schnelle aber auch nicht, wie man die Fokusierung per Pfeiltasten ordentlich verhindert.

[thomas2009]

Ja sicher, wenn man den Code in einem ganzen leeren Projekt legt

Wenn Du aber RadioGroup auf Form danach legst dann funktioniert es nicht mehr :
Nehme diesen Code als Test :

Code:

object Form1: TForm1
  Left = 192
  Top = 114
  Width = 524
  Height = 365
  Caption = 'Form1'
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Sans Serif'
  Font.Style = []
  KeyPreview = True
  OldCreateOrder = False
  OnKeyDown = FormKeyDown
  PixelsPerInch = 96
  TextHeight = 13
  object Panel1: TPanel
    Left = 24
    Top = 24
    Width = 185
    Height = 81
    Caption = 'Panel1'
    TabOrder = 0
  end
  object RadioGroup1: TRadioGroup
    Left = 227
    Top = 16
    Width = 246
    Height = 206
    BiDiMode = bdLeftToRight
    Caption = 'RadioGroup1'
    Font.Charset = ANSI_CHARSET
    Font.Color = clWindowText
    Font.Height = -13
    Font.Name = 'Arial'
    Font.Style = []
    ItemIndex = 0
    Items.Strings = (
      '1'
      '2'
      '3'
      '4')
    ParentBiDiMode = False
    ParentFont = False
    TabOrder = 1
  end
end

[Matze]

Wenn die Anwendung nur für dich ist (das nehme ich an), könntest du von den Buttons etc. "TabStop" auf false setzen.
Eine Bedienung per Tabstop-Taste ist dann nicht mehr möglich. D.h. die Anwendung verhält sich nicht wie man es erwartet und ist somit für die "breite Masse" nicht geeignet.
Aber vielleicht reicht dir das schon aus.

[s.h.a.r.k]

Alternativ kannst du auch mal den Thread durchlesen, da ist u.A. die Lösung, die Matze gerade erwähnt hat, enthalten.

[Matze]

Ich habe auch was gefunden:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
  private
    { Private-Deklarationen }
    procedure CMDialogKey(var Msg: TWMKey); message CM_DIALOGKEY;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.CMDialogKey(var Msg: TWMKEY);
var
  handled: Boolean;
begin
  handled := true;

  case msg.charcode of
    VK_UP: Panel1.Top := Panel1.Top - 10;
    VK_DOWN: Panel1.Top := Panel1.Top + 10;
    VK_LEFT: Panel1.Left := Panel1.Left - 10;
    VK_RIGHT: Panel1.Left := Panel1.Left + 10;
  else
    handled := False
  end;

  if handled then
    msg.result := 1
  else
    inherited;
end;

end.