Exception bei writeln

[Thomas F]

Wieso funktioniert der folgende Code nicht ?
Erst wenn ich das Programm zum zweiten Mal starte und die Datei 'Test.txt' schon existiert,
gibt es keine Exception !
Wenn ich die Datei 'Test.txt' lösche und das Programm starte kommt diese
Meldung: Exception .......'E/A-Fehler 32'

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject);
var f:Textfile;
begin
assignfile(f,'Test.txt');
rewrite(f);
writeln(f,'blablabla');
closefile(f);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
if not fileexists ('Test.txt') then

filecreate('Test.txt');
end;

[nachti1505]

Wie sieht denn die FileCreate aus?

[DeddyH]

Aus der Hilfe zu FileCreate:

Zitat:

Hinweis

Die Verwendung der nichtnativen Pascal-Dateiroutinen wie FileCreate ist nicht zu empfehlen. Diese Low-Level-Routinen entsprechen den Windows-API-Funktionen und geben Datei-Handles zurück, keine normalen Pascal-Dateivariablen. Verwenden Sie für normale Dateioperationen statt dessen AssignFile, Rewrite und Reset.

[Thomas F]

Oh Mann

Einfach das FileCreate weglassen, dann gehts !

Danke

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject); 
var f:Textfile; 
begin 
assignfile(f,'Test.txt'); 
rewrite(f); 
writeln(f,'blablabla'); 
closefile(f); 
end;

[himitsu]

Zitat von Thomas F:

Einfach das FileCreate weglassen, dann gehts !

Das ist aber nicht die richtge Lösung.

Grund für den Fehler war eine fehlerhafte Verwendung von FileCreate.

siehe Zitat von DeddyH, hast du vergessen das Dataihandle entgegenzunehmen und vorallem hast du vergesen die mit CreateFile geöffnte Datei wieder zu schließen.

Und da Rewrite keine Sharing-Rechte zuläßt schlägt der Vorgang, Aufgrund der geöffneten Datei, fehl.

[DeddyH]

Das FileCreate war aber hier wirklich überflüssig. Allerdings wäre eine Fehlerbehandlung für das AssignFile,Rewrite...-Gespann schon ganz sinnvoll.

[Thomas F]

Zitat von DeddyH:

Das FileCreate war aber hier wirklich überflüssig. Allerdings wäre eine Fehlerbehandlung für das AssignFile,Rewrite...-Gespann schon ganz sinnvoll.

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject); 
var f:Textfile; 
begin 
try
assignfile(f,'Test.txt'); 
rewrite(f); 
writeln(f,'blablabla'); 
closefile(f); 
except
closefile(f);
end;
end;

....so am besten..

[himitsu]

wenn schon, dann so: (verwendete Variablen im Exceptionblock vorher initialisieren)

Delphi-Quellcode:

assignfile(f, 'Test.txt');
try
  Rewrite(f);
  WriteLn(f, 'blablabla');
  CloseFile(f);
except
  CloseFile(f);
end;

oder lieber so:

Delphi-Quellcode:

AssignFile(f, 'Test.txt');
try
  Rewrite(f);
  WriteLn(f, 'blablabla');
finally
  CloseFile(f);
end;

Aber besser doch erst garkeine Exception auslösen (wird im Beispiel der OH auch so gemacht)

Delphi-Quellcode:

{$I-}
AssignFile(f, 'Test.txt');
Rewrite(f);
WriteLn(f, 'blablabla');
CloseFile(F);
{$I+}
if IOResult <> 0 then FehlerBehandlung;

[Fussball-Robby]

Zitat von Thomas F:

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject); 
var f:Textfile; 
begin 
try
assignfile(f,'Test.txt'); 
rewrite(f); 
writeln(f,'blablabla'); 
closefile(f); 
except
closefile(f);
end;
end;

Das ist aber nicht sinnvoll, da CloseFile hier auf jeden Fall aufgerufen wird - und für sowas benutzt man i.d.R. try..finally:

Delphi-Quellcode:

procedure TForm1.FormShow(Sender: TObject); 
var
  f: TextFile; 
begin 
  try
    AssignFile(f, 'Test.txt'); 
    Rewrite(f); 
    WriteLn(f, 'blablabla'); 
  finally
    CloseFile(f);//das wird auf jeden Fall ausgeführt
  end;
end;

Es gibt sicherlich sinnvolere Fehlerbehandlungen, aber mit diesen Routinen kenne ich mich nicht so gut aus

[quendolineDD]

Der Finally-Block wird aber auch auf jeden Fall aufgerufen.

Zitat:

Jede Anweisungsliste setzt sich aus einer Folge von Anweisungen zusammen. In einem try...finally-Block werden zuerst die Programmzeilen in Anweisungsliste1 (try-Klausel) ausgeführt. Wenn dabei keine Exceptions auftreten, wird anschließend Anweisungsliste2 (finally-Klausel) ausgeführt. Bei einer Exception wird die Steuerung an Anweisungsliste2 übergeben und danach die Exception erneut ausgelöst. Befindet sich ein Aufruf der Standardprozedur Exit, Break oder Continue in Anweisungsliste1, wird dadurch automatisch Anweisungsliste2 aufgerufen. Daher wird die finally
-Klausel unabhängig davon, wie der try-Block beendet wird, immer ausgeführt.

Wenn eine Exception ausgelöst, aber in der finally-Klausel nicht behandelt wird, führt sie aus der try...finally-Anweisung hinaus, und jede zuvor in der try-Klausel ausgelöste Exception geht verloren. In der finally-Klausel sollten daher alle lokal ausgelösten Exceptions behandelt werden, damit die Behandlung anderer Exceptions nicht gestört wird.