Text mit TResourceStream laden

[Luckie]

Ich habe gerade mal versucht eine Textdatei, die als Ressource eingebunden ist mit TResourceStream zu laden. Über die ID geht es wunderbar, nur über den Namen nicht.

Delphi-Quellcode:

{$R resource.res}

function LoadTextFromResourceByName(ResourceName: ansiString): AnsiString;
var
  ResourceStream: TResourceStream;
begin
  ResourceStream := TResourceStream.Create(HInstance, ResourceName, RT_RCDATA);
  try
    try
      SetLength(Result, ResourceStream.Size);
      ResourceStream.ReadBuffer(Result[1], ResourceStream.Size);
    except
      raise;
    end;
  finally
    ResourceStream.Free;
  end;
end;

function LoadTextFromResourceByID(ResourceID: Cardinal): AnsiString;
var
  ResourceStream: TResourceStream;
begin
  ResourceStream := TResourceStream.CreateFromID(HInstance, ResourceID, RT_RCDATA);
  try
    try
      SetLength(Result, ResourceStream.Size);
      ResourceStream.ReadBuffer(Result[1], ResourceStream.Size);
    except
      raise;
    end;
  finally
    ResourceStream.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    //Memo1.Text := LoadTextFromResourceByID(100);
    Memo1.Text := LoadTextFromResourceByName('ExcludeList');
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
end;

Code:

#define ExcludeList 100

ExcludeList RCDATA DISCARDABLE "exclude.lst"

Kann mir bitte jemand sagen, was ich da falsch mache?

Entwicklungsumgebung ist Delphi 7.

[DeddyH]

Ich mag mich täuschen, aber vermutlich deklarierst Du mit der define-Anweisung eine Konstante namens ExcludeList, welche beim Kompilieren durch 100 ersetzt wird.

[Satty67]

Ein Blick via ResourceExplorer in die Exe bestätigt das...

[Luckie]

Verfluchte Hacke. Das war es. Ich habe die Datei mit einem Ressourceneditor erzeugt und der hat mir die erste Zeile da reingeschrieben. Ich dachte, sie würde nicht weiter stören. Nehme ich sie raus, findet er sie über den Namen.

Danke, besten Dank.