"tote" Instanzen finden und beenden?

[HeikoAdams]

Hallo,
hat hier jemand eine Idee, wie ich "tote" Instanzen (z.B. nach einem Programmabsturz) meines Programms finden und beenden kann? Eine Suche zu dem Thema bringt nur die Diskussionen, ob Delphi tot ist oder nicht, als Ergebnisse

[HeikoAdams]

Nach ein wenig herum suchen bin ich schon einmal einen Schritt weiter: Ob mein Programm bereits ausgeführt wird kann ich über CreateMutex herausfinden und falls ja, kriege ich ja auch das Handle des Prozesses raus.

Aber wie kann ich prüfen, ob der Prozess tot ist oder nicht?

[HeikoAdams]

Hat sich erledigt. Ich habe eine Lösung gefunden:

Delphi-Quellcode:

function TFrmBackup.CheckInstance: Boolean;
var
  h: HWnd;
   RetValue: Cardinal;
  hProcess, ProcessId: THandle;
begin
  Result := True;
  mutex := 0;
  //Mutex erzeugen
  mutex := Windows.CreateMutex(nil, True, PChar(sMutex));

  if (GetLastError = ERROR_ALREADY_EXISTS) then
  begin
    Result := False;
    h := 0;

    //Handle der anderen Instanz suchen
    repeat
      h := FindWindowEx(0, h, 'TApplication', PChar(Application.Title))
    until (h <> Application.Handle);

    if (h <> 0) then
    begin
       //prüfen, ob die Instanz hängt
      if (SendMessageTimeOut(h, WM_NULL, 0, 0, SMTO_NORMAL or SMTO_ABORTIFHUNG,
         5000, RetValue) = 0) then
      begin
         //ProzessId des hängenden Prozesses holen
        GetWindowThreadProcessId(h, ProcessId);

        if (ProcessId = 0) then
           Exit;

        //hängenden Prozess beenden
        hProcess := OpenProcess(PROCESS_TERMINATE, False, ProcessId);

        if (hProcess <> 0) then
          try
            TerminateProcess(hProcess, 255);
          finally
            CloseHandle(hProcess);
          end;
      end;
    end;
  end;
end;

[Meta777]

huhu,
der code ab " if (h <> 0) then" sollte innerhalb der repeat until loop sein.

shalom

[SirThornberry]

@HeikoAdams: Bitte unterlasse zukünftig das pushen innerhalb von 24 Stunden.

@Meta777: Nein, der Source stimmt schon so. Er will ja nicht die neu gestartete Instanz beenden sondern eine andere.

[Aphton]

Es kann aber sein, dass es mehrere Instanzen gibt, ausgeschlossen dieser Instanz. Daher ab in die Schleife!

[HeikoAdams]

Okay, dann würde die entsprechende Code-Sequenz wohl so aussehen:

Delphi-Quellcode:

    repeat
       h := FindWindowEx(0, h, 'TApplication', PChar(Application.Title));

       if (h <> 0)
         and (h <> Application.Handle) then
       begin
          //prüfen, ob die Instanz hängt
          if (SendMessageTimeOut(h, WM_NULL, 0, 0, SMTO_NORMAL or SMTO_ABORTIFHUNG,
             5000, RetValue) = 0) then
          begin
             //ProzessId des hängenden Prozesses holen
             GetWindowThreadProcessId(h, ProcessId);

             if (ProcessId = 0) then
                Continue;

             //hängenden Prozess beenden
             hProcess := OpenProcess(PROCESS_TERMINATE, False, ProcessId);

             if (hProcess <> 0) then
                try
                   TerminateProcess(hProcess, 255);
                finally
                   CloseHandle(hProcess);
                end;
          end;
       end;
    until (h = 0);

[himitsu]

Wäre ein until h = 0; nicht besser?

Und statt dem Exit auch noch ein

Delphi-Quellcode:

if ProcessId = 0 then
  Continue;

bzw. bessen auch ein

Delphi-Quellcode:

if ProcessId <> 0 then
begin
  ...
end;

[HeikoAdams]

Zitat von himitsu:

Wäre ein until h = 0; nicht besser?

Nein, weil der Code ja normalerweise mindestens die Instanz, die den Code ausführt, finden sollte

Zitat von himitsu:

Und statt dem Exit auch noch ein

Delphi-Quellcode:

if ProcessId = 0 then
  Continue;

bzw. bessen auch ein

Delphi-Quellcode:

if ProcessId <> 0 then
begin
  ...
end;

Habs ergänzt

[himitsu]

until h = 0; = solange, bis keine Instanz h mehr gefunden wurde

until h <> 0; = springe nach der 1. Instanz raus und wenn garnichts gefunden wurde, dann bleib in einer Endlosschleife hängen.