Curl mit Indy aufrufen

[Neutral General]

Weiß nicht ob es mit dem Hinweis von Schokohase schon klappt, aber in deiner Delphi-Version gibt es auch spezielle REST-Klassen.
Mit folgendem Code:

Delphi-Quellcode:

uses
  REST.Client, REST.Types;

procedure TForm2.FormCreate(Sender: TObject);
var client: TRESTClient;
    response: TRESTResponse;
    request: TRESTRequest;
begin
  client := TRESTClient.Create('https://api.nuki.io/');
  try
    response := TRESTResponse.Create(nil);
    try
      request := TRESTRequest.Create(nil);
      try
        request.Client := client;
        request.Response := response;
        request.Resource := 'account/user';
        request.Method := rmPUT;  // <<< Edit: Hatte ich vergessen 
        request.AddParameter('Authorization', 'Bearer BeispielToken', TRESTRequestParameterKind.pkHTTPHEADER, [poDoNotEncode]);
        request.AddBody('{ "type": 0, "email": "[e-mail]", "name": "apitest", "language": "de" }', TRESTContentType.ctAPPLICATION_JSON);

        request.Execute;

        Memo1.Text := response.Content;
        Label1.Caption := response.StatusText;
      finally
        request.Free;
      end;
    finally
      response.Free;
    end;
  finally
    client.Free;
  end;
end;

Bekomme ich:

Zitat:

StatusCode: 401 (Unauthorized)
{"detailMessage":"Your access token is not authorized","stackTrace":[],"suppressedExceptions":[]}

Also: Es klappt, aber ich hab natürlich kein gültiges Token.