Formatieren einzelner Zellen in einem StringGrid

[KahPee]

Hallo,

ich arbeite im Moment mit einem Stringgrid und möchte verschiedene Zellen verschieden formatieren. Ich habe dazu um Forum schon einiges gefunden, allerdings läuft das ganze noch nicht einwandfrei. Wie ich herrausbekommen hab muss man bei einem Stringgrid ein bisschen "schummeln" aber gut.
In meinem Fall geht es vor allem um die Formatierung der Hintergrundfarbe und der Schrift. In dem Oncreate-Ereignis der Form lege ich für die einzelnen Zellen teilweise schon Text fest, anderen Zellen wird erst später ein Text, bzw. ein neuer Text zu gewiesen. Die Formatierung der Zellen soll über die ganze Zeit gleich bleiben. Es ändert sich nur unter Umständen der Text.

Nun habe ich gelesen, dass ich die Formatierung der Zellen in dem ondraw-Ereignis des Stringgrids festlegen kann:

Delphi-Quellcode:

procedure TForm5.SgstatsDrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState); // das Stringgrid heißt 'sgstats'
begin
with TStringGrid(Sender).Canvas do begin
       if (ACol=1) and (ARow=1) then begin //später sollen es noch viel mehr Zellen formatiert werden es geht hier erstmal um eine Beispielzelle
          font.Style:=[fsBold];
          FillRect(Rect);
       end;
  end;
end;

Bei obigen code tritt das problem auf, dass jetzt der Text der in der Zelle [1,1] steht nicht mehr angezeigt wird.

Delphi-Quellcode:

DefaultDraw:=true; 
{Diese Eigenschaft soll ja irgendwie wichtig sein, wenn sie auf "false" steht wird beim OnCreate-Ereignis nichts mehr in die Zellen geschrieben}

Schon mal im Vorraus vielen Dank für die Hilfe.

Kahpee

[Wolfgang Mix]

Vielleicht hilft Dir dieser Codeschnipsel. Den habe ich schon öfter mißbraucht

Delphi-Quellcode:

procedure TForm3.FormCreate(Sender: TObject);
var
  Col, Row: integer;
begin
  // Set the sizes of the arrays
  SetLength(FG, Grid.ColCount, Grid.ColCount);
  SetLength(BG, Grid.ColCount, Grid.ColCount);
  // Initialize with default colors
  for Col := 0 to Grid.ColCount - 1 do begin
    for Row := 0 to Grid.RowCount - 1 do begin
      FG[Col, Row] := clBlack;
      BG[Col, Row] := clWhite;
    end;
  end;

end;

procedure TForm3.GridClick(Sender: TObject);
var
  Col, Row: integer;
  Colo1, Colo2, Colo3: byte;
begin
  Col := Grid.Col;
  Row := Grid.Row;
  // Calculate contrasting random colours
  Colo1 := 200 + Random(56);
  Colo2 := 200 + Random(56);
  Colo3 := 100 + Random(156);
  BG[Col, Row] := RGB(Colo1, Colo2, Colo3);
  FG[Col, Row] := RGB(255 - Colo3, 255 - Colo1, 255 - Colo2);
  // Set the text to be displayed
  Grid.Cells[Col, Row] := 'clicked';

end;


procedure TForm3.GridDrawCell(Sender: TObject; ACol, ARow: Integer;
          Rect: TRect;State: TGridDrawState);
var     S: string;
begin

  S := Grid.Cells[ACol, ARow];
  // Fill rectangle with colour
  Grid.Canvas.Brush.Color := BG[ACol, ARow];
  Grid.Canvas.FillRect(Rect);
  // Next, draw the text in the rectangle
  Grid.Canvas.Font.Color := FG[ACol, ARow];
  Grid.Canvas.TextOut(Rect.Left + 2, Rect.Top + 2, S);
end;

Gruß

Wolfgang

[KahPee]

Grid.Canvas.TextOut(Rect.Left + 2, Rect.Top + 2, S); Das war der entscheidene Befehl. Hätt man auch selber drauf kommen können vielen Dank!

[zeras]

Ich nutze die Module von TMS Software. Da ist ein Grid enthalten, was alles(?) kann. Manchmal schon zuviel, wenn man mal nur eine Eigenschaft ändern will, findet man dies gar nicht mehr.
Aber ansonsten sehr gut. Nicht zu verschweigen ist, dass es aber nicht umsonst ist. Der Preis hat sich aber auf jeden Fall schon rentiert.