XPath Abfrage im TXMLDocument: Probleme mit Namespace

[Der.faule.Christoph]

Hallo zusammen,

ich möchte mit einem TXMLDocument und XPath in einer XBLR Datei (XML) arbeiten. Leider hab ich da Probleme mit dem Namespace.
Die XPath abfragen funktionieren nicht >> http://www.futurelab.ch/xmlkurs/xpath.de.jsp
Mit Sketch-Pro (Demoversion) Allerdings schon. Hier habe ich auch Über die XMLNS alle aktiert.
Hier erst mal das XML:

Code:

<?xml  version="1.0"  encoding="utf-8"  ?>
<!--(c) XBRL Deutschland e.V. - see http://www.xbrl.de-->
<linkbase
 xmlns="http://www.xbrl.org/2003/linkbase"  xsi:schemaLocation="http://www.xbrl.org/2003/linkbase http://www.xbrl.org/2003/xbrl-linkbase-2003-12-31.xsd"  xmlns:de-gcd="http://www.xbrl.de/taxonomies/de-gcd-2010-02-19"  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"  xmlns:xlink="http://www.w3.org/1999/xlink" >
<roleRef xmlns:de-gcd="http://www.xbrl.de/taxonomies/de-gcd-2010-02-19"  xmlns:xlink="http://www.w3.org/1999/xlink"  roleURI="http://www.xbrl.de/taxonomies/de-gcd/role/gcd"  xlink:href="de-gcd-2010-12-16.xsd#role_gcd"  xlink:type="simple" />
<presentationLink xmlns:xlink="http://www.w3.org/1999/xlink"  xlink:role="http://www.xbrl.de/taxonomies/de-gcd/role/gcd"  xlink:type="extended" >
<loc xlink:type="locator"  xlink:href="de-gcd-2010-12-16.xsd#de-gcd_genInfo"  xlink:label="de-gcd_genInfo" />
<loc xlink:type="locator"  xlink:href="de-gcd-2010-12-16.xsd#de-gcd_genInfo.doc"  xlink:label="de-gcd_genInfo.doc" />
<loc xlink:type="locator"  xlink:href="de-gcd-2010-12-16.xsd#de-gcd_genInfo.doc.id"  xlink:label="de-gcd_genInfo.doc.id" />
<presentationArc xlink:from="de-gcd_genInfo"  xlink:to="de-gcd_genInfo.doc"  order="1"  use="optional"  xlink:arcrole="http://www.xbrl.org/2003/arcrole/parent-child"  xlink:type="arc" />
<presentationArc xlink:from="de-gcd_genInfo.doc"  xlink:to="de-gcd_genInfo.doc.id"  order="1"  use="optional"  xlink:arcrole="http://www.xbrl.org/2003/arcrole/parent-child"  xlink:type="arc" />
<presentationArc xlink:from="de-gcd_genInfo.doc.id"  xlink:to="de-gcd_genInfo.doc.id.generationDate"  order="1"  use="optional"  xlink:arcrole="http://www.xbrl.org/2003/arcrole/parent-child"  xlink:type="arc" />
</presentationLink>
</linkbase>

Hier der Delphi 2007 Code zum Abfragen:

Delphi-Quellcode:

var
  xmlReader: TXMLDocument;
  hList: IDOMNodeList;
  i: Integer;
begin
  xmlReader.LoadFromFile('de-gcd-2010-12-16-presentation_smal.xml');
  xmlReader.Active := true;
  hList := (xmlReader.DOMDocument as IDOMNodeSelect).selectNodes('//linkbase/presentationLink/presentationArc/@xlink:to');
  for i := 0 to hList.length - 1 do
    writeln(IntToStr(i) + '. ' +  hList.item[i].nodeName +' = '+  hList.item[i].nodeValue);

Und nun die XPath Abfragen:
1. Eine Liste mit allen presentationArc Elementen:
//presentationArc
Nix passiert. ich bekomme keine Ergebnisse.
2. Eine Liste mit allen Elementen die xlink:to als Attribut haben
//linkbase/presentationLink/presentationArc/@xlink:to
Fehlermeldung: Verweis auf ein nicht deklariertes Namespace-Präfix: 'xlink'

Ander Abfragen wiederum Funktionieren:
z.B.
//@*[name()="xlink:from"]
oder
//*

