Anfängerfrage: TMetafileCanvas.Create

[HJay]

Hallo! Ich habe eine Anfängerfrage zur Logik hinter der Erzeugung von Metafile-Objekten. Ich verstehe einfach die Syntax und die Logik hinter dem Aufruf nicht.

Delphi-Quellcode:

procedure MyDraw;
  var MetaGraphic : TMetafile;
begin
  MetaGraphic := TMetafile.Create;
  with TMetafileCanvas.Create(MetaGraphic, 0) do begin
    LineTo(10, 10); // beliebige Zeichenoperationen...
    Free; // "erzeugt" das fertige MetaGraphic-Objekt (?)
  end;
  MyCanvas.Draw(0, 0, MetaGraphic); // MetaGraphic enthält jetzt die Zeichenoperationen
  MetaGraphic.Free;
end;

Wieso kann man "with" auf ein Klassenobjekt anwenden, ohne dass es instantiiert wurde? TMetafileCanvas.Create ist auch keine Funktion, sondern Prozedur. Auf welches Objekt wird "with" hier angewendet? Ich gebe zu, ich habe wahrscheinlich was grundlegendes nicht verstanden, aber ich würde es gerne verstehen...

Jetzt noch die zentrale, praktische Frage, die mich eigentlich dazu gebracht hat: Wie könnte man die obige Prozedur OHNE Verwendung von "with" schreiben? Ich möchte nämlich eigentlich innerhalb der with-Klausel eine Prozedur mehrfach aufrufen und weiß nicht, wie ich innerhalb der Unterprozedur auf das TMetafileCanvas-Objekt zugreifen könnte:

Delphi-Quellcode:

procedure MyDraw;
  var MetaGraphic : TMetafile;
      A           : Integer;

  procedure DrawSomething(Angle:Integer);
  begin
    // hier sollen etliche Zeichenoperationen stehen, als ob sie unter "with" stehen würden
    LineTo(10, 10);
  end;

begin
  MetaGraphic := TMetafile.Create;  
  with TMetafileCanvas.Create(MetaGraphic, 0) do begin
    for A := 0 to 90 do DrawSomething(A);
    Free; 
  end;
  MyCanvas.Draw(0, 0, MetaGraphic);
  MetaGraphic.Free;
end;

Ich wäre sehr dankbar für Erklärung und Lösung!

[patti]

Du kannst doch ein Objekt des Typs "TMetaFileCanvas" per Hand erzeugen und anschließend wieder freigeben. Mach es doch einfach so:

Delphi-Quellcode:

procedure MyDraw; 
  var MetaGraphic : TMetafile; 
      MetaCanvas  : TMetafileCanvas; // <-- hier
      A           : Integer; 

  procedure DrawSomething(Angle:Integer); 
  begin 
    // hier sollen etliche Zeichenoperationen stehen, als ob sie unter "with" stehen würden 
    MetaCanvas.LineTo(10, 10); // <-- hier noch ein "MetaCanvas" davor
  end; 

begin 
  MetaGraphic := TMetafile.Create;
  //
  // lieber noch in einen try-finally-Block packen
  //
  try
    MetaCanvas := TMetafileCanvas.Create(MetaGraphic, 0);
    //
    try   
      for A := 0 to 90 do DrawSomething(A);
      //
      MyCanvas.Draw(0, 0, MetaGraphic); 
    finally
      MetaCanvas.Free;
    end; 
  finally
    MetaGraphic.Free;
  end;
end;

Hoffe, das hilft dir schonmal weiter.

MFG
Patti

PS: Willkommen in der DP

[HJay]

Vielen Dank, Patti, das hat sehr weitergeholfen. Wenn man das so sieht, sieht es auch ganz einfach und logisch aus. Mich hatte diese "with"-Konstruktion doch sehr verwirrt.

Danke!

[himitsu]

das With legt die übergebene Variable als aktuellen Namespace fest
und hier wurde auch noch eine temporäre Variable genutzt.

es ist also so, daß alle Funktionen/Namen erstmal in diesem Namespace gesucht werden

Delphi-Quellcode:

with TMetafileCanvas.Create(MetaGraphic, 0) do begin
  for A := 0 to 90 do DrawSomething(A);
  Free;
end;

Delphi-Quellcode:

var MC: TMetafileCanvas;

MC := TMetafileCanvas.Create(MetaGraphic, 0)
with MC do begin
  for A := 0 to 90 do {MC.}DrawSomething(A);
  {MC.}Free;
end;

Delphi-Quellcode:

var MC: TMetafileCanvas;

MC := TMetafileCanvas.Create(MetaGraphic, 0)
for A := 0 to 90 do MC.DrawSomething(A);
MC.Free;

[patti]

Zitat von HJay:

Vielen Dank, Patti, das hat sehr weitergeholfen. Wenn man das so sieht, sieht es auch ganz einfach und logisch aus. Mich hatte diese "with"-Konstruktion doch sehr verwirrt.

Danke!

Diese "with"-Konstruktionen sind auch nicht sonderlich beliebt, da nicht wirklich übersichtlich etc.. Habe schon von Unternehmen gehört, die ihren Mitarbeitern "verboten" haben, diese zu benutzen. Auf der anderen Seite sind sie aber auch ganz nützlich. Wo ich sie relativ häufig einsetze, ist tatsächlich bei Zeichen-Aktionen auf einer Canvas, also z.B.

Delphi-Quellcode:

with Self.Canvas do
begin
  Pen.Color := clBlack;
  // usw...
end;

Ich denke, dass es letztlich Geschmackssache ist, ob man sie nutzt oder eben nicht.

Patti

[himitsu]

Ja, mit With kann man praktisch Code kürzen, aber da sollte man aufpassen, das der Namespace nicht andere Befehle im einbeschlossenen Code verändert ... z.B. bei gleichnamigen Funktionen und Co.

z.B. kann man sich bei sowas eben auch mal 'ne Variable sparen, aber try-finally sollte auch mit rein

Delphi-Quellcode:

with TMetafileCanvas.Create(MetaGraphic, 0) do
  try
    for A := 0 to 90 do DrawSomething(A);
  finally
    Free;
  end;

nutze ichgern mal für INIs oder kleine Formulare via ShowModal

Delphi-Quellcode:

with TMyOprionDialog.Create(Self) do
  try
    ...
    // Variablen/Property befüllen
    ...
    if ShowModal = mrOK then begin
      ...
      // Rückgabewerte verarbeiten
      ...
    end;
  finally
    Free;
  end;

[HJay]

Nochmal vielen Dank für Eure Kommentare. Ich habe die With-Konstruktion jetzt verstanden, aber finde sie immer noch etwas gewöhnungsbedürftig. Ich habe aber gelernt, dass das Create einer Methode eben doch wie eine Funktion funktioniert und ein Result des eigenen Methodentyps zurückgibt. Es beruhigt ein wenig, dass auch erfahrene Programmierer die Konstruktion beachten müssen. Ab jetzt kenne ich sie und werde sie trotzdem versuchen zu vermeiden...