ReadFile

[n3r0f0x]

Hi,

ich möchte mit delhi eine Datei in einen String umwandeln. In Delphi7 hat das auch ganz gut geklappt mit:

Delphi-Quellcode:

function ReadFile(FileName: String): AnsiString;
var
  F             :File;
  Buffer        :AnsiString;
  Size          :Integer;
  ReadBytes     :Integer;
  DefaultFileMode:Byte;
begin
  Result := '';
  DefaultFileMode := FileMode;
  FileMode := 0;
  AssignFile(F, FileName);
  Reset(F, 1);

  if (IOResult = 0) then
  begin
    Size := FileSize(F);
    while (Size > 1024) do
    begin
      SetLength(Buffer, 1024);
      BlockRead(F, Buffer[1], 1024, ReadBytes);
      Result := Result + Buffer;
      Dec(Size, ReadBytes);
    end;
    SetLength(Buffer, Size);
    BlockRead(F, Buffer[1], Size);
    Result := Result + Buffer;
    CloseFile(F);
  end;

  FileMode := DefaultFileMode;
end;

Nach dem umstieg auf Delphi 2010 geht leider nichts mehr. Wenn ich nun eine Datei umwandel gibt er mir immer

Zitat:

MZP

aus.

Hat wer ne Idee?

mfg nerofox

[Astat]

Hallo n3r0f0x.

Delphi-Quellcode:

function ReadFile(const FileName: String): AnsiString;
var
  ms: TMemoryStream;
begin
  ms := TMemoryStream.Create;
  ms.LoadFromFile(FileName);
  setLength(Result, ms.size);
  move(ms.memory^, Result[1], ms.Size);
  ms.Free;
end;

PS. MZP ist ein PE-File, wenn Du den String anzeigen willst, geht dies nur bis #0
Hier ist Result wie ein Buffer zu verwenden, also länge durchiterieren und in Hex etc. konvertieren.

// EDIT Auf Anregung hier ohne Memory Stream

Delphi-Quellcode:

{$R+} {$Q+} {$I+}
function FileToStringEx(const AFileName: AnsiString): AnsiString;
var
  hFile: DWORD;
  cbLen, cbRead: DWORD;
begin
  hFile := CreateFile(PAnsiChar(AFileName), GENERIC_READ, 0, nil, OPEN_EXISTING,
    FILE_ATTRIBUTE_NORMAL, 0);
  cbLen := GetFileSize(hFile, nil);
  if hFile  <> INVALID_HANDLE_VALUE then begin
    SetLength(Result, cbLen);
    if not ReadFile(hFile, Result[1], cbLen, cbRead, nil) then
      raise Exception.Create('ERROR ReadFile');
    CloseHandle(hFile);
  end;
end;
{$R-} {$Q-} {$I-}

lg. Astat

[n3r0f0x]

danke...

[sx2008]

Zitat von Astat:

Delphi-Quellcode:

function ReadFile(const FileName: String): AnsiString;
var
  ms: TMemoryStream;
begin
  ms := TMemoryStream.Create;
  ms.LoadFromFile(FileName);
  setLength(Result, ms.size);
  move(ms.memory^, Result[1], ms.Size);
  ms.Free;
end;

Hier wird aber Speicher in der doppelten Grösse der Datei verwendet.
Man sollte die Funktion schnell entsorgen bevor sie im Internet immer weiter kopiert wird.
Hier der Ersatz:

Delphi-Quellcode:

function FileToString(const AFileName: string): AnsiString;
var
  f: TFileStream;
  l: Integer;
begin
  Result := '';
  f := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyWrite);
  try
    l := f.Size;
    if L > 0 then
    begin
      SetLength(Result, l);
      F.ReadBuffer(Result[1], l);
    end;
  finally
    F.Free;
  end;
end;

[Astat]

Zitat von sx2008:

Delphi-Quellcode:

function FileToString(const AFileName: string): AnsiString;
var
  f: TFileStream;
  l: Integer;
begin
  Result := '';
  f := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyWrite);
  try
    l := f.Size;
    if L > 0 then
    begin
      SetLength(Result, l);
      F.ReadBuffer(Result[1], l);
    end;
  finally
    F.Free;
  end;
end;

Hier wird aber Speicher in der einfachen Grösse der Datei verwendet.
Man sollte die Funktion schnell entsorgen bevor sie im Internet immer weiter kopiert wird.
Hier der Ersatz:

Delphi-Quellcode:

function FileToMap(const AFileName: AnsiString; out cbSize, dwError: DWORD): pointer;
var
  hFile, hMap: DWORD;
begin
  result := nil;
  dwError := NO_ERROR;
  hFile := CreateFile(PAnsiChar(AFileName), GENERIC_READ, 0, nil, OPEN_EXISTING,
    FILE_ATTRIBUTE_NORMAL, 0);
  if hFile  <> INVALID_HANDLE_VALUE then begin
    cbSize := GetFileSize(hFile, nil);
    if cbSize <> INVALID_FILE_SIZE then begin
      hMap := CreateFileMapping(hFile, nil, PAGE_READONLY or SEC_COMMIT, 0,
        cbSize, nil);
      if (hMap <> 0) then begin
        result := MapViewOfFile(hMap, FILE_MAP_READ, 0, 0, 0);
        CloseHandle(hMap);
      end else
        dwError := GetLastError;
    end else
      dwError := GetLastError;
    CloseHandle(hFile);
  end else
    dwError := GetLastError;
end;

// EDIT: nach gebrauch mit

Delphi-Quellcode:

 

UnmapViewOfFile(Pointer);

aufräumen.

[sx2008]

...da bin ich wohl jemand auf den Schlips getreten, sorry.
Ich würde trotzdem die einfache Funktion FileToString() verwenden und Memory Mapped Files nur bei sehr grossen Dateien einsetzen.

[Astat]

Zitat von sx2008:

...da bin ich wohl jemand auf den Schlips getreten, sorry.
Ich würde trotzdem die einfache Funktion FileToString() verwenden und Memory Mapped Files nur bei sehr grossen Dateien einsetzen.

Hallo sx2008, ja, bin da natürlich auch Deiner Meinung, hab wohl einen schlechten Tag erwischt, auch sorry.



lg. Astat

[n3r0f0x]

Danke erstma

Aber Leider bekomm ichs immer noch nix zum laufen ...

Ich hab alle eure Funktionen Probiert aber als Ergebniss bekomme ich entweder einen Lehrstring oder MZP. Ich möchte aber eine Datei in einen String einlesen und diese von dort aus wieder abspeichern.

mfg

nerofox

[nat]

woher weißt du denn, dass du wirklich nur 'MZP' bekommst?
kann es sein, dass du dir das über ein memo ausgeben lässt?

[p80286]

Zitat von n3r0f0x:

Ich möchte aber eine Datei in einen String einlesen und diese von dort aus wieder abspeichern.

Warum denn das?

ein String ist zunächst einmal für Text-Informationen gedacht. Sobald irgendein Programmteil (und sei es das Betriebssystem) anfängt diese Daten zu interpretieren, dann sind sie zerbröselt! (MZP)

Wenn Du schon Daten kopieren willst, (wofür gibt es eigentlich "copy"?)
Dann lies die Daten in ein " Buffer : array [0..x] of Byte (oder Integer oder...)" ein und schreib sie danach gleich wieder weg. Und wenn Du wissen willst was drin steht, dann schau's dir halt mit "inttohex" an!

Ja man kann auch einen String als Puffer benutzen, man kann auch zu foß nach Kölle jon.

gruß
K-H