Ich habe schon mit xmlReader.DocumentElement.DeclareNamespace(sName, sURI); alle Namespaches Hinzugefügt aber leider ohne Erfolg.
Auch habe ich nach einem XmlNameSpaceMannager gesucht, aber keine verbindung zum TXMLDocument hinbekommen.
Sind meine XPath abfragen Falsch oder die Delphi Implementierung?
Was muss ich machen das auch die 1. und 2. Abfrage gelingt?

[Der.faule.Christoph]

Ich habe ein Lösung gefunden. Leider geht das ganze nicht direkt mit TXMLDocument. Zumindest nicht in meinem Delphi 2007. Es werden Interfache Funktionen gebraucht die erst mit IXMLDOMDocument2 dazukommen.

Da ich es nicht geschafft habe von einer TXMLDocument Instanz auf dessen TMSDOMDocument und dessen IXMLDOMDocument zu kommen (dann hätte ich eine QueryInterfache auf das IXMLDOMDocument2 machen können). Muss ich den Umweg über ein neues IXMLDOMDocument2 machen.

Also ein neues IXMLDOMDocument2 erzeugen und das XML aus der TXMLDocument Instanz einladen.
Dann frage ich alle im XML enthalten Namespace ab (selectNodes('//namespace::*')).
Denn um eine XPath Abfrage zu machen müssen alle externen Namespace Elemente dem XPath bekannt sein. Siehe hierzu die MSDN Remarks unter SelectionNamespaces Property

Also eine Namespaceliste für das SelectionNamespaces Property aufbauen und diese mit IXMLDOMDocument2 .setProperty setzten.

Dann klappt auch alles. Hier die Funktion:

Delphi-Quellcode:

function XPathQuery(aXmlDoc: TXMLDocument; aQuery: string): IXMLDOMNodeList;
var
  hList: IDOMNodeList;
  i: Integer;
  s, sNSN, sNSUri: string;
  sNsLine: string;
  hQueryDoc: IXMLDOMDocument2;
begin
  Result := nil;
  if not aXmlDoc.Active then
    exit;

  hList := (aXmlDoc.DOMDocument as IDOMNodeSelect).selectNodes('//namespace::*');
  try
    for i := 0 to hList.length - 1 do
    begin
      sNSN := StringReplace(hList.item[i].nodeName, 'xmlns:', '', []);
      if sNSN = 'xml' then
      begin  // wenn es als xmlns:xml hinzugefügt wird bekommt man die meldung das der Namespacename xml nicht verwendet werden darf...
        sNSN := 'xmlns:MyXml';
        sNSUri := hList.item[i].nodeValue;
      end
      else
      if sNSN = 'xmlns' then
      begin  // den Default Namespace mit einem Namen versehen, damit XPath drauf zugreifen kann.
        sNSN := 'xmlns:dn';
        sNSUri := hList.item[i].nodeValue;
      end
      else
      begin  // alle anderen Namespace auch für XPath bekannt machen
        sNSN := hList.item[i].nodeName;
        sNSUri := hList.item[i].nodeValue;
      end;
      s := sNSN + '="'+sNSUri+'"';
      if ContainsText(sNsLine, s) then
        continue;
      sNsLine := ' '+s + sNsLine;
    end;
    sNsLine := trim(sNsLine);
  finally
    hList := nil;
  end;

  hQueryDoc := CreateOleObject('MSXML2.DOMDocument.4.0') as IXMLDOMDocument2;
  try
    hQueryDoc.loadXML(aXmlDoc.XML.Text);
    hQueryDoc.setProperty('SelectionLanguage', 'XPath');  // ab 4.0 ist SelectionLanguage eh immer XPath
    hQueryDoc.setProperty('SelectionNamespaces', sNsLine) ;
    Result := hQueryDoc.selectNodes(aQuery);
  finally
    hQueryDoc := nil;
  end;
end;

Und die Beispiele, wichtig ist das der Default Namespace auch einen Namen bekommen hat. Das hat Einfluss auf den XPath Query:

Delphi-Quellcode:

XPathQuery(xmlReader, '//presentationArc');
//Funktioniert auch nicht, erst wenn die XPath Abfrage um den Default Namespace Namen erweitert wird kommt das gewünschte ergebnis raus:
XPathQuery(xmlReader, '//dn:presentationArc'); //geht!

XPathQuery(xmlReader, '//linkbase/presentationLink/presentationArc/@xlink:to'); //geht nicht
XPathQuery(xmlReader, '//dn:linkbase/dn:presentationLink/dn:presentationArc/@xlink:to'); //geht!