Objekt klonen?

[Namenloser]

Hallo,

ich habe in meinem Projekt eine Basisklasse namens TNObject, von der verschiedene Klassen abgeleitet sind, z.B. TNObjDoor, TNObjNinja, TNObjDrone und einige andere. Das ganze sind Elemente eines Spiels (nicht von mir), für das ich einen Leveleditor schreibe. Nun will ich der Basisklasse TNObject eine Funktion hinzufügen, die einen Klon eines vorhandenen Objekts erzeugt.
Die soll so aussehen:

Delphi-Quellcode:

function TNObject.MakeClone: TNObject;
begin
  result := <Klasse>.Create;
  result.Assign(self);
end;

Das Problem ist, dass ich nicht weiß, wie ich <Klasse> herausbekomme. Ich hatte gehofft, hier self einsetzen zu können, was aber leider nicht funktionierte (zerschossene Objekte etc, Zugriffsverletzungen etc). ClassType funktioniert auch nicht, da der Compiler meldet, dass TObject und TNObject nicht kompatibel seien. Mit einem Typecast auf TNObject gibt es dann später Zugriffsverletzungen an verschiedenen Adressen nahe Adresse $00000000.

Wie macht man es richtig? Irgendwie muss das doch gehen

[omata]

Vielleicht so...

Delphi-Quellcode:

type
  TNObject = class
  public
    function MakeClone:TNObject;
    procedure Assign(Obj:TNObject);
  end;

  TNObjDoor = class(TNObject)
  end;

  TNObjNinja = class(TNObject)
  end;

  TNObjDrone = class(TNObject)
  end;

:
:

function TNObject.MakeClone: TNObject;
begin
  Result:=TNObject(Self.ClassType.Create);
  Result.Assign(Self);
end;

Aufruf...

Delphi-Quellcode:

var O, Oclone:TNObject;
begin
  O:=TNObjDoor.Create;
  Oclone:=O.MakeClone;
  ShowMessage(Oclone.ClassName);
end;

[Pfoto]

Hallo,

ich habe bei mir folgendes im Einsatz:

Delphi-Quellcode:

Type
  TCmdClass = class of TCmd;
  TCmd = class(TPersistent)
  [...]

Nun gibt es folgende Funtkion, die ohne auch Instanz-Erstellung aufgerufen werden kann

Delphi-Quellcode:

class function TCmd.CreateByClassname(const aClassName: string): TCmd;
var
  tc: TPersistentClass;
begin
  result:= nil;
  tc:= GetClass(aClassName);
  If assigned(tc) then
  begin
    result:= TCmdClass(tc).Create;
    If not assigned(result) then
      raise Exception.Create(Format('Befehl ''%s'' konnte nicht erstellt werden.', [aClassName]));
  end else
    raise Exception.Create(Format('Klasse ''%s'' ist nicht registriert', [aClassName]));
end;

AssignTo wurde in dieser Klasse überschrieben, so dass alle
öffentlichen Eigenschaften kopiert werden können (Code hier aus dem Forum):

Delphi-Quellcode:

procedure TCmd.AssignTo(Dest: TPersistent);
var count,i:integer;
    List:PProplist;
    Info:PPropInfo;
begin
  count:=GetPropList(self,List);
  try
    for i:=0 to count-1 do
    begin
      Info:=List^[i];
      setpropvalue(dest,Info^.Name,getpropvalue(self,Info^.Name));
    end;
  finally
    freemem(list);
  end;
end;

Nach Erstellung des Objektes über CreateByClassname(QuellObjekt.ClassName)
kann dann über das neue Objekt Assign() aufgerunfen werden und
die Eigenschaften des Quellobjektes werden übernommen.


Gruß
Jürgen

[mjustin]

Zitat von Pfoto:

Delphi-Quellcode:

Type
  TCmdClass = class of TCmd;
  TCmd = class(TPersistent)
  [...]

Das geht auch mit TObject in Verbindung mit {$M+}. Doch es geht bei TPersistent und TObject + {$M+} nicht mit öffentlichen (public) sondern nur mit published Eigenschaften...

[Namenloser]

Zitat von omata:

Vielleicht so...

Delphi-Quellcode:

function TNObject.MakeClone: TNObject;
begin
  Result:=TNObject(Self.ClassType.Create);
  Result.Assign(Self);
end;

var O, Oclone:TNObject;
begin
  O:=TNObjDoor.Create;
  Oclone:=O.MakeClone;
  ShowMessage(Oclone.ClassName);
end;

Verzwickterweise gibt dieser Test sogar das richtige aus, allerdings wird der falsche constructor aufgerufen, nämlich der von TNObject. Dadurch werden manche Werte nicht richtig initialisiert und es kracht.

@Pfoto:
Der Typecast auf eine "class of"-Klasse ist mir heute nacht im Bett auch noch eingefallen. Und siehe da, das klappt sogar!

Delphi-Quellcode:

TNObjectClass = class of tnobject;

...

function TNObject.MakeClone: TNObject;
begin
  result := TNObjectClass(ClassType).Create;
  result.Assign(self);
end;

Danke an alle!

[Muetze1]

Zitat von NamenLozer:

Verzwickterweise gibt dieser Test sogar das richtige aus, allerdings wird der falsche constructor aufgerufen, nämlich der von TNObject. Dadurch werden manche Werte nicht richtig initialisiert und es kracht.

Virtueller Constructor und fleißig override in den Ableitungen löst dein Problem...