Stored Procedure: Rückgabewert

[mkinzler]

Zitat:

@Markus:
Hätte das gegenüber obigen einen Vorteil oder ist es nur "anders"?

In diesem Fall nur anders.

Wg Tranaktionen:
Bei FireBird ist aber zu beachten, dass keine Transaktionslog verwendet wird, wie bei den meisten anderen DBMS, sondern Datensatzversionierung.
Deshalb ist diese auch bei/für nicht ändernde Vorgänge wichtig.

[tsteinmaurer]

Hallo Frederic,

dein Verständnis zu Transaktionen sind prinzipiell richtig. Das Ganze in Verbindung mit Firebird wäre jetzt eine etwas längere Geschichte, aber prinzipiell ist ein ständiges COMMIT RETAINING (eine spezielle Form von COMMIT, wo der Transaktionskontext erhalten bleibt) über eine längere Dauer für den Firebird Server nicht gut, weil hiermit das Fortschreiten der "Oldest Active Transaction" blockiert wird. Ich erwähne das deswegen, weil jeglicher AutoCommit Modus ein COMMIT RETAINING verwendet. Man muss dann schon mal von Zeit zu Zeit ein COMMIT anstatt von COMMIT RETAINING ausführen, damit man hier nicht in ein Performanceproblem reinläuft. Dazu am besten die Transaktions-Counter (ermittelbar über gstat -h oder Admin/Dev-Tool) im Auge behalten.

Gerade für deinen Anwendungsfall, wo es um das Anlegen eines Benutzers geht, würde ich eine explizit gestartete Transaktion vorziehen. Wer weiss, wer sonst noch die interne/implizite Transaktion der Connection in Verwendung hat. Ist sauberer und frei von Seiteneffekten, weil man hier mit der eigenen Transaktion alles selbst im Griff hat.

Was ich gerne mit AutoCommit verwende sind Datenmengen, die im Kontext einer ReadOnly-Transaktion geöffnet wurden, sofern die Datensätze nicht bearbeitet werden müssen.

Thomas

[fkerber]

Hi,

das sit natürlich gut zu wissen.
Danke für die Erläuterung.

LG, Frederic

[fkerber]

Hi,

das Ganze sieht dann nun so aus (und funktioniert auch):

Delphi-Quellcode:

var
  proc: TIBCStoredProc;
  ta: TIBCTransaction;
begin
  ta := TIBCTransaction.Create(nil);
  ta.DefaultConnection := ibc_mainDB;
  proc := TIBCStoredProc.Create(nil);
  proc.Transaction := ta;
  proc.StoredProcName := 'CREATECUSTOMER';
  proc.Prepare;
  proc.ParamByName('name').Value := custName;
  proc.ParamByName('title').Value := title;
  proc.ParamByName('forename').Value := forename;
  proc.ParamByName('surname').Value := surname;
  proc.ParamByName('street').Value := street;
  proc.ParamByName('houseNo').Value := houseNo;
  proc.ParamByName('country').Value := Uppercase(country);
  proc.ParamByName('zipcode').Value := zipcode;
  proc.ParamByName('cityname').Value := cityname;
  proc.ExecProc;
  result := proc.ParamByName('contactid').AsInteger;
  proc.Close;
  ta.Commit;
  proc.Free;
  ta.Free;
end;

Ist das dann so ok?


LG, Frederic

[tsteinmaurer]

Sieht ganz gut aus. Ich würde noch das Close weg geben und ein sauberes Exception-Handling machen. In etwa so:

Delphi-Quellcode:

var
  proc: TIBCStoredProc;
  ta: TIBCTransaction;
begin
  ta := TIBCTransaction.Create(nil);
  ta.DefaultConnection := ibc_mainDB;
  proc := TIBCStoredProc.Create(nil);
  proc.Transaction := ta;
  try
    ta.StartTransaction;
    try
      proc.StoredProcName := 'CREATECUSTOMER';
      proc.Prepare;
      proc.ParamByName('name').Value := custName;
      proc.ParamByName('title').Value := title;
      proc.ParamByName('forename').Value := forename;
      proc.ParamByName('surname').Value := surname;
      proc.ParamByName('street').Value := street;
      proc.ParamByName('houseNo').Value := houseNo;
      proc.ParamByName('country').Value := Uppercase(country);
      proc.ParamByName('zipcode').Value := zipcode;
      proc.ParamByName('cityname').Value := cityname;
      proc.ExecProc;
      result := proc.ParamByName('contactid').AsInteger;
      ta.Commit;
    except
      ta.Rollback;
      raise;
    end;
  finally
    proc.Free;
    ta.Free;
  end;
end;

Thomas

[fkerber]

Dankeschön!

[omata]

kleine Korrektur...

Delphi-Quellcode:

var
  proc: TIBCStoredProc;
  ta: TIBCTransaction;
begin
  ta := TIBCTransaction.Create(nil);
  proc := TIBCStoredProc.Create(nil);
  try
    proc.Transaction := ta;
    ta.DefaultConnection := ibc_mainDB;
    ta.StartTransaction;
    try
      proc.StoredProcName := 'CREATECUSTOMER';
      proc.Prepare;
      proc.ParamByName('name').Value := custName;
      proc.ParamByName('title').Value := title;
      proc.ParamByName('forename').Value := forename;
      proc.ParamByName('surname').Value := surname;
      proc.ParamByName('street').Value := street;
      proc.ParamByName('houseNo').Value := houseNo;
      proc.ParamByName('country').Value := Uppercase(country);
      proc.ParamByName('zipcode').Value := zipcode;
      proc.ParamByName('cityname').Value := cityname;
      proc.ExecProc;
      result := proc.ParamByName('contactid').AsInteger;
      ta.Commit;
    except
      ta.Rollback;
      raise;
    end;
  finally
    proc.Free;
    ta.Free;
  end;
end;