Windows 64 bit und Postmessage (Multimediatasten abfangen)

[Bomberbb]

Hallo,

ich hab seit dem Wechsel auf Windows 7 x64 Probleme mit Postmessage und Sendmessage.

zum einen hab ich hier schon einen Thread SaveWatchList, bei dem ich auch schon Probleme damit habe. Das andere, will ich hier ansprechen. Ich will die Multimediatasten abfangen und selber verarbeiten, damit ich die Tasten neu belegen kann. Das ganze habe ich so programmiert:

Delphi-Quellcode:

Library keyboardhook;

Uses
  Windows,
  Messages,
  Dialogs,
  SysUtils;

Var
  HookHandle                            :Cardinal=0;
  AppHandle                             :HWND;

Function KeyboardHookProc (nCode:Integer;wParam:WPARAM;lParam:LPARAM) :LRESULT; Stdcall;
Begin
  Result := CallNextHookEx (HookHandle,nCode,wParam,lParam) ;
  If (nCode<>HC_NOREMOVE) And (nCode=HC_ACTION)
    And (wParam In [$A6..$B7]) //Nur Multimediatasten
  And (lParam=16777217) //Nur KeyDown
  Then
  Begin
    Beep;
    PostMessage (AppHandle,WM_USER+1235,wParam,lParam) ;
  End;
End;

Function InstallHook (ApplicationHandle:HWND) :Boolean; Stdcall;
Begin
  Result := False;
  If HookHandle=0 Then
  Begin
    HookHandle := SetWindowsHookEx (WH_KEYBOARD,
      @KeyboardHookProc,
      HInstance,
      0) ;
    AppHandle := ApplicationHandle;
    Result := True;
  End;
End;

Function UninstallHook:Boolean; Stdcall;
Begin
  Result := UnhookWindowsHookEx (HookHandle) ;
  HookHandle := 0;
End;

Exports
  InstallHook,
  UninstallHook;
End.

Delphi-Quellcode:

Unit Unit1;

Interface

Uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Forms;

Type
  TForm1=Class(TForm)
    Procedure FormClose(Sender:TObject;Var Action:TCloseAction);
    Procedure Afterformcreate;
  Private
    Procedure DllMessage(Var Msg:TMessage); Message WM_USER+1235;
  End;

Function InstallHook(AppHandle:HWND):Boolean;stdcall;external'keyboardhook.dll';
Function UninstallHook:Boolean;stdcall;external'keyboardhook.dll';
Var
  Form1                                 :tForm1;

Implementation

{$R *.dfm}

Procedure TForm1.FormClose(Sender:TObject;Var Action:TCloseAction);
Begin
  UninstallHook;
End;

Procedure TForm1.DllMessage(Var Msg:TMessage);
Const
  //  BROWSERTASTEN:
  VK_BROWSER_BACK                       =$A6;
  VK_BROWSER_FORWARD                    =$A7;
  VK_BROWSER_REFRESH                    =$A8;
  VK_BROWSER_STOP                       =$A9;
  VK_BROWSER_SEARCH                     =$AA;
  VK_BROWSER_FAVORITES                  =$AB;
  VK_BROWSER_HOME                       =$AC;
  //--------------------------------

  //  MULTIMEDIATASTEN:
  VK_VOLUME_MUTE                        =$AD;
  VK_VOLUME_DOWN                        =$AE;
  VK_VOLUME_UP                          =$AF;
  VK_MEDIA_NEXT_TRACK                   =$B0;
  VK_MEDIA_PREV_TRACK                   =$B1;
  VK_MEDIA_STOP                         =$B2;
  VK_MEDIA_PLAY_PAUSE                   =$B3;
  //--------------------------------

  //  ZUSATZTASTEN:
  VK_LAUNCH_MAIL                        =$B4;
  VK_LAUNCH_MEDIA_SELECT                =$B5;
  VK_LAUNCH_APP1                        =$B6;
  VK_LAUNCH_APP2                        =$B7;
Begin
  If Msg.WParam In [$A6..$B7] Then
  Begin
    Sleep(100);
    Beep;
  End;
End;

Procedure TForm1.AfterFormcreate;
Begin
  InstallHook(Handle);
End;

End.

Bei manchen Anwendungen Beept es 2 mal, bei anderen Anwendungen nur einmal, was mich darauf schließen läßt, dass die Postmessage nicht funktioniert...

Und noch eine andere Frage, ich möchte nicht, dass eine andere Anwendung den Tastendruck noch verarbeitet. ist das möglich?

Gruß

BBB

[Astat]

Hallo Bomberbb.

