Picture aus String laden

[mkmk]

Guten Tag allerseits

Von der seriellen Schnittstelle bekomme ich von einem Controller ein Bild im Jpeg Format zugesendet.
Im 1. Schritte habe ich diese Daten in eine Datei 'bild.jpg' geschrieben und dann mit
Form1.Image1.Picture.LoadFromFile('bild.jpg'); in der Form angezeigt.

Um dann nicht den Umweg über die Disk zu nehmen, habe ich es über String geladen. Nur: obwohl es einwandfrei funktioniert, habe ich keine Ahnung, ob ich alles richtig gemacht habe. Denn das meiste habe ich mehr intuitiv denn diskursiv gemacht. Darf ich Euch bitten, die folgenden Zeilen zu kritisieren.
Danke für eure Mithilfe.

Delphi-Quellcode:

//==============================
//  ListView1 Click
//==============================
procedure TForm1.ListView1Click(Sender: TObject);
  var nPictNr : Integer;
      cBild   : String;
      TmpJpg  : TJPEGImage;
      memStream  : TMemoryStream;
begin
  nPictNr := StrToInt(ListView1.Items[ListView1.ItemIndex].Caption);

  cBild := MyComPort.SendPicture(nPictNr);
  if cBild <> '' then begin
     memStream := TMemoryStream.Create();
     memStream.WriteBuffer(cBild[1], Length(cBild));
     memStream.Position := 0;
     TmpJpg := TJPEGImage.Create;
     TmpJpg.LoadFromStream(memStream);

     Form1.Image1.Picture.Assign(TmpJpg);
  end;
end;

[shmia]

Mit einem TStringStream wird die Sache noch eleganter:

Delphi-Quellcode:

cBild := MyComPort.SendPicture(nPictNr); 
  if cBild <> '' then 
  begin 
     strStream := TStringStream.Create(cBild); 
     TmpJpg := TJPEGImage.Create; 
     TmpJpg.LoadFromStream(memStream); 

     Image1.Picture.Assign(TmpJpg);  // unbedingt Form1. weglassen !!!
     TmpJpg.Free; // nicht vergessen !!
  end;

[SirThornberry]

wie bereits angemerkt hast du vergessen das jpg frei zu geben.
Zudem wäre es empfehlenswert da mit try-finally zu arbeiten damit es nicht zu unvorhergesehenen Dingen kommt falls mal kein Bild an der seriellen Schnittstelle empfangen wird oder ein Bild welches im falschen Format ist.

[mkmk]

Ich habe TStringStream und try-finally in mein Programm eingebaut. Danke für die Anmerkungen.

[SirThornberry]

ich habe gerade noch etwas gesehen. Neben dem Jpeg gibst du auch den Stream nicht frei.
Kannst du nochmal den aktuellen Quelltext posten?

[mkmk]

Zitat von SirThornberry:

ich habe gerade noch etwas gesehen. Neben dem Jpeg gibst du auch den Stream nicht frei.
Kannst du nochmal den aktuellen Quelltext posten?

Delphi-Quellcode:

//==============================
//  ListView1 Click
//==============================
procedure TForm1.ListView1Click(Sender: TObject);
  var nPictNr : Integer;
      cBild   : String;
      TmpJpg  : TJPEGImage;
      strStream : TStringStream;
begin
  nPictNr := StrToInt(ListView1.Items[ListView1.ItemIndex].Caption);
//   ListView.Items[ListView1.ItemIndex].SubItems[0] waere 2. Spalte

  cBild := MyComPort.SendPicture(nPictNr,  ProgressBar1);
  if cBild <> '' then begin
    strStream := TStringStream.Create(cBild);
    TmpJpg := TJPEGImage.Create;
    TmpJpg.LoadFromStream(strStream);
    Form1.Image1.Picture.Assign(TmpJpg);
    TmpJpg.Free;
  end;
end;

Noch eine Frage: warum muss ich TmpJpg.free schreiben? Ist TmpJpg nicht eine locale Variable?

Edit: Try-Finaly herauskommentiert, weil noch fehlerhaft.

[mkmk]

Vergiss meine Frage
TmpJpg und strStream sind ja nur Pointer, die mit Create erschaffen werden; und deshalb mit free auch wieder aus der Memory entfernt werden müssen.

[mkmk]

Der Code in seiner ganzen strahlenden Schönheit:

Delphi-Quellcode:

//==============================
//  ListView1 Click
//==============================
procedure TForm1.ListView1Click(Sender: TObject);
  var nPictNr : Integer;
      cBild   : String;
      TmpJpg  : TJPEGImage;
      strStream : TStringStream;
begin
  nPictNr := StrToInt(ListView1.Items[ListView1.ItemIndex].Caption);
//   ListView.Items[ListView1.ItemIndex].SubItems[0] waere 2. Spalte

  cBild := MyComPort.SendPicture(nPictNr,  ProgressBar1);
  if cBild <> '' then begin
    try
      strStream := TStringStream.Create(cBild);
      TmpJpg := TJPEGImage.Create;
      TmpJpg.LoadFromStream(strStream);
      Form1.Image1.Picture.Assign(TmpJpg);
    finally
      TmpJpg.Free;
      strStream.Free;
    end;
  end;
end;

[jaenicke]

Die beiden Creates gehören vor das try . Wenn im Konstruktor ein Fehler auftritt, räumt Delphi das selber wieder auf.

[alzaimar]

Delphi-Quellcode:

//==============================
//  ListView1 Click
//==============================
procedure TForm1.ListView1Click(Sender: TObject);
  var nPictNr : Integer;
      cBild   : String;
      TmpJpg  : TJPEGImage;
      strStream : TStringStream;
begin
  nPictNr := StrToInt(ListView1.Items[ListView1.ItemIndex].Caption);
//   ListView.Items[ListView1.ItemIndex].SubItems[0] waere 2. Spalte

  cBild := MyComPort.SendPicture(nPictNr,  ProgressBar1);
  if cBild <> '' then begin
    strStream := TStringStream.Create(cBild);
    Try
      TmpJpg := TJPEGImage.Create;               
      Try                                          
        TmpJpg.LoadFromStream(strStream);        
        Form1.Image1.Picture.Assign(TmpJpg);     
      Finally                                     
        TmpJpg.Free;                              
      End;                                       
    Finally                                      
      strStream.Free;
    End;
  end;
end;

Zitat von mkmk:

Noch eine Frage: warum muss ich TmpJpg.free schreiben? Ist TmpJpg nicht eine lokale Variable?

Das stimmt, aber es handelt sich um einen Zeiger auf einen alloziierten Speicherbereich. Delphi räumt hier nicht automatisch auf.