Wie ein TComboBox Hintergrundfarbe ändern ?

[madina]

Hallo,

wie kann ich in einem TComboBox die jede 2. Hintergrundfarbe ändern ?
z.B.:
1.Eintrag Hintergrundfarbe weiß
2.Eintrag Hintergrundfarbe rot
3.Eintrag Hintergrundfarbe weiß
4.Eintrag Hintergrundfarbe rot
...usw

mfg

[juergen]

Hallo madina,

im OnDrawItem Event hinterlegst du folgendes:

Delphi-Quellcode:

procedure TForm1.Combobox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
var meine_Farbe: TColor;
begin
  meine_Farbe := ComboBox1.Color;

  with ComboBox1, ComboBox1.Canvas do begin
    if Index mod 2 = 0 then
    begin
      meine_Farbe := clWhite;
      Font.Color:= clblack;
      Brush.Color:= meine_Farbe;
      FillRect(Rect);
      TextOut(Rect.Left+5, Rect.Top+1, Items[index]);
    end
    else
    begin
      meine_Farbe := clRed;
      Font.Color:= clblack; 
      Brush.Color:= meine_Farbe;
      FillRect(Rect);
      TextOut(Rect.Left+5, Rect.Top+1, Items[index]);
    end;
  end;
end;

Und nicht vergessen den Style der Combobox auf csOwnerDrawFixed zu setzen.

[madina]

Hallo,

es fuktioniert danke.

Leider ist meine blaue Markierung verschwunden, wie konnte ich dies wieder kriegen?

mfg

[DeddyH]

Schau Dir mal den State-Parameter an, da steht das drin, Du müsstest das beim Zeichnen dann mit berücksichtigen.

[Satty67]

Hatte es jetzt schon geschrieben, Lerneffekt ist halt dadurch nur bei mir wirksam:

Delphi-Quellcode:

procedure TForm1.ComboBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  FontColor,
  BackColor : TColor;
begin
  if odSelected in State then begin
    FontColor := clHighlightText;
    BackColor := clHighlight;
  end else if (Index mod 2 = 0) then begin
    FontColor := clBlack; // clWindowText
    BackColor := clWhite; // clWindow
  end else begin
    FontColor := clWhite;
    BackColor := clRed;
  end;

  with ComboBox1, ComboBox1.Canvas do begin
    Font.Color:= FontColor;
    Brush.Color:= BackColor;
    FillRect(Rect);
    TextOut(Rect.Left+5, Rect.Top, Items[index]);
  end;
end;