Logging in Form aus anderer Unit steuern

[gssaug]

Hallo,

ich habe eine Prozedur, welche bei der Auslösung eines Events ausgeführt wird.

Delphi-Quellcode:

procedure TfrmMain.ConsoleLineOut(const Line: String);
begin
  Log.Lines.Add(Line);
end;

Das Event

Delphi-Quellcode:

  
ConsoleLineOut.OnLineOut := ConsoleLineOutLineOut;

wird aber in einer anderen Unit ausgelöst. Ich will keine Referenz auf die Form Klasse, da sonst eine zirkuäre Abhängigkeit entsteht und Logik nichts in der Form zu suchen hat.

Wenn also das Event in meiner anderen Unit ausgelöst wird, dann soll in den Log vom Typ TMemo in der Form ein Lines.Add ausgeführt werden. Kann man das überhaupt irgendwie machen, ohne das die beiden Klassen sich kennen? Gibt es Trace Klassen etc.?


Danke Vielmals

PS: Oder gibts eine Quick and Dirty Variante?
Gleiches Problem, leider ungelöst: http://entwickler-forum.de/archive/i...p/t-21154.html

[seifman]

Ich mache das ganze über Messages.

In der Form, in der auch das Logging geschieht, gibt es die Methode WMWriteLog.

procedure WMWriteLog(var AMessage : TMessage); message WM_WRITELOG;

Delphi-Quellcode:

procedure TfrmMain.WMWriteLog(var AMessage: TMessage);
var
  lMessage : PChar;
begin
  lMessage := PChar(AMessage.WParam);
  if (Length(lMessage) > 0) then
    FLog.Add(lMessage);

  StrDispose(lMessage);
end;

An den Stellen, wo ich etwas an das Log übergeben will nutze ich dann "SendMessage" um meinen Text zu an die Form zu schicken.

Delphi-Quellcode:

procedure WriteLog(AMessage: string);
var
  lMessage : PChar;
begin
  lMessage := StrAlloc(Succ(Length(AMessage)));
  StrPCopy(lMessage, AMessage);
  SendMessage(FParentHandle, WM_WRITELOG, integer(lMessage), 0);
  Application.ProcessMessages;  
end;

Ob das nun die sauberste Lösung ist, kann ich nicht versprechen - sie funktioniert aber.

[gssaug]

OK ich hänge an der Stelle, wo ich dem SendMessage ein Objekt vom Typ HWND übergeben muss. Dieses erzeuge ich durch beispielsweise self.handle. Mein Objekt vom Typ meiner Klasse hat aber kein Handle. Wie kann ich das hinzufügen oder muss ich einen eigenen Handler schreiben.

Was ist HWND überhaupt für ein typ?

Danke vielmals aber für die Idee

[DeddyH]

HWND ist ein Fensterhandle.

[sx2008]

Wenn man das Logging elegant und flexibel machen möchte, dann braucht man zunächst eine abstrakte Basisklasse oder ein Interface.

Delphi-Quellcode:

unit MyLogger; // eigene Unit

interface
type

TCustomLogger=class(TPersistent)
public
  procedure LogMsg(level:integer; const msg:string);virtual;abstract;
end;

Davon werden nun eine oder mehrere konkrete Logging-Klassen abgeleitet:

Delphi-Quellcode:

TStringsLogger = class(TCustomLogger)
private
  FList : TStrings;
public
  constructor Create(list:TStrings);
  // "level" dient dazu, verschieden Logmeldung (Fehler, Warnung, Info)
  // voneinander zu trennen
  procedure LogMsg(level:integer; const msg:string);override;
end;

implementation

constructor TStringsLogger.Create(list:TStrings);
begin
  inherited Create;
  FList := list;
end;

procedure TStringsLogger.LogMsg(level:integer; const msg:string);override;
begin
  FList.Add(TimeToStr(Now)+' ('+IntToStr(level)+') '+msg;
end;

Im Hauptformular oder dort wo man die Log-Ausgabe sehen möchte erzeugt man ein Objekt der Klasse TStringsLogger:

Delphi-Quellcode:

procedure TFrmMain.FormCreate(Sender:TObject);
begin
  // Logger-Objekt erzeugen und gleich an ein Memo-Feld anbinden
  FLogger := TStringsLogger.Create(MemoLog.Lines);
end;

procedure TfrmMain.ConsoleLineOut(const Line: String);
begin
  Flogger.LogMsg(0, Line);
end;

Der "Trick" ist nun, dass das Hauptformular das Logger-Objekt in das Unterformular einspeist.
Man nennt das Dependency Injection.

Delphi-Quellcode:

procedure TFrmMain.ZeigeUnterformular;
begin
  if not Assigned(FrmIrgendwas) then
    FrmIrgendwas := TFrmIrgendwas.Create(Application);
  FrmIrgendwas.Logger := FLogger;  // Logger-Objekt weitergeben/einspeisen
  FrmIrgendwas.Show;
end;

Das Unterformular sieht so aus:

Delphi-Quellcode:

uses MyLogger;

TFrmIrgendwas = Class(TForm)
  ...
public
  // wird von aussen zugewiesen
  Logger : TCustomLogger;
  Procedure Test;
end;

Procedure TFrmIrgendwas.Test;
begin
  Logger.LogMsg(99, 'Das ist eine Log-Meldung aus TFrmIrgendwas.Test');
end;

Sourcecode ohne Delphi-IDE eingehackt-kleine Schreibfehler bitte selber korrigieren

Das Hauptformular und das Unterformular arbeiten jetzt mit dem gleichen Logger-Objekt.
Meldungen vom Hauptformular und vom Unterformular laufen über das Logger-Objekt
in ein gemeinsames Memo-Feld.
Man könnte die Klasse TStringsLogger leicht durch eine andere Klasse z.B. TFileLogger austauschen
und die Log-Ausgabe in eine Datei schreiben.
Auch ein Kombination aus direkter Anzeige und Schreiben in eine Datei ist möglich.

Die Klassenstruktur die ich hier gezeigt habe ist flexibel und ohne zirkuläre Abhängigkeiten.

Mit einem Interface anstelle einer abstrakten Basisklasse ist noch mehr möglich,
aber das soll erst einmal reichen.

[gssaug]

Danke Vielmals. Das ist eine gute Antwort!