NonVCL Version von Classes.dcu

[jbg]

Zitat von Chewie:

Durch irgendeine Schwäche im Delphi-Speichermanager

Das ist mehr eine Stärke des Delphi-Speichermanagers, die sich nur bei falscher Verwendung eben stark ins negative wendet.

Zitat:

kann es nun passieren (und es passiert), dass der Speicher, den das Array vor dem Verschieben belegte, nicht wieder frei gegeben wird.

Der Speicher wird schon freigegeben. Wobei er aber nicht an Windows-Speichermanager, sondern an den Delphi-Speichermanager geht, der sich die Adresse merkt um neue Anforderungen viel schneller zu verarbeiten als es der Windows Speichermanager kann.


Du kannst den folgenden Speichermanager, der nichts anderes macht als den Windows-Speichermanager aufzurufen, ja mal als Ersatz nehmen. (Erste Unit im Projektquellcode). Der Geschwindigkeitsunterschied bei vielen Komponenten auf den Formularen ist spürbar.

Delphi-Quellcode:

unit WinMemMan;
interface
uses Windows;

implementation
const
  HEAP_NO_SERIALIZE = 1;
  HEAP_ZERO_MEMORY  = 8;

  HeapFlags: array[False..True] of Cardinal = (HEAP_NO_SERIALIZE, 0);

var
  ProcessHeap: THandle;

function HeapGetMem(Size: Integer): Pointer;
begin
  Result := HeapAlloc(ProcessHeap, HeapFlags[IsMultiThread], Size);
end;

function HeapFreeMem(P: Pointer): Integer;
begin
  if HeapFree(ProcessHeap, HeapFlags[IsMultiThread], P) then Result := 0 else Result := 1;
end;

function HeapReallocMem(P: Pointer; Size: Integer): Pointer;
begin
  Result := HeapReAlloc(ProcessHeap, HeapFlags[IsMultiThread], P, Cardinal(Size));
end;

procedure InitializeHeapMemManager;
var HeapMemManager: TMemoryManager;
begin
  ProcessHeap := GetProcessHeap;
  HeapMemManager.GetMem := HeapGetMem;
  HeapMemManager.FreeMem := HeapFreeMem;
  HeapMemManager.ReallocMem := HeapReallocMem;
  SetMemoryManager(HeapMemManager);
end;

initialization
  InitializeHeapMemManager;

end.