Event in andere Form übertragen

[Digielm]

Hallo zusammen

ich habe ein Problem. Ich erstelle grade eine seperate Form (unterform) die zur Laufzeit in eine vorhandene (Hauptform) eingebunden wird und in einem Panel dargestellt wird.
Auf der Form gibt es div. onclick events. Mein Problem wie bekomme ich das auf der Hauptform mit wenn auf der Unterform ein bestimmter button gedrückt wird oder innerhalb ein anderes Event auftritt ??

Ich stehe da grade auch dem Schlauch.

arbeite grade mit Delphi 2009 Win32

[Björn Ole]

Das Beispiel ist jetzt vielleicht etwas zu groß, aber so ähnlich hatte ich das mal umgesetzt.
Ich erstelle einfach ein neues Event (TOnSpecialClick) für das zweite Formular und weise nach dem Create diesem eine Methode des Hauptformulars zu.

Delphi-Quellcode:

{ MainForm }
type
  TMainForm = class(TForm)
    Button: TButton;
    procedure ButtonClick(Sender: TObject);
  private
    // wird aufgerufen, wenn auf dem zur Laufzeit erstellen Formular ein Butten gedrückt wird
    procedure OnSpecialFormClick(Sender: TObject; const ASpecialText: string); 
  end;

{...}

procedure TMainForm.ButtonClick(Sender: TObject);
var
  SpecialForm: TSpecialForm;
begin
  SpecialForm := TSpecialForm.Create(nil);
  try
    SpecialForm.OnSpecialClick := Self.OnSpecialFormClick;
    SpecialForm.ShowModal;
  finally
    SpecialForm.Free;
  end;
end;

procedure TMainForm.OnSpecialFormClick(Sender: TObject; const ASpecialText: string);
begin
  ShowMessage(Format('%s clicked. Text: %s', [TComponent(Sender).Name, ASpecialText]));
end;

Delphi-Quellcode:

{ SpecialForm }
type
  TOnSpecialClick = procedure(Sender: TObject; const ASpecialText: string) of object;

  TSpecialForm = class(TForm)
    SpecialButton1: TButton;
    SpecialButton2: TButton;
    SpecialEdit: TEdit;
    // OnClick Event für beide Buttons    
    procedure SpecialButtonClick(Sender: TObject);
  private
    FOnSpecialClick: TOnSpecialClick;
  public
    property OnSpecialClick: TOnSpecialClick read FOnSpecialClick write FOnSpecialClick;
  end;

{...}

procedure TSpecialForm.SpecialButtonClick(Sender: TObject);
begin
  if Assigned(FOnSpecialClick) then
    FOnSpecialClick(Sender, SpecialEdit.Text);
end;

[hboy]

Du kannst zum Beispiel eine TNotifyEvent-Variable beim eingebetteten TForm-Objekt anbieten, bei der sich das Hauptformular mit einem event handler eintragen kann.
Dann überschreibst du den message handler des Unterformulars mit

Delphi-Quellcode:

  protected
    procedure WndProc(var Message: TMessage); override;

mit

Delphi-Quellcode:

procedure TForm2.WndProc(var Message: TMessage);
begin
  inherited WndProc(Message);
  if assigned(NotifyMainFormEvent) then NotifyMainFormEvent(self);
end;

(ps. hier müsstest du die message in einer public-Variable zugänglich machen oder einen eigenen Eventtyp als procedure of object definieren, bei dem standardmäßig ein var-Parameter übergeben wird)


alternativ kannst du auch beim Hauptformular eigene messages definieren und mit

procedure OnForwardedFormEvent(var Message: TMessage); Message WM_IRGENDWAS;
abarbeiten, dabei ist WM_IRGENDWAS >= WM_USER. Du schickst dann Messages aus dem Unterformular heraus an das Hauptformular (PostMessage, SendMessage).

letzteres funktioniert auch über Threadgrenzen hinaus.

[Digielm]

Hat sich erledigt

ich habs mit ner Property gemacht und genau das erreicht was ich in diesem Fall wollte.

Danke aber trotzdem für die Antworten