Damit alle Applikationen unter 64 Bit gehookt werden, muss man einen WOW32 Hook und einen 64 Bit Hook erstellen.
Mit Delphi ist nur ein WOW32 Hook möglich, da Delphi keinen 64Bit Compiler besitzt.
Für einen 64Bit Hook, FPC verwenden.


Also: 32 Bit Applikationen 32 Bit Hook, 64 Bit Applikationen 64 Bit Hook

lg. Astat

[Bomberbb]

Im Debugger konnte ich einen Haltepunkt bei
PostMessage (AppHandle,WM_USER+1235,wParam,lParam) ; setzen, deshalb hab ich gedacht, der hook hätte funktioniert. Nur leider scheint die Nachricht nicht anzukommen. Habe ein ähnliches Problem auch in der anderen Anwendung, bei denen die Nachrichten nur sporadisch ankommen. Dabei ist inder anderen Anwendung gar kein Hook vorhanden...

z. B. funktioniert dieses Programm, wenn Notepad, was meines Wissens nach 32bit ist, oder Speedcommander in der 64Bitversion den Fokus haben, allerdings nicht wenn Firefox oder Thunderbird aus (beide 32 Bit) fokussiert sind.

[Astat]

Hi, in deiner Hook Prozedure

Function InstallHook (ApplicationHandle:HWND) :Boolean; Stdcall; übergibst du das Application Handle, dies geht aber verloren, da du es nicht global für alle gehookten Prozesse abspeicherst.

Vorgang:

1. Hook wird mit Installhook initialisiert.
2. Windows lädt nun in alle laufenden 32 Bit Prozesse, mit Ausnahmen wegen Privileges, abgesehen die angegebene Hook-dll.
3. In der HookDll des Prozesses X ist das Handle somit unbekannt, und kann nicht funktionieren.

Ändern:
1. Handle in Memory Mapped File zwischenspeichern und aus diesem auslesen.
2. Etwas unschöner, handle in der Registry speichern und von dort auslesen.

lg. Astat

[Bomberbb]

Danke, ich werde es wohl erst mal mit der einfachen Variante probieren und mich dann mit dem Memory Mapped File beschäftigen...

[Bomberbb]

So, nun läuft es wie gewollt. Nun wollte ich Euch aber zumindest meine Lösung noch posten.
Zum einen war das übergebene Handle falsch. Nun übergebe ich es nicht mehr, sondern setze es mit Findwindows in Installhook. Eine weiters Problem war die Zeile
(lParam=16777217) //Nur KeyDown hier wurden manche events doppelt verarbeitet. Das hab ich in
(lParam And (1 Shl 31) <>0)then //Nur KeyUp geändert und mit diesen beiden Änderungen klappt es wunderbar.

Delphi-Quellcode:

Library keyboardhook;

Uses
  Windows,
  Messages,
  Dialogs,
  SysUtils;

Var
  HookHandle                            :Cardinal=0;
  AppHandle                             :HWND;

Function KeyboardHookProc (nCode:Integer;wParam:WPARAM;lParam:LPARAM) :LRESULT; Stdcall;
Begin
  Result := CallNextHookEx (HookHandle,nCode,wParam,lParam) ;
  If (nCode<>HC_NOREMOVE) And (nCode=HC_ACTION)
    And (lParam And (1 Shl 31) <>0)then //Nur KeyUp
     if (wParam In [$B1..$B3]) //Nur Multimediatasten
     then
  Begin
    AppHandle := FindWindow ('TfrmKeyMakro',Nil) ;
    If AppHandle<>0 Then
      PostMessage (AppHandle,WM_USER+1235,wParam,lParam) ;
  End;

End;

Function InstallHook :Boolean; Stdcall;
Begin
  Result := False;
  If HookHandle=0 Then
  Begin
    HookHandle := SetWindowsHookEx (WH_KEYBOARD,
      @KeyboardHookProc,
      HInstance,
      0) ;
    AppHandle := FindWindow ('TForm1',Nil) ;
    Result := True;
  End;
End;

Function UninstallHook:Boolean; Stdcall;
Begin
  Result := UnhookWindowsHookEx (HookHandle) ;
  HookHandle := 0;
End;

Exports
  InstallHook,
  UninstallHook;
End.

Ich habe aber noch eine andere Alternative zu bieten, die ich im Netz gefunden habe. Wenn man nur eine Sondertaste mit einem Programm belegen will geht einfacher mit der registry

und zwar unter

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\Curr entVersion\Explorer\AppKey

Ich hoffe, es das post hilft noch anderen.

Gruß

BBB