Float in zwei Integer zerlegen

[Popov]

In der letzten Zeit bin ich ein Fan von virtuellen Listen, sowohl bei ListBoxen, wie auch bei ListViews. Verwaltet werden die Daten in einer ObjectList und lediglich angezeigt in ListView. Der Vorteil, dadurch wird das Ganze viel schneller. Der Grund - hier muss ListView nicht die ganzen Daten schleppen, die bleiben in der ObjectList. ListView ist nur noch für die Anzeige der paar Items die gerade sichtbar sind:

Delphi-Quellcode:

uses
  Contnrs;

type
  TTest = class
    Num: Integer;
    DateTime: TDateTime;
  end;

var
  ol: TObjectList;

procedure TForm1.FormCreate(Sender: TObject);
var
  d: Integer;
  Test: TTest;
  Col: TListColumn;
begin
  //Hier eine ObjectList Liste erstellen
  ol := TObjectList.Create(True);

  //Hier die Liste mit Daten füllen
  for d := Trunc(Now) - 365 to Trunc(Now) do
  begin
    Test := TTest.Create;
    Test.Num := Random(1000);
    Test.DateTime := d + Now;
    ol.Add(Test);
  end;

  with ListView1 do
  begin
    ViewStyle := vsReport;
    Col := Columns.Add;     //Beschriftungen
    Col.Caption := 'Num';
    Col := Columns.Add;
    Col.Caption := 'Date';
    Col.Width := 150;

    OwnerData := True;
    Items.Count := ol.Count;
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ol.Free;
end;

procedure TForm1.ListView1Data(Sender: TObject; Item: TListItem);
var
  Test: TTest;
begin
  Test := TTest(ol[Item.Index]);  //hier werden die Daten aus ObjectList an ListView übertragen
  Item.Caption := IntToStr(Test.Num);
  Item.SubItems.Add(DateTimeToStr(Test.DateTime));
end;

Um das Beispiel umzusetzen reicht ein ListView auf dem Formular.