FormCloseQuery FormShowing abfrage

[Christian Seehase]

Moin Capa,

hier mal ein anderer Ansatz:

Delphi-Quellcode:

var
  i : Integer;

begin
  for i := 0 to Application.ComponentCount-1 do begin
    if Application.Components[i] is TForm then begin
      if  (Application.Components[i] as TForm).Visible and
         ((Application.Components[i] as TForm).Tag = 1) then begin
        CanClose := False;
        break;
      end;;
    end;
  end;
  if not CanClose then MessageBox(self.Handle,'Erst alle anderen Formulare schliessen','Fehler',MB_ICONERROR);
end;

Alle Unterformulare bekommen, entweder manuell im Objektinspektor, oder per Programm im OnCreate die Eigenschaft Tag auf 1 gesetzt (Tag ist ein beliebig verwendbarer Integerwert).
Sobald eines sichbar ist, und Tag=1 ist darf das Hauptformular nicht geschlossen werden.

[Capa]

funzt super danke
dann weiß ich jetzt auch wie ich meine anderen Probleme lösen kann

Mfg Capa

[Sir Rufo]

Wofür denn das Tag setzen? Nur um herauszufinden, ob die Form nicht die MainForm ist?

If MyForm <> Application.MainForm then Das geht immer und man kann dabei nichts vergessen (z.B. das Tag setzen)

[Capa]

Wenns mir um die Mainform gehen würde könnte ich auch name='Form1'; abfragen
aber so kann ich zum bsp auch das Programm schliessen lassen, wenn noch ne Form angezeigt wird
wo keine speicherrelevanten daten drin sind sondern nur anzeigen.

[DeddyH]

Könnte man nicht einfach Screen.FormCount abfragen?

[Sir Rufo]

Diese MainForm prüft alle (mit Application als Owner) Formulare, ob diese sich schließen können.

Mit der Property CloseForce kann man das Schliessen erzwingen (was beim Abmelden/Herunterfahren -> WM_ENDSESSION auch gemacht wird).

Delphi-Quellcode:

unit frmMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class( TForm )
    procedure FormCloseQuery( Sender : TObject; var CanClose : Boolean );
    procedure FormCreate( Sender : TObject );
  private
    FCloseForce : Boolean;
  protected
    procedure WMEndSession( var message : TWMEndSession ); message WM_ENDSESSION;
  public
    property CloseForce : Boolean
      read   FCloseForce
      write  FCloseForce;
  end;

var
  Form1 : TForm1;

implementation

uses
  frmData;

{$R *.dfm}

procedure TForm1.FormCloseQuery( Sender : TObject; var CanClose : Boolean );
var
  idx : Integer;
begin
  if not CloseForce
  then
    for idx := 0 to Application.ComponentCount - 1 do
      if ( Application.Components[idx] <> Self ) and ( Application.Components[idx] is TForm )
      then
        CanClose := CanClose and TForm( Application.Components[idx] ).CloseQuery;
end;

procedure TForm1.FormCreate( Sender : TObject );
begin
  CloseForce := False;
end;

procedure TForm1.WMEndSession( var message : TWMEndSession );
begin
  inherited;
  CloseForce := True;
end;

end.

[Capa]

oO wieso sollte ich das den erzwingen wollen der user soll doch das programm solange nicht schliessen können
bis alle forms geschlossen sind, wenn ich das nun erzwinge is doch das ganze was ich damit versuche zu erreichen
zwecklos oder seh ich das falsch ?