TPersistent über Findclass erzeugen und Constructor

[Rainer Wolff]

Hallo Delphi-User,

Ich will Klassen über FindClass nach folgendem Schema erzeugen. Ich wundere mich aber, warum kein Constructor der Klasse TTest aufgerufen wird. Anscheinend wird nur der Constructor von TObject aufgerufen, aber nicht der von TTest.
Erzeuge ich jedoch TTest direkt über einen Aufruf TTest.Create, scheint der Constructor aufgerufen zu werden.

Wo liegt hier noch mein Fehler?

Vielen Dank

Rainer

Delphi-Quellcode:

  TTest = class(TPersistent)
  private
    FX: Integer;
  public
    constructor Create; virtual;
    property X: Integer read FX write FX;
  end;

constructor TTest.Create;
begin
  x:=5;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  tc: TPersistentClass;
begin
  tc:=FindClass('TTest');
  p:=TPersistent(tc.Create);
end;

initialization
  RegisterClass(TTest);

finalization
  UnRegisterClass(TTest);

[mkinzler]

Versuch es mal so:

Delphi-Quellcode:

TTest = class(TPersistent)
  private
    FX: Integer;
  public
    constructor Create; virtual; override;
    property X: Integer read FX write FX;
  end;

constructor TTest.Create;
begin
  inherited Create;
  FX:=5;
end;

[Rainer Wolff]

Geht nicht

    constructor Create; virtual; override;

Zitat:

[Pascal Fehler] Unit1.pas(19): E2169 Felddefinition nicht erlaubt nach Methoden oder Eigenschaften

    constructor Create; override; virtual;

Zitat:

[Pascal Fehler] Unit1.pas(19): E2170 Eine nichtvirtuelle Methode kann nicht überschrieben werden

Ausserdem funktioniert der Constructor ja, wenn ich ihn über TTest.Create erzeuge.

Ich habe ein funktionierendes Beispiel aus der DP, das aber mit Objekten arbeitet, die von TComponent statt TPersistent abgeleitet sind, da funktionierts komischerweise.

[Hawkeye219]

Hallo Rainer,

der Konstruktor von TPersistent ist statisch, du benötigst also eine eigene Klassenreferenz, um dem Compiler deinen Wunsch mitzuteilen:

Delphi-Quellcode:

type
  TTestClass = class of TTest;
  
procedure TForm1.FormCreate(Sender: TObject);
var
  tc: TPersistentClass;
  p : TPersistent; // oder TTest
begin
  tc:=FindClass('TTest');
  p:=TTestClass(tc).Create;
end;

Gruß Hawkeye