File patchen

[KodeZwerg]

Im Anhang ein total simpler byte patcher.

Delphi-Quellcode:

       Offsets : ARRAY [1..8] OF LONGINT = ($2e57, $2e58, $42b4, $42b5, $63a4, $67bf, $68ff, $6c4e);
     OrgValues : ARRAY [1..8] OF BYTE = ($7c, $0f, $7c, $18, $85, $85, $8d, $75);
     NewValues : ARRAY [1..8] OF BYTE = ($90, $90, $90, $90, $84, $84, $85, $eb);

darüber wird der ablauf gesteuert.
Geschrieben vor einer Ewigkeit, gerade nur mal kurz getestet ob es kompiliert und noch das tut was es soll.
Vielleicht hilft es Dir?

[Andreas13]

Danke KodeZwerg!

kompilieren geht auch bei mir, kann jedoch das Programm im Debugger nicht starten, weil folgende Fehlermeldung kommt:
„Fehler
Prozess kann nicht erzeugt werden: Der angeforderte Vorgang erfordert erhöhte Rechte.“
obwohl ich auf meinem PC der Administrator bin.
Gibt es einen Trick dafür?

Könntest Du bitte evtl. auch die im Programm verwendete xyz.exe raufladen, damit ich den Ablauf studieren kann.

Danke & viele Grüße
Andreas

[KodeZwerg]

Zitat von Andreas13:

Danke KodeZwerg!

Gern geschehen!

Zitat von Andreas13:

Gibt es einen Trick dafür?

Das erzeugte Kompilat als Administrator ausführen.

Zitat von Andreas13:

Könntest Du bitte evtl. auch die im Programm verwendete xyz.exe raufladen, damit ich den Ablauf studieren kann.

xyz.exe gibt es nicht, das sollte nur ein rudimentäres Beispiel darstellen.
Der ablauf?
Datei xyz.exe öffnen, per "Seek" zu einem Offset springen und den Wert einlesen/auswerten/patchen, entweder wird ein Patch eingespielt oder entfernt oder gemeckert das es weder original noch dem Patch entspricht.

Heutzutage würde ich das ganze per Stream erledigen, die art und weise bleibt identisch, Seek -> Patch.
Ob die zu patchenden Daten wie in meinem Beispiel aus einem Array kommen oder moderner per Liste ist Geschmackssache.

[Andreas13]

Zitat von KodeZwerg:

Das erzeugte Kompilat als Administrator ausführen.

Das heißt, so ein Programm läßt sich gar nicht debuggen?
Beim Start des etwas angepaßten Programms als Administrator erhalte ich bei einer Test.exe von mir gleich Runtime error 105.

[Edit]: "Runtime error" - Problem behoben.

[KodeZwerg]

Zitat von Andreas13:

Zitat von KodeZwerg:

Das erzeugte Kompilat als Administrator ausführen.

Das heißt, so ein Programm läßt sich gar nicht debuggen?

Ich habe keine Ahnung wozu Du es debuggen möchtest aber wenn, dann start Delphi auch als Administrator.
Es gibt doch nur diese drei Konstanten die der code durchläuft also ist das einzige was zu "debuggen" ist, die Konstante

Ich schreib Dir morgen mal was aktuelleres per FileStream und Forms und ohne Admin und zum debuggen etc

[Andreas13]

Vielen Dank für Deine Hilfe, KodeZwerg!
Grüße, Andreas

[KodeZwerg]

Hier das ganze nochmal, sorry keine UI, alles unter der Console.
Als Ziel nahm ich einfach mein vorigen Post als Kompilat in der Hoffnung das er bei Dir exakt so ist wie bei mir.

Delphi-Quellcode:

program Patcher;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, System.Classes;

const
  CFName   = string('Patch.exe');
  CFSize   = UInt64(58880);
  CPatches = UInt64($23);
  COffsets:  array[0..CPatches] of UInt64 = ($50,$51,$52,$53,$54,$55,$56,$57,$58,$59,$5A,$5B,$5C,$5D,$5E,$5F,$60,$61,$62,$63,$64,$65,$66,$67,$68,$69,$6A,$6B,$6C,$6D,$6E,$6F,$70,$71,$72,$73);
  //This program must be run under Win32
  COrgBytes: array[0..CPatches] of Byte   = ($54,$68,$69,$73,$20,$70,$72,$6f,$67,$72,$61,$6d,$20,$6d,$75,$73,$74,$20,$62,$65,$20,$72,$75,$6e,$20,$75,$6e,$64,$65,$72,$20,$57,$69,$6e,$33,$32);
  //Hier steht jetzt etwas total cooles!
  CNewBytes: array[0..CPatches] of Byte   = ($48,$69,$65,$72,$20,$73,$74,$65,$68,$74,$20,$6a,$65,$74,$7a,$74,$20,$65,$74,$77,$61,$73,$20,$74,$6f,$74,$61,$6c,$20,$63,$6f,$6f,$6c,$65,$73,$21);

var
  fs: TFileStream;
  FName: string;
  i: Integer;
  b: Byte;
  Org, New, Diff: UInt64;
begin
  FName := ExtractFilePath(ParamStr(0)) + CFName;
  if (not FileExists(FName)) then
    begin
      WriteLn(FName + ' not found!');
      ReadLn;
      Exit;
    end;
  try
    fs := TFileStream.Create(FName, fmOpenReadWrite or fmShareExclusive);
    try
      Org := 0; New := 0; Diff := 0;
      if (fs.Size <> CFSize) then
        begin
          WriteLn('Wrong Filesize!');
          ReadLn;
          Exit;
        end;
      for i := 0 to CPatches do
        begin
          fs.Position := COffsets[i];
          fs.Read(b, 1);
          if (b = COrgBytes[i]) then
            Inc(Org);
          if (b = CNewBytes[i]) then
            Inc(New);
          if ((b <> COrgBytes[i]) and (b <> CNewBytes[i])) then
            Inc(Diff);
        end;
      if Org = Succ(CPatches) then
        begin
          for i := 0 to CPatches do
            begin
              fs.Position := COffsets[i];
              fs.Write(CNewBytes[i], 1);
            end;
          WriteLn('Patch applied!');
        end;
      if New = Succ(CPatches) then
        begin
          for i := 0 to CPatches do
            begin
              fs.Position := COffsets[i];
              fs.Write(COrgBytes[i], 1);
            end;
          WriteLn('Patch removed!');
        end;
      if Diff <> 0 then
        WriteLn('Wrong Version!');
    finally
      fs.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  ReadLn;
end.

Ich hoffe das es Dir hilft, so jedenfalls sieht bei mir ein simpler Byte-Patcher aus.
Falls es noch Fragen gibt, nur keine Scheu