Unit zur Verwendung von SHGetKnownFolderPath

[MicMic]

Es hat ja ein wenig damit zu tun (SHGetKnownFolderPath).
Geht das auch irgendwie andersrum? Ich habe z.B. "C:\Programme" und möchte den wirklichen Ordner ermitteln. Also hier dann "C:\Program Files".
Geht das irgendwie?

Gruß
Micha

[Luckie]

Wie oft muss man euch beide eigentlich noch ermahnen!

Ich hoffe mit dem letzten Beitrag wird wieder zum Thema zurückgefunden.

[KodeZwerg]

Zitat von MicMic:

Es hat ja ein wenig damit zu tun (SHGetKnownFolderPath).
Geht das auch irgendwie andersrum? Ich habe z.B. "C:\Programme" und möchte den wirklichen Ordner ermitteln. Also hier dann "C:\Program Files".
Geht das irgendwie?

Gruß
Micha

Ich mache es so:

Delphi-Quellcode:

// kann sein das Dein Delphi die zwei Zeilen schon in Windows.pas hat, dann wegmachen.
const FILE_NAME_NORMALIZED = $0;
Function GetFinalPathNameByHandleA(hFile: THandle; lpszFilePath: LPSTR; cchFilePath: DWORD; dwFlags: DWORD): DWORD; stdcall; external 'Kernel32.dll';

