[Gelöst] Aussortieren bei TList

[Edlmann]

Hey DP,

ich baue gerade ein kleines Minigame, bei dem man unter anderem schießen kann (Ja ich weiß, ziemlich kreativ ) und habe für die einzelnen Schüsse
eine Liste vom Typ TLIst erstellt, in welche ich Records mit den Daten von meinem Schuss schreibe. Soweit so gut, auslesen und alles funktioniert auch wunderbar,
das einzige was einfach nicht funktionieren will ist das aussortieren von Schüssen, die nicht mehr gezeichnet werden müssen. Momentan sieht meine Methode dafür
wie folgt aus:

Delphi-Quellcode:

procedure TPlayer.SortShots;
var x: Integer;   
  temp: PShot;
begin
  x := 0;
  while not x > Shots.Count -1 do
  begin
    temp := PShot(Shots.Items[x]);
     if temp.Timer <= 0 then
     begin
        Shots.Remove(temp);
        dispose(temP);
     end
     else
      inc(x);
  end;
end;

Was meiner Meinung nach funktionieren müsste. Shots ist meine TList, und der Typ PShot ist wie folgt deklariert:

Delphi-Quellcode:

type
  PShot = ^TShot;
  TShot = record
  X, Y: Single;
  MRot: Single;
  Timer: Integer;
end;

Allerdings bleibt die Länge meiner TList immer gleich hoch, egal ob ich sortieren lasse oder nicht, und darunter leidet die Performance auf Dauer.
Weiß jemand von euch warum das ganze nicht funktioniert?

Lg, Edlmann

[DeddyH]

Mir fällt erst einmal folgendes auf:

Zitat:

while not x > Shots.Count -1 do

Das sollte wohl
while not (x > Shots.Count -1) do heißen.

[edit] Verständlicher wird es IMHO so:

Delphi-Quellcode:

procedure TPlayer.SortShots;
var x: Integer;
  temp: PShot;
begin
  for x := Shots.Count -1 downto 0 do
  begin
    temp := PShot(Shots.Items[x]);
    if temp.Timer <= 0 then
    begin
      Shots.Remove(temp);
      dispose(temP);
    end;
  end;
end;

Wobei ich mich frage, was das mit Sortieren zu tun hat, das ist ja höchstens Aussortieren [/edit]

[Edlmann]

Mmh...mal wieder an den Tücken des Delphi-Compilers gescheitert ^^
Danke, mit der Klammer funktioniert alles so wie es soll und ich hab immer nur so 25 Schüsse.
Ich versteh zwar nicht ganz wie der Compiler dass ohne die Klammer interpretiert (muss ja
irgendwie anders sein, ansonsten würds ja funktionieren) aber naja, wieder was gelernt

Und ja, Aussortieren wäre passender, aber Sort is kürzer als Sortout

[DeddyH]

Das ist relativ schnell erklärt. x ist vom Typ integer mit Wert 0, sieht also binär so aus:

Code:

00000000000000000000000000000000

Du fragst aber ohne Klammer auf not x ab (sieht dann so aus):
while (not x) > Shots.Count - 1 do , was dann

Code:

11111111111111111111111111111111

ergibt. Als Integer ist das -1, das ist niemals größer als Shots.Count - 1

[Edlmann]

Macht Sinn, danke für die Erklärung

[mleyen]

Kurz: not x invertiert alle Bits von x.

Und KISS wo es nur geht.
not (x > Shots.Count -1) .
=> x <= Shots.Count-1 .
Dann spart man sich öfters solche Fehler.

[DeddyH]

Ich hätte ja
x < Shots.Count genommen *g*. Oder eher die absteigende For-Schleife wie oben beschrieben.

[Edlmann]

Mmmh...soweit hab ich noch nicht gedacht, hab mir halt gedacht
"ne For-Schleife kannst du ja nicht nehmen, denn wenn du ein Element löscht,
rücken die anderen nach" aber wenn mans Rückwärts macht gehts natürlich auch ^^
Da sich das von der Performance her aber nicht viel tut werde ich es so lassen wie ich es jetzt habe