hi,
ich wollte mal fragen wie man mehrere Parameter einer funktion bei aufruf von Beginthread übergibt
kleines beispiel:
-funktion:

markieren

Delphi-Quellcode:

funktion rechne(a,b:integer):integer;
begin
result := a+b;
end;

-aufruf:

markieren

Delphi-Quellcode:

a1s := 2;
b1s := 3;
threadhandle:=beginThread(nil,0,TFNThreadStartRoutine(@rechnen),@a1s, 0, threadid);

nun versuch ich schon seit einiger zeit herauszufinden wie man aus 2 parametern einen macht aber was nützliches hab ich noch nicht gefunden.
wie kann ich nun auch b1s mit übergeben?

Erstell ein Record mit den Parametern und übergib den Record an die Funktion.

und wie muss das record aussehen?

markieren

Delphi-Quellcode:

  myrecord = record
    a: Pinteger;
    b: Pinteger;

so oder muss ich dann die integer weitergeben?

Ganz normal. Du übergibst dann den Zeiger auf den Record. Siehe auch mein Threading Tutorial: http://delphitutorials.michael-puff.de

Parameter auf dem Heap ablegen:

zusammenfalten · markieren

Delphi-Quellcode:

(******************************************************************************
*                                                                            *
*  Project: Thread Programmierung unter Windows mit Delphi                  *
*          Paramter-Demo                                                    *
*                                                                            *
*  Copyright (c) Michael Puff  [url]http://www.michael-puff.de[/url]                    *
*                                                                            *
******************************************************************************)

program ParameterHeap;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TThreadParams = packed record
    Number: Integer;
    Text: string;
  end;
  PThreadParams = ^TThreadParams;

function IntToStr(Int: integer): string;
begin
  Str(Int, result);
end;

function ThreadFunc(tp: PThreadParams): Integer;
var
  Number : Integer;
  Text : string;
  s : string;
begin
  // Parameter lokalen Variablen zuweisen.
  Number := PThreadParams(tp)^.Number;
  Text := PThreadParams(tp)^.Text;
  s := 'Zahl: ' + IntToStr(Number) + #13#10 + 'Text: ' + Text;
  // ExitCode enthält Rückgabewert der Messagebox.
  Result := MessageBox(0, PChar(s), 'Thread', MB_YESNO or MB_ICONINFORMATION);
  // Reservierten Speicher für Parameter wieder freigeben.
  Dispose(tp);
end;

procedure RunThread;
var
  tp : PThreadParams;
  Thread : THandle;
  ThreadID : Cardinal;
  ExitCode : Cardinal;
begin
  // Speicher für Struktur reservieren.
  New(tp);
  // Daten den feldern der Struktur zuweisen.
  tp.Number := 42;
  tp.Text := 'Die Antwort.';
  // Thread erzeugen.
  Thread := BeginThread(nil, 0, @ThreadFunc, tp, 0, ThreadID);
  // Auf Beendigung des Threads warten.
  WaitForSingleObject(Thread, INFINITE);
  // Rückgabewert ermitteln...
  GetExitCodeThread(Thread, ExitCode);
  // ...und auswerten.
  case ExitCode of
    IDYES: Writeln('Benutzer hat "Ja" angeklickt.');
    IDNO: Writeln('Benutzer hat "Nein" angeklickt.');
  end;
  // Thread-Handle schliessen udn somit das Thread-Objekt zerstören.
  CloseHandle(Thread);
end;

begin
  RunThread;
  Readln;
end.

Parameter auf dem Stack ablegen:

zusammenfalten · markieren

Delphi-Quellcode:

(******************************************************************************
*                                                                            *
*  Project: Thread Programmierung unter Windows mit Delphi                  *
*          Paramter-Demo                                                    *
*                                                                            *
*  Copyright (c) Michael Puff  [url]http://www.michael-puff.de[/url]                    *
*                                                                            *
******************************************************************************)

program ParameterStack;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TThreadParams = packed record
    Number: Integer;
    Text: string;
  end;
  PThreadParams = ^TThreadParams;

function IntToStr(Int: integer): string;
begin
  Str(Int, result);
end;

function ThreadFunc(tp: PThreadParams): Integer;
var
  Number : Integer;
  Text : string;
  s : string;
begin
  Number := PThreadParams(tp)^.Number;
  Text := PThreadParams(tp)^.Text;
  s := 'Zahl: ' + IntToStr(Number) + #13#10 + 'Text: ' + Text;
  Result := MessageBox(0, PChar(s), 'Thread', MB_YESNO or MB_ICONINFORMATION);
end;

procedure RunThread;
var
  tp : TThreadParams;
  Thread : THandle;
  ThreadID : Cardinal;
  ExitCode : Cardinal;
begin
  tp.Number := 42;
  tp.Text := 'Die Antwort.';
  Thread := BeginThread(nil, 0, @ThreadFunc, @tp, 0, ThreadID);
  WaitForSingleObject(Thread, INFINITE);
  GetExitCodeThread(Thread, ExitCode);
  case ExitCode of
    IDYES: Writeln('Benutzer hat "Ja" angeklickt.');
    IDNO: Writeln('Benutzer hat "Nein" angeklickt.');
  end;
  CloseHandle(Thread);
end;

begin
  RunThread;
  Readln;
end.

Die zweite Möglichkeit funktioniert aber nur, wenn man tatsächlich in der selben Routine auf die Beendigung des Threads wartet. Das dürfte recht selten vorkommen.

Logisch. Da beim Verlassen der Routine die lokalen Variablen ungültig werden. Aber es geht.

Dass du das weißt, war mir klar. Das war nur als Hinweis für den unbedarften Leser gedacht.

danke das hab ich denke ich mal verstanden
jetzt muss ichs nur noch auf meine:
"pointer auf ein array von records die aus pointern auf array von zahlen bestehen" variante umwandeln^^ und nachdem ich das gesachafft hab muss ich rausfinden warum ich zugriffsverletzungen bekomme wenn ich die zahlen verändern will.

statt einem Record könnte man auch ein Objekt übergeben (also die Objektreferenz) ... wollt ich nur mal so erwähnen,
aber das mit dem Record ist wohl gängiger.

Zitat von himitsu:

statt einem Record könnte man auch ein Objekt übergeben (also die Objektreferenz) ... wollt ich nur mal so erwähnen,
aber das mit dem Record ist wohl gängiger.

Und man kan die Threadfunction aucvh gleich asl Methode der zugehörigen Klasse nehmen:

zusammenfalten · markieren

Delphi-Quellcode:

type TmyThread=class
      private
       a,b:Integer;
      public
       function ThreadFunc:Integer;
       property ...
     end;

...

//und im Aufruf:
myThread:=TmyThread.create;
myThread.property:=xyz;
BeginThread(nil,0,@TmyThreadClass.ThreadFunc,myThread,0,id);