Kryptischer Fehler bei Split-Funktion

[Trogge]

Hallo,

ich habe ein Programm in Arbeit, an dessen Anfang einige Daten aus einer Textdatei eingelesen werden müssen. Die Trennung der einzelnen Informationen geschieht mithilfe der drei Trennzeichen ";" (erste Ebene), "," (zweite Ebene), " " (dritte Ebene).
Die Ebenen bedeuten, dass der String zuerst an den Semikola getrennt wird, die anschließend entstehenden Strings bei bedarf noch an den Kommta und die so entstandenden Strings falls notwendig noch an den Leerzeichen.
Meine Split-Funktion hat die folgende Gestalt:

Delphi-Quellcode:

function Split(Input: String; Delimiter: Char): TStringList;
var Strings : TStringList;
begin
   Strings := TStringList.Create; 
   Strings.Clear;
   Strings.Delimiter := Delimiter;
   Strings.DelimitedText := Input;
   result := Strings;
end;

Nun habe ich einen String s, den ich einlesen will, der folgendermaßen aussieht:

Code:

s = power;16,4;true;0;,;SetPower 0 false #1 true,SetFwd 0 false,On_ 0 false

(das "s = " ist nicht Teil des Strings, sondern dient hier nur zur Erläuterung)
Nach dem ersten Aufruf von Split ("Split(s,';')") müsste ich ja nun eigentlich eine StringList (sl) erhalten, die folgendermaßen aussieht:

Code:

sl[0] = power
sl[1] = 16,4
sl[2] = true
sl[3] = 0
sl[4] = ,
sl[5] = SetPower 0 false #1 true,SetFwd 0 false,On_ 0 false

Tatsächlich erhalte ich allerdings eine StringList, die so aussieht:

Code:

...
sl[4] = ,
sl[5] = SetPower
sl[6] = 0
sl[7] = false
sl[8] = #1
sl[9] = true,SetFwd
sl[10] = 0
sl[11] = false,On_
sl[12] = 0
1l[13] = false

Ich habe versucht, dass Trennzeichen " " durch "." zu ersetzen. Das Ergebnis bleibt das gleiche.
Hat jemand eine Idee, woher es kommt, das die Split-Funktion an anderer Stelle trennt, als sie soll?

Dank im voraus,

Trogge

[mkinzler]

Setzte mal StrictDelimiter auf True, sonst werden Leerzeichen als zusätzliche Trenner betrachtet

[DeddyH]

Ich persönlich bin kein Freund von Funktionsrückgabewerten in Form von Objekten, die innerhalb der Funktion instanziert werden, da man sich so der Gefahr von Speicherlecks aussetzt. Dürfte ich also folgende Änderung vorschlagen?

Delphi-Quellcode:

procedure Split(const Input: string; Delimiter: char; Output: TStrings);
begin
  if Assigned(Output) then
    begin
      Output.Delimiter := Delimiter;
      Output.StrictDelimiter := true;
      Output.DelimitedText := Input;
    end;
end;

TStringlist wurde zudem in TStrings geändert, um sich nicht unnötig einzuschränken.

[edit] Gerade einmal ausprobiert, das scheint ja ganz gut zu klappen

Delphi-Quellcode:

procedure TFrmTest.btnSplitClick(Sender: TObject);
const
  s = 'power;16,4;true;0;,;SetPower 0 false #1 true,SetFwd 0 false,On_ 0 false ';
var
  i: integer;
  sl: TStrings;
begin
  ListBox2.Items.Clear;
  ListBox3.Items.Clear;
  Split(s,';',ListBox1.Items);
  sl := TStringlist.Create;
  try
    for I := 0 to ListBox1.Items.Count - 1 do
      begin
        Split(ListBox1.Items[i],',',sl);
        ListBox2.Items.AddStrings(sl);
      end;
    for I := 0 to ListBox2.Items.Count - 1 do
      begin
        Split(ListBox2.Items[i],' ',sl);
        ListBox3.Items.AddStrings(sl);
      end;
  finally
    sl.Free;
  end;
end;

[/edit]

[Aphton]

Ach du meine Güte

Ich kannte die Eigenschaft "StrictDelimiter" noch garnicht. Hab letztens beim Projekt eines Freundes lange nach dem Problem gesucht - habs auch gefunden und hab mich gewundert, warum DelimitedText nicht NUR nach Delimiter trennt. Daher habe ich eine eigene DelimitText() Funktion für ihn gebastelt -.-'

Völlig umsonst =(

[Trogge]

Der Knackpunkt liegt als bei der Eigenschaft "StrictDelimiter"?
Alle restlichen Änderungen kann ich später einbauen, aber ich will erstmal das das Programm im Kern läuft.
Ich nehms mir aber zu Herzen.

Danke