JPGs aus einer Resourcendatei laden

[Bummi]

sorry , ich hatte Dich in die falsche Ecke geschickt

Delphi-Quellcode:

procedure LoadPictureFromJpgResource(picture : TPicture;const AResName: string);
var
   rs: TResourceStream;
   jpg: TJPEGImage;
begin
   rs := TResourceStream.Create(HInstance,AResName,RT_RCDATA);
   jpg := TJPEGImage.Create;
   try
      jpg.LoadFromStream(rs);
      picture.Assign(jpg);
   finally
      jpg.Free;
      rs.Free;
   end;
end;


procedure TForm1.Button1Click(Sender: TObject);
begin

  LoadPictureFromJpgResource(Image1.Picture,'TEST2');
end;

[fiscch4]

Hallo,

ich weis nicht ob ich mich zu blöd anstelle aber wenn ich die Procedure oben registrieren will bringt einen fehler von wegen [Fehler] test.pas(40): Ungenügende Forward- oder External-Deklaration: 'TForm1.LoadPictureFromJpgResource'

dann habe ich es versucht das was in der Procedur normal abläuft in oncreat zu packen
aber dann sagt er nur Resource B1(RC sieht so aus:
B1 RT_RCDATA "test.jpg"
B2 RT_RCDATA "images.jpg"

ist umgewandelt und eigebunden) nicht.

muss ich sonst noch irgendwas beachten ich gehe mal davon aus das ich den Code richtig verstanden habe und AResName= in meinem Fall B1 ist
und picture in meinem Fall Image1.Picture

ich hoffe ich bringe das noch bis nächsten Mittwoch hin
soll ein Adventskalender werden mit Bildern ...

Also Vielen Dank
und Gute Nacht

[Luckie]

Ist die Routine auch eine Methode deines Formulars?

[Bummi]

Du hast wahrscheinlich die Deklaration von LoadPictureFromJpgResource
so vorgenommen

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
    Procedure LoadPictureFromJpgResource(....
  end;

Damit wäre es eine Methode der Klasse TForm1 und muß unterhalb von implementation auch so
Procedure TForm1.LoadPictureFromJpgResource(...
eigefügt werden.

Sinvoller ist aber, wenn Du es nicht gleich in eine UtilUnit packen willst

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

Procedure LoadPictureFromJpgResource(...

var
  Form1: TForm1;

implementation

[fiscch4]

Hallo,

also das mit der Procedure funktioniert jetzt soweit nur das immer noch die Fehlermeldung kommt das die Resource nicht gefunden wurde
hier mal der Quellcode komplett

Delphi-Quellcode:

unit testen;

interface

uses
  JPEG, Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;
procedure LoadPictureFromJpgResource(picture : TPicture;const AResName: string);
var
  Form1: TForm1;

implementation

{$R *.dfm}
{$R bilder.RES}

procedure LoadPictureFromJpgResource(picture : TPicture;const AResName: string);
var
   rs: TResourceStream;
   jpg: TJPEGImage;
begin
   rs := TResourceStream.Create(HInstance,AResName,RT_RCDATA);
   jpg := TJPEGImage.Create;
   try
      jpg.LoadFromStream(rs);
      picture.Assign(jpg);
   finally
      jpg.Free;
      rs.Free;
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin

  LoadPictureFromJpgResource(Image1.Picture,'TEST2');
end;


end.

der Code von der bilder.RC datei die ich dann per drag and drop in die BRCC32.exe schieb und eine bilder.RES rausbekommen

Code:

TEST1 RT_RCDATA "C:\Users\Public\Documents\delphi\test\test.jpg"
TEST2 RT_RCDATA "C:\Users\Public\Documents\delphi\test\images.jpg"

warum kann er die Resource nicht finden habe ich beim einbinden was falsch gemacht?
oder schon bei der Erstellung der bilder.RES?
der Rest würde denk ich funktionieren
Vielen Dank

PS: ich bin echt positiv überrascht das ihr so viel geduld habt... und mir helft

[rollstuhlfahrer]

Zitat von fiscch4:

Code:

TEST1 RT_RCDATA "C:\Users\Public\Documents\delphi\test\test.jpg"
TEST2 RT_RCDATA "C:\Users\Public\Documents\delphi\test\images.jpg"

Es muss TEST1 RCDATA heißen. RT_RCDATA ist die Konstante aus Delphi. Das kannst du auch sehen, wenn du dir die EXE mit einem Ressourceneditor betrachtest.

Bernhard

[fiscch4]

Vielen Vielen Dank
es funktioniert

hätte gleich noch eine frage dürfte wahrscheinlich leicht zu beantworten sein habe bloß mit sowas noch nie gearbeitet
ich möchte gernen einen Prozess starten ohne Form oder ähnliches das es quasie nur im taskmanager unter prozesse zufinden ist und damit dann das Datum abgleiche alle 24 std
ist sowas mit delphi möglich?

falls nicht ist es egal

nochmals vielen Dank
fiscch4

[DeddyH]

Sicher ist das möglich. Was ich immer mache: Konsolenanwendung erstellen und das {$APPTYPE CONSOLE} rauslöschen.

[Bummi]

hat mich jetzt auch etwas Zeit gekostet ich verwende immer den XN ResourceEditor

Code:

TEST1 RCDATA "C:\Users\Public\Documents\delphi\test\test.jpg"
TEST2 RCDATA "C:\Users\Public\Documents\delphi\test\images.jpg"

EDIT:
zu spät....

[fiscch4]

Zitat von Bummi:

hat mich jetzt auch etwas Zeit gekostet ich verwende immer den XN ResourceEditor

Trotzdem Danke

ich gebs heute nicht auf

JPGs anstatt in TImage in Buttons zu laden bzw verschieden Onclicks für die verschiedenen TImages
ist auch das möglich oder muss ich dann die position des cursors abfragen?

Vielen Vielen Dank