privaten Record über Getter heraus geben

[Sir Rufo]

Oder eine Kombination aus Interface, Instanz und Record:

Delphi-Quellcode:

IFoo = interface
  function GetBar: Integer;
  procedure SetBar( const Value: Integer );
  property Bar : Integer read GetBar write SetBar;
end;

TFoo = record
private
  FFoo: IFoo;
  procedure EnsureInitialized();
  function GetBar: Integer;
  procedure SetBar( const Value: Integer );
public
  property Bar: Integer read GetBar write SetBar;
end;

TFooImpl = class( TInterfacedObject, IFoo )
private { IFoo }
  function GetBar: Integer;
  procedure SetBar( const Value: Integer );
private
  FBar: Integer;
end;

procedure TFoo.EnsureInitialized;
begin
  if not Assigned( FFoo )
  then 
    FFoo := TFooImpl.Create;
end;

function TFoo.GetBar: Integer;
begin
  EnsureInitialized();
  Result := FFoo.Bar;
end;

procedure TFoo.SetBar( const Value: Integer );
begin
  EnsureInitialized();
  FFoo.Bar := Value;
end;

function TFooImpl.GetBar: Integer;
begin
  Result := FBar;
end;

procedure TFooImpl.SetBar( const Value: Integer );
begin
  FBar := Value;
end;

Dem Record sollte man dann aber noch eine Clone Methode spendieren, damit man bei Bedarf auch einen unabhängigen Record bekommen kann