ListView GetGroupRect

[Björn Ole]

Hallo,

ich möchte gerne einige Informationen gruppiert in einem TListView anzeigen.
Im Header jeder Gruppe befindet sich eine URL, die ich durch folgenden Code "anklickbar" erscheinen lasse:

Delphi-Quellcode:

procedure TForm1.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  i: Integer;
  r: TRect;
begin
  for i := 0 to ListView1.Groups.Count - 1 do
  begin
    if ListView_GetGroupRect(ListView1.Handle, i, LVGGR_LABEL, r) = 1 then
    begin
      // if cursor is over group label, change cursor icon
      // and set header index for mouse up
      if (r.Top < Y) and (r.Bottom > Y) and (r.Left < X) and (r.Right > X) then
      begin
        ListView1.Cursor := crHandPoint;
        FGroupHeaderIndex := i;
        Break;
      end
      else
      begin
        ListView1.Cursor := crDefault;
        FGroupHeaderIndex := -1;
      end;
    end;
  end;
end;

Eigentlich alles kein Problem. Ich benutze LVGGR_LABEL, da sich der Cursor ändern soll, wenn er sich genau über dem Text befindet. Allerdings stimmen die Angaben, die mir ListView_GetGroupRect im TRect zurückgibt, nicht ganz, die Breite ist im Verhältnis zur Textlänge zu gering. Zur Verdeutlichung hab ich mal zwei Panels positionieren lassen, siehe Bild im Anhang. Ab dort, wo die Panels aufhören, ist der Cursor wieder crDefault, obwohl er noch über der URL ist.

Wie komme ich am besten an die korrekte Breite des Labels?

Vielen Dank,
Björn.

[Björn Ole]

Ich hab mittlerweile herausgefunden, dass das Rect die Maße enthält, die auch GetTextExtentPoint32 zurückliefert, also GetTextExtentPoint32 = (Rect.Right - Rect.Left). Die Breite des Rects entspricht der Textbreite in normaler Schrift, z.B. in einem Item des ListViews. Dummerweise wird der Text der GroupHeader etwas in die Breite gezogen (sieht man sehr gut im Bild, vgl. Textbreite erster GroupHeader - erstes Item), sodass das Rect immer zu kurz ist. Wie ich das umgehe, konnte ich nicht herausfinden.

Ich addiere jetzt einfach einen Bruchteil der Breite drauf, das reicht für meine Bedürfnisse.

Des Weiteren gibt ListView_GetGroupRect nur das Rect für HeaderAlign = taLeftAlign zurück. Ist ein anderes HeaderAlign eingestellt, befindet sich das Rect an der Stelle, an der der Header mit taLeftAlign stehen würde. Das rechne ich jetzt auch noch um, sodass die anderen Aligns auch funtkionieren.

Delphi-Quellcode:

procedure TForm1.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  bMouseOverGroupLabel: boolean;
  i, labelWidth: Integer;
  r: TRect;
begin
  // if cursor is over group label, change cursor icon
  // and set header index for mouse up
  bMouseOverGroupLabel := false;
  for i := 0 to ListView1.Groups.Count - 1 do
  begin
    if ListView_GetGroupRect(ListView1.Handle, i, LVGGR_LABEL, r) = 1 then
    begin
      // adjust label width
      r.Right := r.Right + 10 + Round((r.Right - r.Left) * 0.06);
      labelWidth := r.Right - r.Left;
      
      // if header is not taLeftAlign, we need to recalc rect.left and rect.right
      case ListView1.Groups[i].HeaderAlign of
        taCenter: // reposition rect to center
          begin
            r.Left := (ListView1.ClientWidth - labelWidth) div 2;
            r.Right := (ListView1.ClientWidth + labelWidth) div 2;
          end;
        taRightJustify: // reposition rect to right
          begin
            r.Left := ListView1.ClientWidth - (labelWidth) - 12;
            r.Right := ListView1.ClientWidth - 12;
          end;
      end;

      bMouseOverGroupLabel := (r.Top < Y) and (r.Bottom > Y) and (r.Left < X) and (r.Right > X);
      if bMouseOverGroupLabel then
      begin
        ListView1.Cursor := crHandPoint;
        FGroupHeaderIndex := i;
        Break;
      end;

    end;
  end;
  
  if not bMouseOverGroupLabel then
  begin
    ListView1.Cursor := crDefault;
    FGroupHeaderIndex := -1;
  end;
end;

Abschließend sei noch zu erwähnen, dass der ganze Spaß erst ab Vista läuft.