Dateinamen mit einem File Filter vergleichen

[Codehunter]

Jepp, vollkommen korrekt Gollum Hab mich nämlich auch gewundert dass mir der Code um die Ohren geflogen ist... Daneben habe ich noch ein paar Failsafes eingebaut für den Fall das lange Dateipfade als Filename übergeben werden (Da scheint MatchesMask allergisch zu sein) und auch für den Fall, dass der Filterstring nicht ganz sauber formuliert ist.

So schauts jetzt aus:

Delphi-Quellcode:

function dwMatchesFilter(const AFilename, AFilter: String): Boolean;
var
  I: Integer;
  SL: TStringList;
  S, FN: String;
begin
  result:= FALSE;
  FN:= ExtractFileName(AFilename);
  SL:= TStringList.Create;
  try
    SL.Text:= StringReplace(Trim(AFilter), '|', #13#10, [rfReplaceAll]);
    for I:= 0 to SL.Count - 1 do begin
      if I mod 2 <> 0 then begin
        S:= S + SL[I] + ';';
      end;
    end;
    while Pos(';;', S) > 0 do S:= StringReplace(S, ';;', ';', [rfReplaceAll]);
    SL.Text:= StringReplace(S, ';', #13#10, [rfReplaceAll]);
    for I:= 0 to SL.Count - 1 do begin
      S:= SL[I];
      if MatchesMask(FN, S) then begin
        result:= TRUE;
        Break;
      end;
    end;
  finally
    SL.Free;
  end;
end;

Allerdings passt die praktische Erfahrung hier nicht mit der Delphi-Hilfe zusammen, die bei "Exit" folgendes sagt:

Code:

Exit beschränkt sich nicht auf einen Block, sondern beendet die gesamte Prozedur. Exit beeinflusst die Ablaufsteuerung von try..finally-Blöcken nicht. Wenn Sie Exit in einem try..finally-Konstrukt aufrufen, wird die Ausführung in der finally-Klausel fortgesetzt.

Denn wie man hier sehen kann wird SL.Free im finally nicht aufgerufen obwohl es laut Hilfe so sein sollte.

[DeddyH]

Bist Du ganz sicher? Nach meinen Tests vor einiger Zeit wird das finally immer durchlaufen, sobald man das try betreten hat. Es würde mich wundern, wenn sich das geändert haben sollte.

[himitsu]

Zitat:

Die Routine erzeugt hier ein Speicherleck. Statt Exit dann schon eher ein Break oder Du musst die Stringlist an dieser Stelle separat freigeben.

Exit innerhalb eines Try-Finally löst eine "stille" Exception aus und springt damit direkt ins Finally (diese Exception wird dann im End; der Funktion/Prozedur zurückgesetzt).

Außerhalb von Try-Finally/Except ist Exit ein normaler Jump (GOTO) zum End der Prozedur.

[Maik81ftl]

gegenfrage an euch??? würde euch da ggf eine LCL-Routine ausreichen?

Wenn ja schaut mal bitte bei Lazarus-Crr da dies zu 95% mit delphi konform geht, wäre dies doch eine Sinnvolle alternative.

[himitsu]

Delphi-Quellcode:

uses Masks;

function MatchesFilter(const Filename, Filter: String): Boolean;
var
  SL: TStringList;
  i:  Integer;
begin
  SL := TStringList.Create;
  try
    SL.StrictDelimiter := True;
    SL.Delimiter := '|';
    SL.DelimitedText := Filter;
    for i := 0 to SL.Count div 2 - 1 do
      SL.Delete(i);
    SL.DelimitedText := ';';
    SL.Text := SL.Text;
    for i := SL.Count - 1 downto 0 do
      if MatchesMask(Filename, SL[i]) then
        Exit(True);
  finally
    SL.Free;
  end;
  Result := False;
end;

// oder um nocheine Zeile kürzer
function MatchesFilter(const Filename, Filter: String): Boolean;
var
  SL: TStringList;
  i:  Integer;
begin
  SL := TStringList.Create;
  try
    SL.LineBreak := '|';
    SL.Text := Filter;
    for i := 0 to SL.Count div 2 - 1 do
      SL.Delete(i);
    SL.LineBreak := ';';
    SL.Text := SL.Text;
    for i := SL.Count - 1 downto 0 do
      if MatchesMask(Filename, SL[i]) then
        Exit(True);
  finally
    SL.Free;
  end;
  Result := False;
end;

Statt Exit(True); kann man auch (für ältere Delphis) auf Folgendes ausweichen.

Delphi-Quellcode:

begin
  Result := True;
  Exit;
end;

PS: nicht getestet ... sollte aber gehn

PPS: In der CodeLb sollte von mir eine MaskMatch-Version rumliegen, welche speziell für Dateinamen vorgesehen ist,
denn "*.*" findet eigentlich auch "DateiOhneEndung", was Masks.MatchesMask nicht macht.

[Codehunter]

Um jetzt nochmal auf die Frage mit dem Try und dem Exit zurückzukommen:

Ich bin die Sache Step by Step via F8 durchgegangen. In der konkreten Funktion wird Finally tatsächlich NICHT angesprungen, in anderen Routinen meiner Programme bei ähnlicher Konstellation dagegen schon. Ich konnte noch nicht herausfinden wo es im konkreten Fall klemmt. Evtl. ist das auch ein Bug im Linker? Nichtsdestotrotz ist Break die bessere Lösung anstelle von Exit. "Exit(x)" ähnelt mehr dem C-Konstrukt "return x" und wurde von mir bisher nie verwendet. Ich weise immer Result das Ergebnis zu, der Übersicht wegen.

[himitsu]

Zitat von Codehunter:

"Exit(x)" ähnelt mehr dem C-Konstrukt "return x" und wurde von mir bisher nie verwendet.

Ist in Delphi 5 eh noch nicht vorhanden.