function _FileGetSymLinkTarget( const APathToLink : string; var ATarget : string ) : boolean;
  var
    LinkHandle: THandle;
    TargetName: array [0..OFS_MAXPATHNAME-1] of AnsiChar;
  begin
    ATarget := '';
    LinkHandle := CreateFile( PChar(APathToLink), 0, FILE_SHARE_READ, nil,
        OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
    Win32Check(LinkHandle <> INVALID_HANDLE_VALUE);
    try
      Result := GetFinalPathNameByHandleA(LinkHandle, @TargetName, OFS_MAXPATHNAME, FILE_NAME_NORMALIZED) > 0;
      if Result then
        begin
        ATarget := TargetName;
        if Pos( '\\?\UNC\', ATarget ) = 1 then
           begin
           Delete( ATarget, 1, 8 );
           Insert( '\\', ATarget, 1 );
           end
          else
          if Pos( '\\?\', ATarget ) = 1 then
             Delete( ATarget, 1, 4 );
        end;
    finally
      CloseHandle(LinkHandle);
    end;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  s: String;
begin
  s := '';
  _FileGetSymLinkTarget('c:\programme',s);
  ShowMessage(s);
end;

Zitat:

C:\Program Files

Zitat von Luckie:

Wie oft muss man euch beide eigentlich noch ermahnen!

Ich hoffe mit dem letzten Beitrag wird wieder zum Thema zurückgefunden.

Verzeih mir und ich hoffe mit diesem Beitrag Deinen Wunsch Sinngemäß umgesetzt zu haben

[MicMic]

hihi... habe zeitgleich auch "GetFinalPathNameByHandle" gefunden und was probiert und wollte gleich mal hier nachfragen, ob man sich auf dieses "\\?\" (was mit übergeben wird) verlassen kann?
Aber deine Funktion nehme ich gerne. Dankeschön

Was ich auch noch nicht so ganz begreife... mit diesem "A" und "W" bei Funktionen.

Also "GetFinalPathNameByHandleA". Es gibt auch "W". Ich glaube A für Ansi und W für WideString? Da muss man wohl je nach aktion/nutzen die richtigen Funktionen wählen? Gerade wegen Dateinamen etc. nutze ich dann z.B. "FindFirstFileW". So ganz bin ich da noch nicht durch (wieso, weshalb, warum) aber bei mir gehen dann schon mal auch chinesische/japanische/russische Dateinamen. Na am Ende muss man das wohl dann alles durchtesten.

Gruß
Micha

[KodeZwerg]

Zitat von MicMic:

hihi... habe zeitgleich auch "GetFinalPathNameByHandle" gefunden und was probiert und wollte gleich mal hier nachfragen, ob man sich auf dieses "\\?\" (was mit übergeben wird) verlassen kann?
Aber deine Funktion nehme ich gerne. Dankeschön

Was ich auch noch nicht so ganz begreife... mit diesem "A" und "W" bei Funktionen.

Also "GetFinalPathNameByHandleA". Es gibt auch "W". Ich glaube A für Ansi und W für WideString? Da muss man wohl je nach aktion/nutzen die richtigen Funktionen wählen? Gerade wegen Dateinamen etc. nutze ich dann z.B. "FindFirstFileW". So ganz bin ich da noch nicht durch (wieso, weshalb, warum) aber bei mir gehen dann schon mal auch chinesische/japanische/russische Dateinamen. Na am Ende muss man das wohl dann alles durchtesten.

Gruß
Micha

Ich habe bei Microsoft nur diese Api gefunden. Wenn es eine Wide Version gibt, dann unbedingt die bevorziehen! Unicode und so. Ja, das A am Ende steht für Ansi, deswegen AnsiChar im Code. Unicode hat dann alle characters, also W.
Ich schreibe mal mein Code für Wide um und teste, meine Windows.pas kennt halt gar keine von denen (Delphi 2019) und Microsoft sagte mir nix von einer W... oder ich habs überlesen, dann sorry!

[KodeZwerg]

Schnell rumgewurschtelt, nun sollte es Unicode sein?

Delphi-Quellcode:

const FILE_NAME_NORMALIZED = $0;
//Function GetFinalPathNameByHandleA(hFile: THandle; lpszFilePath: LPSTR; cchFilePath: DWORD; dwFlags: DWORD): DWORD; stdcall; external 'Kernel32.dll';
Function GetFinalPathNameByHandleW(hFile: THandle; lpszFilePath: LPWSTR; cchFilePath: DWORD; dwFlags: DWORD): DWORD; stdcall; external 'Kernel32.dll';

function _FileGetSymLinkTarget( const APathToLink : string; var ATarget : string ) : boolean;
  var
    LinkHandle: THandle;
    TargetName: array [0..OFS_MAXPATHNAME-1] of WideChar;
  begin
    ATarget := '';
    LinkHandle := CreateFileW( PWideChar(APathToLink), 0, FILE_SHARE_READ, nil,
        OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
    Win32Check(LinkHandle <> INVALID_HANDLE_VALUE);
    try
      Result := GetFinalPathNameByHandleW(LinkHandle, @TargetName, OFS_MAXPATHNAME, FILE_NAME_NORMALIZED) > 0;
      if Result then
        begin
        ATarget := TargetName;
        if Pos( '\\?\UNC\', ATarget ) = 1 then
           begin
           Delete( ATarget, 1, 8 );
           Insert( '\\', ATarget, 1 );
           end
          else
          if Pos( '\\?\', ATarget ) = 1 then
             Delete( ATarget, 1, 4 );
        end;
    finally
      CloseHandle(LinkHandle);
    end;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  s: String;
begin
  s := '';
  _FileGetSymLinkTarget('c:\programme',s);
  ShowMessage(s);
end;

[EWeiss]

Wenn schon denn schon..
CreateFileW(PWideChar(...

gruss

[KodeZwerg]

Zitat von EWeiss:

Wenn schon denn schon..
CreateFileW(PWideChar(...

gruss

Ich wusste doch da war noch was, Dankeschön!

edit
So vielleicht auch für ältere Delphis.

Delphi-Quellcode:

const FILE_NAME_NORMALIZED = $0;
function GetFinalPathNameByHandle(hFile: THandle; lpszFilePath: PChar; cchFilePath: DWORD; dwFlags: DWORD): DWORD; stdcall;
         external 'Kernel32.dll' name {$IFDEF UNICODE}'GetFinalPathNameByHandleW'{$ELSE}'GetFinalPathNameByHandleA'{$ENDIF};

function _FileGetSymLinkTarget( const APathToLink : string; var ATarget : string ) : boolean;
  var
    LinkHandle: THandle;
    TargetName: array [0..OFS_MAXPATHNAME-1] of {$IFDEF UNICODE}WideChar{$ELSE}AnsiChar{$ENDIF};
  begin
    ATarget := '';
    LinkHandle :=  CreateFile( {$IFDEF UNICODE}PWideChar{$ELSE}PAnsiChar{$ENDIF}
                               (APathToLink), 0, FILE_SHARE_READ, nil,
                               OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
    Win32Check(LinkHandle <> INVALID_HANDLE_VALUE);
    try
        Result := GetFinalPathNameByHandle(LinkHandle, @TargetName, OFS_MAXPATHNAME, FILE_NAME_NORMALIZED) > 0;
      if Result then
        begin
        ATarget := TargetName;
        if Pos( '\\?\UNC\', ATarget ) = 1 then
           begin
           Delete( ATarget, 1, 8 );
           Insert( '\\', ATarget, 1 );
           end
          else
          if Pos( '\\?\', ATarget ) = 1 then
             Delete( ATarget, 1, 4 );
        end;
    finally
      CloseHandle(LinkHandle);
    end;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  s: String;
begin
  s := '';
  _FileGetSymLinkTarget('c:\programme',s);
  ShowMessage(s);
end;