Free, FreeAndNil und mehrere Variablen

[knochen]

Hallo zusammen,


folgendes Testprogramm (Delphi 2010):

Delphi-Quellcode:

procedure TForm2.Button3Click(Sender: TObject);
var
  a, b: TObject;

begin
  a := TObject.Create;
  b := a;

  Memo1.Lines.Add(IntToStr(Integer(a)));   // --> 12003408
  Memo1.Lines.Add(IntToStr(Integer(b)));   // --> 12003408

  a.Free;   // mit FreeAndNil(a) ist der Effekt derselbe
  a := nil;

  Memo1.Lines.Add('');

  Memo1.Lines.Add(IntToStr(Integer(a)));   // --> 0
  Memo1.Lines.Add(IntToStr(Integer(b)));   // --> 12003408

end;

Durch die Zuweisung b := a; enthält b einen Verweis auf dasselbe Objekt wie a.
Nachdem a auf nil gesetzt wurde, ergibt Integer(b) immer noch besagte Zahl(s.o.)
Natürlich will ich nicht mit Zahlen herumjonglieren, o.g. Testprogramm dient nur der Veranschaulichung. Fakt ist, dass nachdem a gefreet und genilt wurde, Assigned(b) immer noch True ergibt. Arbeite ich mit diesem "Objekt", so kommt es natürlich früher oder später zu einer Fehlermeldung/ Schutzverletzung.

Kann ich irgenwie erreichen, dass Assigned(b) auch False ist, nachdem a freigegeben wurde?

Vielen Dank im Voraus.

[mleyen]

Dieses Problem gab es schon ein paar Male: 1, 2
Ich hoffe dies hilft dir weiter.

[Neutral General]

Das ist in meinen Augen kein Problem, sondern total logisch und auch nicht vermeidbar.

[blackfin]

wenn du das genau so haben willst, nimm doch nen pointer auf das TObject:

Delphi-Quellcode:

var
  a: TObject;
  b: ^TObject ;

begin
  a := TObject.Create;
  b := @a;

  Memo1.Lines.Clear() ;

  Memo1.Lines.Add('a: ' + IntToStr(Integer(a)));
  Memo1.Lines.Add('b: ' + IntToStr(Integer(b)));
  Memo1.Lines.Add('assigned(b): ' + BoolToStr(Assigned(b^))) ;   // -1 --> true

  a.Free;
  a := nil;

  Memo1.Lines.Add('after free:');

  Memo1.Lines.Add('a: ' + IntToStr(Integer(a)));
  Memo1.Lines.Add('b: ' + IntToStr(Integer(b)));
  Memo1.Lines.Add('assigned(b): ' + BoolToStr(Assigned(b^))) ; // 0 --> false

end;

[himitsu]

- TObjekt ist nunmal nur ein Zeiger auf ein Objekt
(nur weil man das Objekt löscht, ändern sich nicht alle Zeiger ... und du änderst nunmal nur A)
- A und B kennen sich nicht


* TOpjekt/Pointer ist ein Zeiger
* ein Zeiger ist nur eine Adresse, also für den PC blos eine Zahl
tja, was erwartest du denn nun hier?

Delphi-Quellcode:

procedure TForm2.Button3Click(Sender: TObject);
var
  a, b: Integer;

begin
  a := 123456;
  b := a;

  Memo1.Lines.Add(IntToStr(a));   // --> 123456
  Memo1.Lines.Add(IntToStr(b));   // --> 123456

  a := 0;

  Memo1.Lines.Add('');

  Memo1.Lines.Add(IntToStr(Integer(a)));   // --> 0
  Memo1.Lines.Add(IntToStr(Integer(b)));   // --> 123456
end;

Und jetzt die Frage:
was möchstest du denn erreichen?

a) daß B den wert von A hat (siehe blackfin)
oder
b) daß das Objekt erst freigegeben wird, wenn auch B auf "nil" steht (siehe Interfaces) ?

[mkinzler]

Das Problem ist, dass der Speicher wohl bei .Free nicht gelöscht wird. So zeigt b immer noch auf den Speicherbereich.

[himitsu]

Selbst wenn der Speicher gelöscht würde, dann würde B immernoch auf diese Stelle zeigen.
Was der Speichermanager nun genau macht, das kann man natürlich nicht bestimmen.

Aber es ist ja egal, ob nun der Speicher wirklich freigegeben würde,
kann man sowas nicht machen.

Ob nun etwas Altes angezeigt wird, oder es eine Zugriffsverletzung gibt, wenn man drauf zugreifen ... es kann immernoch passieren, daß inzwischen ein anderes Objekt erzeugt wurde, welches zufälig an der Stelle liegt ....

Man sollte sich einfach im Klaren sein, daß der Objektzeiger eben nur ein Zeiger auf ein Objekt ist
und daß man beim Kopieren dieses Zeigers eben aufpassen muß.

anderes Beispiel:

Delphi-Quellcode:

var
  a, b: THaus;

begin
  // THaus.Create baut ein Haus
  // a ist ein Zettel, auf welchen die Adressse draufgeschrieben wird
  a := THaus.Create;
  // b ist eine Kopie dises Zettels
  b := a;

  Memo1.Lines.Add(a.AdresseAblesen);
  Memo1.Lines.Add(b.AdresseAblesen);

  // das Haus wird zerstört
  a.Free;
  // der Zettel wird vernichtet (alles wird mit Weiß übermalt)
  a := nil;

  // geht nicht, da der Text ja gelöscht wurde
  Memo1.Lines.Add(a.AdresseAblesen);
  // tja, hier steht dennoch die Adresse drauf,
  // selbst wenn das Haus vernichtet und der andere Zettel überschrieben wurde
  Memo1.Lines.Add(b.AdresseAblesen);
end;

bezüglich dem ausgelesenen Wert von B
- der Speichermanager vernichtet nicht alles sofort, wenn man es ihm sagt ... vielleicht benötigt man den Baugrund ja demnächst gleich wieder ... drum kann man eventuell noch was auslesen
- wenn es doch schon gelöscht wurde, dann knallt es natürlich, weil du beim betreten des "Hauses" in ein tiefes Loch fällst
- inzwischen könnte ja auch schon ein neues Haus gebaut wurden sein, dann zeigt die Adresse natürlich immernoch auf etwas ... blos halt was Anderes