DLL mit Form

[Capa]

sharemem setz ich ja schon ein. funktioniert ja auch der test nur halt das mit dem beenden nicht.

Zitat:

Das passt schon. Sorgt dafür das für die DLL-Formulare kein extra Taskbar-Eintrag erscheint.

Genau das ist ja gewollt, den sonst würde bei der menge an Forms die ich immo im Projekt hab die ganze taskbar voll sein.

[blauweiss]

Zitat von Capa:

sharemem setz ich ja schon ein. funktioniert ja auch der test nur halt das mit dem beenden nicht.

Hi Capa,

Du mußt ShareMem sowohl in EXE- als auch DLL-project in der uses-List als erstes(!) einbinden:

uses
ShareMem,
...

Gruß
blauweiss

[Capa]

das mit sharemem hab ich geändert.
und auch das mit dem show/free hab nun caFree und create beim aufruf solange nicht schon vorhanden
allerdings wenn ich die form schliesse und dann wieder neu öffnen will bekomm ich nen fehler

Zitat:

Zugriffsverletzung bei Adresse 00585B62 in Modul 'DLL1.dll'. Lesen von Adresse 00000280.

die DLL1.dll is meine eigene DLL

[blauweiss]

Hallo Capa,

Action=caFree im OnClose gibt die Form zwar frei, aber Deine Instanz (Form2) wird dabei nicht auf nil gesetzt -> die nächste Abprüfung auf nil (in CreateForm2) ergibt false, die Form wird nicht neu erzeugt -> AV beim Show-Versuch.

Vorschlag: Entweder Action=caHide oder im Forum suchen, wie "Form nil setzen nach Schließen" o.ä. funktioniert.

Gruß,
blauweiss

[Capa]

siehe oben das mit hide hat ich schonmal da wurde mein programm immer unsanft
per Taskmanager von mir geschlossen.
ich versuch mal etwas was mir gerade im kopf rumschwirrt.
und danke für den hinweis :/ wow lenkt mich wohl doch zu sehr ab


Edit: Also bisher funzt es wie folgt, wenn ich die form starte dann zeigt er sie ohne fehler an
kann auch drauf zugreifen und die Form schliessen und wieder öffnen allerdings hab ich immernoch nen problem mit dem programmende quasi immernoch per taskmanager.

Delphi-Quellcode:

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
  FreeAndNil(Form2);
end;

[blauweiss]

im FormClose darfst Du nicht die Instanz selber zerstören

Delphi-Quellcode:

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
//  FreeAndNil(Form2);   <- hätte eigentlich hier schon krachen können
end;

dazu scheint es etwas hart, am Programmende eine ggfs. offene Form (noch dazu die in der DLL) einfach freizugeben, statt sie zu schließen.
Ich würde im Hauptprogramm dieses machen:

Delphi-Quellcode:

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := False;
  try
    HideForm2; // <-   anstatt FreeForm2
  finally
    CanClose := True;
  end;
end;

und auf den Garbage collector vertrauen.

Das setzt natürlich voraus, daß HideForm2 robust programmiert wird, z.B.

Delphi-Quellcode:

procedure HideForm2; stdcall;
begin
  if Assigned(Form2) then // <- hat bei Dir gefehlt
    Form2.Hide();
end;

Gruß,
blauweiss

[Capa]

mhh anderer Code selbes ergebnis kann die exe immernoch nur per taskmanager killen
bzw über die stop funktion in delphi.

Hier nochma der aktuelle Code nicht das sich doch noch nen anderer Fehler eingeschlichen hat den ich nicht
gesehen hab aber bei dem wenigen Code glaub ich das eher weniger.

DLL-File

Delphi-Quellcode:

library DLL1;

uses
  Sharemem,
  SysUtils,
  Classes,
  Forms,
  windows,
  DLLUnit1 in 'DLLUnit1.pas' {Form2};

{$R *.res}

procedure CreateForm(appHandle: THandle); stdcall;
begin
  if appHandle = 0 then apphandle := GetActiveWindow;
  Application.Handle := appHandle;
  try
    if Form2=nil then
      Form2 := TForm2.Create(Application);
    Form2.Show();
  except
    On E: Exception Do Application.HandleException(E);
  end;
  Application.Handle := 0;
end;

procedure HideForm; stdcall;
begin
  if Assigned(Form2) then
  begin
    Form2.Hide();
//    FreeAndNil(Form2);
  end;
end;

procedure Test(text1,text2,text3: string); stdcall;
begin
  Form2.Listbox1.Items.Add(text1);
  Form2.Listbox1.Items.Add(text2);
  Form2.Listbox1.Items.Add(text3);
end;

exports CreateForm,
          HideForm,
              Test;

begin
end.

DLL-Unit

Delphi-Quellcode:

unit DLLUnit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm2 = class(TForm)
    ListBox1: TListBox;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caHide;
end;

end.

Exe-Unit

Delphi-Quellcode:

unit Unit1;

interface

uses
  Sharemem, Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls,
  Forms, Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

procedure CreateForm2(appHandle: THandle); stdcall; external 'DLL1.dll' name 'CreateForm';
procedure HideForm2; stdcall; external 'DLL1.dll' name 'HideForm';
procedure Test(text1,text2,text3: string); stdcall; external 'DLL1.dll' name 'Test';


{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  CreateForm2(Application.Handle);
  Test('Need Help','Capa','DLL Form');
end;

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := False;
  try
    HideForm2;
  finally
    CanClose := True;
  end;
end;

end.

P.S.: Selbst wenn ich die Exe nur starte und dann wieder beende hab ich das problem
also auch wenn ich die Form2 nicht initialisiere.