Sounds übereinander abspielen

[dutyfree]

Hallo, in einem Tool wird wenn ich ein Button drücke mit dem Befehl MCISendString(PChar('play ' + Pfad), nil, 0, 0) eine .wav Datei abgespielt. Problem ist, wenn ich den Button erneut drücke während der Ton schon abgespielt wird, passiert nichts. Ich wollte es so haben, dass der Ton dann trozdem abgespielt wird, also dass man beide Töne dann hört (auch wenns die gleichen sind). Wenn das nicht geht, wie mache ichs, dass der Ton dann sofort gestoppt wird und von Anfang abgespielt wird?
Wie kann ich das machen? Thx

[dutyfree]

Ich hab es jetzt nochmal mit dem Befehl PlaySOUND(PChar(Pfad),hInstance,snd_ASync ); versucht, war eigentlich ganz okay, bis ich gemerkt habe, dass wenn ich eine Datei anspiele und dann eine andere anmache (nicht die gleiche) dass die die man vorher gehört hat weggeht.

Edit:

Also nochmal kurz zusammengefasst was ich machen will:

2 Sounds. 2 Buttons. Ein kurzer (2 Sekunden) und ein langer (20 Sekunden). Wenn ich den kurzen anklicke spielt er sofort ab und wenn ich nochmal draufklicke fängt er sofort von vorne an. hier ist der Befehl "PlaySOUND(PChar(Pfad),hInstance,snd_ASync)" perfekt. Wenn ich aber jetzt den langen anklicke und er anfängt abzuspielen und ich dazu dann den kurzen anmache dann soll der lange Sound aber trozdem weiterlaufen! Wenn ich es mit dem oben genannten Befehl mache geht der Sound dann auch weg. Hierfür ist der Befehl "MCISendString(PChar('play ' + Pfad), nil, 0, 0)" ganz gut, dann bin ich aber wieder bei problem 1 mit dem kurzen Sound, da der Sound nicht neuanfängt wenn man neu draufklickt mit diesem Befehl.
Ich brauche also eine Möglichkeit um die "Stärken" dieser beiden Möglichkeiten zu vereinen. Weiss aber nicht wie.

[fui-tak]

Du könntest das ganze mit 2 TMediaPlayern machen...

[turboPASCAL]

Oder einfach die BASS.DLL (BASS.DLL) verwenden:

Delphi-Quellcode:

// ... *schnipp* ... //

implementation

{$R *.dfm}

var
  WavFileName1 : string;
  WavFileName2 : string;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form1.Caption := Application.Title;

  WavFileName1 := ExtractFilePath(ParamStr(0)) + '\WavSnd\LongSound.wav';  // oder mp3-Files
  WavFileName2 := ExtractFilePath(ParamStr(0)) + '\WavSnd\ShortSound.wav';

  // Bass.dll initialisieren
  if not BASS_Init(-1, 44100, 0, 0, nil) then
  begin
    ShowMessage('Can''t initialize sound.');
    Application.Terminate; // Stop & Exit Prograam
  end;

  /////// SOUNDVOLUME SETUP //////////////////////////////////////////////////
  //
  // Muss man nicht, kann man aber wenn man will
  //
  // Get Stream global Volume
  StreamVol := BASS_GetConfig(BASS_CONFIG_GVOL_STREAM);
  // immer ein bissel leiser abends ;-)
  // 1000 = 100%
  //  800 =  80%
  //  100 =  10%
  if StreamVol > 800 then
  begin
    StreamVol := 800;
    BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, StreamVol);
  end;
  ////////////////////////////////////////////////////////////////////////////

  // Load Wave-File
  hStream1 := BASS_StreamCreateFile(False, PChar(WavFileName1), 0, 0, 0);
  hStream2 := BASS_StreamCreateFile(False, PChar(WavFileName2), 0, 0, 0);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  // alles Freigeben
  if hStream1 <> 0 then
  begin
    BASS_ChannelStop(hStream1); // muss man nich anhalten, ich machs
    BASS_StreamFree(hStream1);
  end;

  if hStream2 <> 0 then
  begin
    BASS_ChannelStop(hStream2); // muss man nich anhalten, ich machs
    BASS_StreamFree(hStream2);
  end;

  // Bass.dll deinitialisieren
  BASS_Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  // "BASS_ChannelPlay(Stream1, True);" True = Play from Start
  BASS_ChannelPlay(hStream1, True);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  BASS_ChannelPlay(hStream2, True);
end;

end.