DLL Dynamisch laden Problem

[Hybrid666]

hi, ich versuche in meinem programm eine dll dynamisch zu laden und ihr eine info zu entlocken. Ich poste hier einfach mal den code:

Hier wird die DLL geladen und die funktion ausgeführt:

Delphi-Quellcode:

function TForm1.GetPluginInfo (Name : PChar; Plugin : String) : PChar;
type
  TDLLFunc = function():PChar;
var
  DLLHandle : THandle;
  Ret : PChar;
  func : TDllFunc;
begin
  Ret := '';
  DLLHandle := LoadLibrary (PChar(ExtractFilePath (Application.ExeName) + 'Plugins\' + Plugin + '.dll'));
  if DLLHandle >= 32 then
  begin
    @func := GetProcAddress (DLLHandle, Name);
    if Assigned (func) then Ret := func();
    FreeLibrary (DLLHandle);
  end;
  result := Ret;

end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage (String (GetPluginInfo ('GetButtonFunc', 'winamp')));
end;

Hier ist der code der dll:

Delphi-Quellcode:

library winamp;

{ Important note about DLL memory management: ShareMem must be the
  first unit in your library's USES clause AND your project's (select
  Project-View Source) USES clause if your DLL exports any procedures or
  functions that pass strings as parameters or function results. This
  applies to all strings passed to and from your DLL--even those that
  are nested in records and classes. ShareMem is the interface unit to
  the BORLNDMM.DLL shared memory manager, which must be deployed along
  with your DLL. To avoid using BORLNDMM.DLL, pass string information
  using PChar or ShortString parameters. }

uses
  SysUtils,
  Classes;

{$R *.res}

function GetButtonFunc():PChar;export;
begin
  result := PChar('Play|Pause|Stop|Start|Close|ToggleShuffle|ToggleRepeat|NextTrack|PreviousTrack|Volume');
end;

exports
  GetButtonFunc;
begin
end.

Das problem ist das ich eine Access violation bekomme.

Mittlerweile hab ich rausbekommen das es an FreeLibrary liegt, wenn ichs weglasse tut alles wunnerbar.

mfG

[mkinzler]

Du entlädst die Dll auch gleich wieder
FreeLibrary (DLLHandle);

[SirThornberry]

Ich glaube dir fehlt das Bewusstsein was PChar eigentlich ist und du handhabst es daher wie einen normalen String.

[Hybrid666]

dann erklärs mir naja wenn ich wüsste warum der fehler kommt find ich bestimmt auch ne lösung.

[sirius]

Der String befindet sich in der DLL Und du bekommst nur den Zeiger darauf zurück. Wenn die DLL entladen wird, ist auch der String weg.

Edit: Normalerweise ist der String bereits am Ende der Funktion weg. Das ist hier nur nicht der Fall, weil du eine Stringkonstante verwendest, welche im DLL-Image liegt.
Du musst das Konzept komplett umstellen: Speicher in der Exe reservieren. Zeiger auf den Speicher an DLL übergeben. DLL kopiert den Inhalt und fertig.
Oder du nutzt WideString.

[SirThornberry]

PChar ist nichts anderes als ein Pointer nur eben ein typiserter so das jeder sofort weiß "Ah, ein Pointer der auf Zeichen zeigt".
Wenn deine Funktion jetzt einen PChar zurück gibt, so ist dies nichts anderes als ein Pointer auf "'Play|Pause|Stop|Start|Close|ToggleShuffle|Toggle Repeat|NextTrack|PreviousTrack|Volume'" was irgendwo im Speicher der DLL steht.
Gibst du die DLL frei wird somit auch der Speicher freigegeben worauf dein Pointer zeigt.

Daher ist es üblich das nicht ein Pointer zurück gegeben wird sondern das einer Funktion ein Buffer (Speicher) übergeben wird und in diesen Speicher wird dann rein kopiert.

Hier ein Beispiel:

Delphi-Quellcode:

//Der Funktion muss entsprechend Speicher übergeben werden und eine Angabe wie groß dieser ist
//Die Funktion gibt zurück wie groß der Speicher sein muss bzw. wieviel in den Speicher kopiert wurde
function GetButtonFunc(Buffer: PChar; MaxSize: Integer):Integer ;export; 
var
  deinString: String;
begin 
  deinString := 'Play|Pause|Stop|Start|Close|ToggleShuffle|ToggleRepeat|NextTrack|PreviousTrack|Volume';
  if (MaxSize >= Length(deinString)) then
    move(deinString[1], Buffer^, Length(deinString));
  result := Length(deinString);
end;

Ein Aufruf kann dann so aussehen:

Delphi-Quellcode:

var
  neededSize: Integer;
  meinString: String;
begin
  neededSize := GetButtonFunc(nil, 0);
  SetLength(meinString, neededSize);
  GetButtonFunc(@meinString[1], neededSize);
  ShowMessage(meinString);

[thkerkmann]

Warum so kompliziert:

die Funktion

Delphi-Quellcode:

function TForm1.GetPluginInfo (Name : PChar; Plugin : String) : PChar;
var
  DLLHandle : THandle;
  Ret : PChar;

ist doch im Programm.

Wenn ihr Type string ist und nicht pChar ist alles prima.
Dann wird der pChar aus der Dll in den String kopiert und gut.

also:

Delphi-Quellcode:

function TForm1.GetPluginInfo (Name : PChar; Plugin : String) : string;
var
  DLLHandle : THandle;
  Ret : string; // wichtig hier auch

Gruss

[sirius]

Zitat von thkerkmann:

Wenn ihr Type string ist und nicht pChar ist alles prima.
Dann wird der pChar aus der Dll in den String kopiert und gut.

Es geht um den Aufruf einer Funktion (GetButtonFunc) aus einer DLL.