Prüfen, ob Funktion innerhalb von Exceptionbehandlungsroutine aufgerufen wurde

[Dezipaitor]

Hi,

kann man programmatisch prüfen, ob eine Funktion innerhalb von finally (oder Except) aufgerufen wird?
Der Sinn dahinter ist, dass ich gerne ein Funktionspaar definieren würde, deren Gegenfunktion auf jeden Fall ausgeführt werden muss. Die zweite Funktion muss daher für den Fall einer Exception im finally Block stehen.

THX

[mkinzler]

Erweitere die Funktion/Methode um einen entsprechenden Parameter

[himitsu]

"automatisch" Prüfen kannst du es nicht, du kannst es dir höchstens in eigenen Variablen merken und dann auswerten.

Delphi-Quellcode:

gemacht := false;
try
  ...
  gemacht := Machen;
  ...
finally
  if gemacht then Rückgängig;
end;

Delphi-Quellcode:

gemacht := false;
try
  ...
  Machen;
  gemacht := true;
  ...
finally
  if gemacht then Rückgängig;
end;

Das funktioniert so auch schon seit vielen Jahren sehr gut, bei mir.

[Dezipaitor]

Nein, das ist nicht das Thema. Die Funktionen werden nicht unbedingt von mir aufgerufen. Daher ist eine extra Variable nicht möglich.

Viele Programmierer machen z.B. soetwas:

Delphi-Quellcode:

Enter;

if IsWindows2100 then
  exit;

Leave;

Ich würde nur gerne, in Leave eine Exception werfen, dass es in ein finally Block gehört.

[mkinzler]

Aber als weiterer Parameter mit Default. Du kannst ihm dann einen anderen Wert mitgeben

[himitsu]

Auch bei einem Exit wird das Finally aufgerufen ... was du doch bestimmt weißt.

Delphi-Quellcode:

Enter;
try

  if IsWindows2100 then
    exit;

finally
  Leave;
end;

Und wenn ein anderer Programmierer nicht dafür sorgt, daß die "Resource" ordnungsgemäß freigegeben/abgeschlossen wird,
dann ist das nicht dein Problem und er muß eben mit den Konsequenzen rechnen.

[uligerhardt]

Zitat von Dezipaitor:

Hi,

kann man programmatisch prüfen, ob eine Funktion innerhalb von finally (oder Except) aufgerufen wird?
Der Sinn dahinter ist, dass ich gerne ein Funktionspaar definieren würde, deren Gegenfunktion auf jeden Fall ausgeführt werden muss. Die zweite Funktion muss daher für den Fall einer Exception im finally Block stehen.

THX

Vielleicht kannst du dir Delphis Arme-Leute-RAII aka Interfaces zunutze machen. Sowas in der Art:

Delphi-Quellcode:

interface

type
  ICursorGuard = interface
  end;

function GuardCursor(NewCursor: TCursor = crHourGlass): ICursorGuard;

implementation

type
  TCursorGuard = class(TInterfacedObject, ICursorGuard)
  private
    FOldCursor: TCursor;
  public
    constructor Create(NewCursor: TCursor);
    destructor Destroy; override;
  end;

{ TCursorGuard }

constructor TCursorGuard.Create(NewCursor: TCursor);
begin
  inherited Create;
  FOldCursor := Screen.Cursor;
  Screen.Cursor := NewCursor;
end;

destructor TCursorGuard.Destroy;
begin
  Screen.Cursor := FOldCursor;
  inherited Destroy;
end;

function GuardCursor(NewCursor: TCursor = crHourGlass): ICursorGuard;
begin
  Result := TCursorGuard.Create(NewCursor);
end;

Das benutzt man dann so:

Delphi-Quellcode:

procedure Test;
var
  Guard: ICursorGuard;
begin
  Guard := GuardCursor; // <= Hier wird die Sanduhr angezeigt.
  // Was länger dauerndes...
end; // <= Hier wird der alte Cursor wiederhergestellt.

Wer hier das Aufräumen abklemmt, muss dass eigentlich schon mit Absicht so machen.