TDBDateTimePicker

[doctor-x]

Hallo Leute,
Ich wollte mir einige DB Elemente selber machen, da es diese nicht standardmäsig gibt. Das funktioniert auch soweit ganz gut, aber sobald ich dieses steuerelemet (TDBDateTimePicker --> Code der Komponente anbei) auf ein DBCtrlGrid setze steht in allen angezeigten spalten im DBDateTimePicker das selbe, es werden immer in allen DBDateTimePickern die auf das selbe feld verweisen die daten des aktiven (Markirten) Datensatz angezeigt und nicht die daten des jeweiligem datensatzes. Hat jemand vieleicht eine idee was ich dafür ändern muss????

Danke schon mal im voraus!

Delphi-Quellcode:

unit DBDateTimePicker;

interface

uses
  SysUtils, Classes, Controls, ComCtrls, DBCtrls, DB, Messages, Windows, Forms;

type
  TDBDateTimePicker = class(TDateTimePicker)
  private
    FDataLink: TFieldDataLink;
    procedure DataChange(Sender: TObject);
    procedure EditingChange(Sender: TObject);
    function GetDataField: string;
    function GetDataSource: TDataSource;
    function GetField: TField;
    procedure SetDataField(const Value: string);
    procedure SetDataSource(Value: TDataSource);
    procedure UpdateData (Sender: TObject);
    procedure Change; override;
    procedure CMGetDataLink(var Message: TMessage); message CM_GETDATALINK;
  protected
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    property Field: TField read GetField;
  published
    property DataField: string read GetDataField write SetDataField;
    property DataSource: TDataSource read GetDataSource write SetDataSource;
  end;

procedure Register;

implementation

constructor TDBDateTimePicker.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  ControlStyle := ControlStyle + [csReplicatable];
  FDataLink := TFieldDataLink.Create;
  FDataLink.Control := Self;
  FDataLink.OnDataChange := DataChange;
  FDataLink.OnEditingChange := EditingChange;
  FDataLink.OnUpdateData := UpdateData;
end;

destructor TDBDateTimePicker.Destroy;
begin
  FDataLink.Free;
  FDataLink := nil;
  inherited Destroy;
end;

function TDBDateTimePicker.GetDataSource: TDataSource;
begin
  Result := FDataLink.DataSource;
end;

procedure TDBDateTimePicker.SetDataSource(Value: TDataSource);
begin
  if not (FDataLink.DataSourceFixed and (csLoading in ComponentState)) then
    FDataLink.DataSource := Value;
  if Value <> nil then Value.FreeNotification(Self);
end;

function TDBDateTimePicker.GetDataField: string;
begin
  Result := FDataLink.FieldName;
end;

function TDBDateTimePicker.GetField: TField;
begin
  Result := FDataLink.Field;
end;

procedure TDBDateTimePicker.SetDataField(const Value: string);
begin
  FDataLink.FieldName := Value;
end;

procedure TDBDateTimePicker.DataChange(Sender: TObject);
begin
  if FDataLink.Field <> nil then begin
    if FDataLink.Field.DataType = ftDate then DateTime := FDataLink.Field.AsDateTime;
  end;
  if HandleAllocated then RedrawWindow(Handle, nil, 0, RDW_INVALIDATE or RDW_ERASE or RDW_FRAME);
end;

procedure TDBDateTimePicker.EditingChange(Sender: TObject);
begin

end;

procedure TDBDateTimePicker.CMGetDataLink(var Message: TMessage);
begin
  Message.Result := Integer(FDataLink);
end;

procedure TDBDateTimePicker.UpdateData (Sender: TObject);
begin
  FDataLink.Field.AsDateTime := DateTime;
end;

procedure TDBDateTimePicker.Change;
begin
  FDataLink.Field.DataSet.Edit;
  UpdateData(Self);
  inherited Change;
end;

procedure Register;
begin
  RegisterComponents('Datensteuerung', [TDBDateTimePicker]);
end;

end.

[doctor-x]

Scheint ja keine einfache lösung zu geben, oder zumindest keine schnelle

Oder ist die frage unverständlich???

bitte um feedback.

[sx2008]

Das DBCtrlGrid war schon immer mit Vorsicht zu geniesen - nicht alle datensensitiven Controls funktionieren darauf richtig.
Grund dafür ist, dass da im DBCtrlGrid im Hintergrund ganz schön getrickst wird.

Delphi-Quellcode:

procedure TDBDateTimePicker.DataChange(Sender: TObject);
begin
  if FDataLink.Field <> nil then begin
    if FDataLink.Field.DataType = ftDate then DateTime := FDataLink.Field.AsDateTime;
  end;
  // folgende Zeile bitte vielleicht mal auskommentieren
  // TDateTimerPicker merkt von selbst, dass sich das Property DateTime geändert hat
  // und zeichnet sich dann selbst neu
  // das zusätzliche RedrawWindow ist dann doppel gemoppelt
  if HandleAllocated then RedrawWindow(Handle, nil, 0, RDW_INVALIDATE or RDW_ERASE or RDW_FRAME);
end;

[doctor-x]

Hab es mal probiert, bingt mich aber auch nicht weiter

Ich habe über googel ein TDBDateTimePicker gefunden, aber der macht die selben probleme

Das ist doppelt ärgerlich, da ich auch noch einen DBOleContainer brauche, der ebenfalls dieses problem hatt

[manfred_h]

Hallo Doctor-X

es gibt da auch die TJvDBDateTimePicker Komponente. Womöglich hilft Dir die weiter?
Hatte nur Anfangs Probleme das eingetragene Werte nicht übernommen wurden.
Habe dann das so gelöst:

Delphi-Quellcode:

procedure TDM_member.camps_d_m_time_change(Sender: TObject);
begin
  DM.CAMPS_D_PUB.Edit;
  DM.CAMPS_D_PUB.FieldByName('M_MEETING_TIME').AsDateTime := frm_member. Time_M_MEETING_TIME.Time;
  DM.CAMPS_D_PUB.Post;
end;

Shalom
Manfred

[doctor-x]

Danke für den Tip.

Das funktioniert wunderbar