csv read

[DeddyH]

Delphi-Quellcode:

var
  csvreader : TCsvReader;
  sData : TFilestream;
  sList: TStringList;
  i : integer;

begin
  sData := TFilestream.Create('M:\modules Delphi\CSVreader\config.csv',fmopenread);
  try
    csvReader := TCSVReader.Create (sData, ';');
    try
      sList := TStringList.Create;
      try
        csvReader.First;
        while not csvreader.Eof do begin
          //nur Firma 'A'
          if csvreader.Columns[0] = 'A' then
            sList.Add(Format('Channel %s = MAC %s',[csvreader.Columns[1],csvreader.Columns[2]));
          csvreader.Next;
        end;
        sList.SaveToFile(<Dateiname>);  //hier Dateinamen eintragen
      finally
        sList.Free;
      end;
    finally
      csvreader.Free;
    end;
  finally
    sdata.Free;
  end;
end.

[Sir Rufo]

Warum so kompliziert, wenn es doch so schön einfach geht:

Delphi-Quellcode:

  var
    con : TADOConnection;
    qry : TADOQuery;
    MyFile : string;
  begin
    MyFile := 'M:\modules Delphi\CSVreader\config.csv';
    con := TADOConnection.Create( nil );
    try
      con.ConnectionString := 'Driver={Microsoft Text-Treiber (*.txt; *.csv)};Extensions=asc,csv,tab,txt;';
      con.LoginPrompt := False;
      con.DefaultDatabase := ExtractFileDir( MyFile );
      con.Open;
      try
        qry := TADOQuery.Create( con );
        qry.Connection := con;
        qry.SQL.Text := Format( 'SELECT * FROM %s WHERE Firma = %s', [ ExtractFileName( MyFile ), QuotedStr( 'A' ) ] );
        qry.Open;
        try
          while not qry.Eof do
            begin
              // Verarbeitung der Daten z.B. mit qry.FieldByName( 'Firma' ).AsString
              qry.Next;
            end;
        finally
          qry.Close;
        end;
      finally
        con.Close;
      end;
    finally
      con.Free;
    end;
  end;

Es wird in dem Verzeichnis mit den Daten aber auch noch die Datei schema.ini benötigt
In deinem Fall sollte folgender Inhalt genügen

Code:

[config.csv]
Format=Delimited(;)

Man könnte alternativ die Daten auch mit TADOTable auslesen und dann einen Filter setzen

[Tossi65]

@Sir Rufo
Das ist ja geil!! Man lernt nie aus. Muss man bei dieser Methode auf
irgendeine MSDac Version achten oder ist es Basisbestandteil von ADO??

Danke Torsten

[Sir Rufo]

Das ist eine gute Frage ... ich halte es da wie die Hummel ... ich mach es einfach und es klappt

Bisher hatte ich bei keiner Windows-Version damit Probleme (selbst nackig installierte Systeme)

[Tossi65]

Danke

[Sir Rufo]

Vielleicht sollte ich zur weiteren Erheiterung erwähnen, dass auch SQL-Befehle wie UNION und JOIN benutzt werden können

[angos]

Huch,

da hab ich auch mal wieder dazugelernt. Danke!