Tastendruck mit KEYBD_EVENT erzeugen

[Shark99]

Ich benutze KEYBD_EVENT um einen Tastendruck zu simulieren.

Es klappt wenn ich CTRL + v erzeugen will:

Delphi-Quellcode:

       KEYBD_EVENT(VK_CONTROL,0,0,0); // Strg-Taste drücken
       KEYBD_EVENT(VKKeyScan('v'),0,0,0); // v-Taste drücken
       KEYBD_EVENT(VK_CONTROL,0,KEYEVENTF_KEYUP,0); // Strg-Taste loslassen

Wenn ich es jedoch mit SHIFT + Insert versuche klappt es nicht!

Delphi-Quellcode:

       KEYBD_EVENT(VK_SHIFT,0,0,0); // Shift-Taste drücken
       KEYBD_EVENT(VK_INSERT,0,0,0); // INS-Taste drücken
       KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_KEYUP,0); // Shift-Taste loslassen

Es kommt nur die Insert Taste statt Shift + Inser an.

Was mache ich falsch?

[plusplus]

versuche mal:

KEYBD_EVENT(VK_SHIFT,0,0,0); // Shift-Taste drücken
KEYBD_EVENT(VK_INSERT, MapVirtualKey(VK_INSERT, 0),0,0); // INS-Taste drücken
KEYBD_EVENT(VK_INSERT, MapVirtualKey(VK_INSERT, 0),2,0); // INS-Taste loslassen
KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_KEYUP,0); // Shift-Taste loslassen


PS: MapVirtualKey ist auch ein API call

[Shark99]

Danke, aber es funktioniert genau so wenig, nur Insert wird geschickt, ohne Shift.

Ich habe mittlerweile eine halbe Lösung.

So wird Shift + Insert geschickt:

Delphi-Quellcode:

       KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_EXTENDEDKEY,0); // Shift-Taste drücken
       KEYBD_EVENT(VK_INSERT,0,0,0); // INS-Taste drücken
       KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_KEYUP,0); // Shift-Taste loslassen

Allerdings bleibt Shift danach dauerhaft gedrückt, d.h. geht nicht mehr hoch, man ist also in einem CAPS-Lock state (ohne dass Caps-Lock leuchtet).

Loslassen klappt auch nicht mit KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP,0);

[plusplus]

jede taste die gedruckt wird muss man auch wieder loslassen, du must insert key auch loslassen. meine loesung fuktioniert, ich habe es vielemal gebraucht, ich verstehe nicht warum es bei dir nicht geklapt hat. Ich habe alerdings den Ctrl key jemals gebraucht.

[Shark99]

Das Problem ist nur mit Shift, Alt und Ctrl haben das Problem nicht. An loslassen der Insert Taste liegt es auch nicht. Auch wenn ich die per Code loslasse ändert sich an der Sache nichts. Wobei ich mir gar nicht sicher bin ob man die wirklich loslassen muss, weil Tasten wie Insert kann nicht unten gehalten werden können, aber das ist Offtopic.

[Satty67]

Wie sieht es damit aus

Delphi-Quellcode:

       KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_EXTENDEDKEY,0); 
       KEYBD_EVENT(VK_INSERT,0,0,0); 
       KEYBD_EVENT(VK_SHIFT,0,KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP,0);

Alternative wäre noch SendInput-Funktion

[Shark99]

Satty danke für den Vorschlag, aber ich schrieb schon oben dass es so auch nicht geht.

[Satty67]

Achja, im Fliestext.. hatte ich übersehen.

Ist aber trotzdem die richtige Lösung für Shift. Ich hatte nur eine Buchstabentaste getestet, statt Insert (weil es einfacher zu testen war) und deshalb den zweiten Fehler bei Insert nicht bemerkt. Warum das fehlende Flag bei Insert auch den nachfolgenden Auffruf von Shift beeinflusst, kann ich aber auch nicht sagen.

Insert ist auch ein Extended Key, der Code unten funktioniert bei mir (lasse ich das Extended Flag bei Insert weg, kann ich Dein Verhalten reproduzieren).

Der Aufruf von KEYBD_EVENT sollte identisch sein:

Delphi-Quellcode:

procedure SimKeyEvent(VirtualKey : Integer; Flags : LongWord);
var
  KeybdInput : TagKeybdInput;
  Input : TagInput;
begin
  KeybdInput.wVk := VirtualKey;
  KeybdInput.dwFlags := Flags;
  KeybdInput.dwExtraInfo := 0;
  KeybdInput.wScan := 0;
  KeybdInput.time := 0;

  Input.Itype := INPUT_KEYBOARD;
  Input.ki := KeybdInput;

  SendInput(1, Input, SizeOf(Input));
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  SimKeyEvent(VK_SHIFT, KEYEVENTF_EXTENDEDKEY);
  SimKeyEvent(VK_INSERT, KEYEVENTF_EXTENDEDKEY);
  SimKeyEvent(VK_INSERT, KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP);
  SimKeyEvent(VK_SHIFT, KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP);
end;

Getested mit TAction-Shortcut "Shift-Insert", das erst eine MessageBox ausgibt, dann Fokus auf ein TEdit setzt.

Erfolg der Aufruf wie folgt, dann Dein beschriebenes Verhalten:

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
begin
  SimKeyEvent(VK_SHIFT, KEYEVENTF_EXTENDEDKEY);
  SimKeyEvent(VK_INSERT, 0);
  SimKeyEvent(VK_INSERT, 0);
  SimKeyEvent(VK_SHIFT, KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP);
end;

(Erklärt evtl. auch, warum nur Shift betroffen war, weil Ctrl/Alt mit Zeichen, nicht mit Sondertaste getestet wurde).

[Shark99]

Danke Satty, das war der Fehler!

[Cicaro]

Postet immer den richtigen Code am Ende (wenn das Problem gelöst wurde). Egal wie alt es ist.
Die neuen, jungen Programmierer stolpern immer wieder über dieselben Fehler und das Netz ist voll von fehlerhaften Beispielen.

Hier der richtige Code, der bei mir zauberhaft funktioniert (aus C#):

Code:

Windows.keybd_event((byte) key, (byte) Windows.MapVirtualKey(key, 0), Windows.KEYEVENTF_EXTENDEDKEY, 0);
Windows.keybd_event((byte) key, (byte) Windows.MapVirtualKey(key, 0), Windows.KEYEVENTF_EXTENDEDKEY | Windows.KEYEVENTF_KEYUP, 0);

Für dieses Problem (in Delphi):

Delphi-Quellcode:

Windows.keybd_event(VK_SHIFT, Windows.MapVirtualKey(VK_SHIFT, 0), KEYEVENTF_EXTENDEDKEY, 0); // Shift drücken
Windows.keybd_event(VK_INSERT, Windows.MapVirtualKey(VK_INSERT, 0), KEYEVENTF_EXTENDEDKEY, 0); // INS drücken
Windows.keybd_event(VK_INSERT, Windows.MapVirtualKey(VK_INSERT, 0), KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP, 0); // INS loslassen
Windows.keybd_event(VK_SHIFT, Windows.MapVirtualKey(VK_SHIFT, 0), KEYEVENTF_EXTENDEDKEY or KEYEVENTF_KEYUP, 0); // Shift loslassen

Naja, lasst das mal so stehen, wenn ich kein Fehler gemacht habe.
// edit: 3 kleine Fehler korrigiert, danke an Bummi