TCheckListbox, per MouseMove den Check-Status setzen

[taaktaak]

Moin, Moin.

Habe mich immer wieder geärgert, wie umständlich es bei einer größeren Menge von Einträgen ist, den Check-Status zu verändern. Meist gibt es dann zusätzliche Buttons und/oder Tastenkombinationen, die diese Tätigkeit beschleunigen helfen. Heute habe ich mal nach einer alternativen Lösung gesucht und etwas gebastelt, das mir im Ergebnis recht bedienbar erscheint und das ich hier (mit beipielhaftem Code) vorstellen möchte.

Bedienung:
Eine vertikale Bewegung mit gedrückter linker Maustaste über den Listeneinträgen setzt den Check-Status, die Bewegung mit gedrückter rechter Maustaste hebt den Check-Status auf. Die Funktionalität ist nur rechts der dargestellten Checkboxen über dem Texteintrag verfügbar.

Delphi-Quellcode:

var DownLeft  : Boolean; // Kontrollvariablen
    DownRight : Boolean; // (unitglobal) 
    LastIdx   : Integer; // ..
    Modified  : Boolean; // .

procedure TfoMain.clbMouseDown(Sender:TObject;Button:TMouseButton;Shift:TShiftState;X,Y:Integer);
begin
  DownLeft :=(Button=mbLeft );
  DownRight:=(Button=mbRight);
  LastIdx  :=-1;
  Modified :=false;
end;

procedure TfoMain.clbMouseMove(Sender:TObject;Shift:TShiftState;X,Y:Integer);
var Idx : Integer;
begin
  if X>15 then                            // nicht im Bereich der Checkboxen
    if DownLeft  or
       DownRight then

      with TCheckListbox(Sender) do begin
    
        Idx:=ItemAtPos(Point(X,Y),true);
        if (Idx>=0) and                   // nur Zeilen mit Inhalt
           (Idx<>LastIdx) then begin      // jede Zeile nur 1x behandeln
     
          if DownLeft then begin
            
            if not(Modified) then Modified:=(Checked[Idx]=false);
            Checked[Idx]:=true
            end
                      else begin
            
            if not(Modified) then Modified:=(Checked[Idx]=true);
            Checked[Idx]:=false
            end;

          LastIdx:=Idx
          end
        end
end;

procedure TfoMain.clbMouseUp(Sender:TObject;Button:TMouseButton;Shift:TShiftState;X,Y:Integer);
begin
  DownLeft :=false;
  DownRight:=false;
  if Modified then begin
    // wenn CheckStatus verändert
    // z.B. OnClickCheck-Event aufrufen
    end
end;