Probleme mit TWideStrings und TStringList

[toyoman]

habe folgendes problem mit einem alten delphi5 projekt:

wenn ich es mit delphi2007 kompilieren will, bekomme ich an versch. stellen folgende meldung:
E2010 Inkompatible Typen: TWideStrings und TStringListe.

beispiel eines fehlerauftritts (siehe markierter bereich):

Delphi-Quellcode:

procedure TInfoForm.ShowInfo( title: string; db: TSQLConnection; sql: TStringList; init_val: string );
  var
    csr: TCursor;
    ic, cw: integer;
    qry: TSQLQuery;
    dsp: TDataSetProvider;

  begin
  if Assigned( cds ) then
    cds.Free;

  cds := TClientDataSet.Create( nil );
  cds.ReadOnly := True;
  cds.OnFilterRecord := FilterRecord;
  cds.Filtered := False;

  Caption := title;

  FilterText  := '';
  FilterIndex := 1;
  FindText.Text := FilterText;

  FValue := '';

  csr := Screen.Cursor;
  try
    Screen.Cursor := crSQLWait;

    qry := TSQLQuery.Create( nil );
    dsp := TDataSetProvider.Create( nil );

    cds.Active := False;

    qry.SQLConnection := db;
 -->   qry.SQL      := sql; // PROBLEM!!!!
    dsp.DataSet  := qry;
    cds.SetProvider( dsp );

    cds.Active := True;
    cds.SetProvider( nil );
    dsp.Free;
    qry.Free;

    DataSource.DataSet := cds;

    SetBestColWidth( DBGrid );

    // Fit Formwidth to all Colwidths ...
    cw := (DbGrid.Columns.Count-1) +16;   // +16: Scrollbar
    for ic := 0 to DbGrid.Columns.Count-1 do
      cw := cw +DbGrid.Columns[ic].Width;
    ClientWidth := cw +DbGrid.Width -DbGrid.ClientWidth;

    Screen.Cursor := crHourGlass;

    FindSelector.Items.Clear;
    for ic := 0 to DbGrid.Columns.Count-1 do
      FindSelector.Items.Add( DbGrid.Columns[ic].Title.Caption );
    FindSelector.ItemIndex := 1;

    Screen.Cursor := csr;

    init_val := Trim( init_val );
    if (Length( init_val ) > 0) then
      begin
      cds.IndexFieldNames := DbGrid.Columns[0].FieldName;
      if not cds.FindKey( [init_val] ) then
        cds.First
      end
    else
      begin
      cds.IndexFieldNames := DbGrid.Columns[1].FieldName;
      cds.First
      end;

    ShowModal
  finally
    Screen.Cursor := csr
    end
  end;

wie kann ich diese probleme mit möglichst wenig aufwand lösen bzw. das programm delphi 2007 tauglich machen?
bin dankbar für jede idee!

[sx2008]

Du solltest die Procedure so ändern:

Delphi-Quellcode:

// parameter <sql> hat jetzt den Typ TStrings
procedure TInfoForm.ShowInfo( title: string; db: TSQLConnection; sql: TStrings; init_val: string );

Wahrscheinlich reicht das schon.
Falls nicht, versuch mal:
 qry.SQL.Assign(sql); Wenn das nicht klappt, dann

Delphi-Quellcode:

qry.SQL.Clear;
qry.SQL.AddStrings(sql);

[nahpets]

Hallo,

nur Spekulation:

Funktioniert nicht das?

qry.SQL.text := sql.text; Stephan

[DeddyH]

Wobei mir gerade aufgefallen ist:

Zitat:

Delphi-Quellcode:

if Assigned( cds ) then
    cds.Free;

Das sollte man IMHO ändern:

Delphi-Quellcode:

if Assigned( cds ) then
    FreeAndNil(cds);

Nach dem Free ist das Objekt nämlich immer noch Assigned, das kann u.U. böse ins Auge gehen.

[Elvis]

Zitat von DeddyH:

Nach dem Free ist das Objekt nämlich immer noch Assigned, das kann u.U. böse ins Auge gehen.

Er besetzt es doch direkt danach wieder.

[DeddyH]

Und im nächsten Projekt werden Codeteile kopiert ("hat ja immer funktioniert") und das Objekt nicht sofort neu angelegt. Da staunt dann der Fachmann und der Laie wundert sich Wieso nicht besser gleich "defensiv" programmieren?

[toyoman]

halt stopp! ich hab das nicht programmiert
funktioniert aber sonst gut das progrämmchen. allerdings steh ich nun an anderen stellen an.
das mit dem sql -> definition TStrings anstatt TStringlist hat funktioniert, danke!