Problem mit ListBox

[gfjs]

Guten Morgen @all.

Ich habe auf ein Formular eine ListBox gesetzt, kann aber zur Laufzeit keine Eingaben machen. Was habe ich da falsch gemacht?

Dankbar für jeden Tip ist

Jürgen

[Blackheart]

Du meinst editieren ? dafür ist die Listbox nicht gedacht vieleicht wäre Stringgrid ja was für deine Zwecke.

[extrem]

Hallo,

ein TListView wäre dafür auch geeignet.

[marabu]

Moin Jürgen,

direkt in der ListBox ändern kannst du zwar nicht, aber manchmal will man das auch gar nicht.

Delphi-Quellcode:

procedure TDemoForm.ListBoxDblClick(Sender: TObject);
var
  s: string;
begin
  with Sender as TListBox do
    if ItemIndex > -1 then
    begin
      s := Items[ItemIndex];
      if InputQuery('Bearbeiten', 'Text', s) then
        Items[ItemIndex] := s;
    end;
end;

Freundliche Grüße

[toms]

Zitat von extrem:

Hallo,

ein TListView wäre dafür auch geeignet.

So kannst du TListView so aussehen lassen wie eine TListBox aber mit editierbaren Items.

TListView mit einer Spalte (AutoSize := True)

ViewStyle := vsReport
RowSelect := True
ShowColumnHeaders := False

[turboPASCAL]

@marabu, schöne Idee.

[gfjs]

Guten Morgen,

und vielen Dank für die schnellen Antworten. Da habe ich wohl etwas falsch verstanden:

Zitat:

Mit einem TListBox-Objekt können Sie eine bildlauffähige Liste anzeigen, deren Einträge vom Benutzer ausgewählt, hinzugefügt oder gelöscht werden können.

Ich kann allerdings auch keinen der zur Entwurfzeit erstellten Einträge zur Laufzeit löschen. - Irgenwie stehe ich wohl auf der Leitung?!

Gruß Jürgen

[toms]

Ein Item kannst du so löschen:

Listbox1.Items.Delete(ItemIndex);

[gfjs]

Danke für die Antworten - ich dachte ListBox sei viel komfortabler (z.B. markierten + entf + weg isses).

[marabu]

Du musst nur wissen, was du willst.

So kann z.B. eine Tastaturschnittstelle ausehen:

Delphi-Quellcode:

procedure TDemoForm.ListBoxKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var
  s: string;
  i: Integer;
begin
  with Sender as TListBox do
    case Key of
      VK_INSERT:
      begin
        s := '';
        if InputQuery('Hinzufügen', 'Text', s) then
          if Trim(s) <> '' then
            Items.Insert(ItemIndex, s);
      end;
      VK_DELETE:
        if ItemIndex > -1 then
          Items.Delete(ItemIndex);
      VK_SPACE:
      begin
        s := Items[ItemIndex];
        if InputQuery('Bearbeiten', 'Text', s) then
          if Trim(s) <> '' then
            Items[ItemIndex] := s;
      end;
      VK_UP:
        if (ItemIndex > 0) and (ssCtrl in Shift) then
        begin
          i := ItemIndex;
          Items.Exchange(Pred(ItemIndex), ItemIndex);
          ItemIndex := i;
        end;
      VK_DOWN:
        if (Succ(ItemIndex) < Count) and (ssCtrl in Shift) then
        begin
          i := ItemIndex;
          Items.Exchange(Succ(ItemIndex), ItemIndex);
          ItemIndex := i;
        end;
    end;
  // Key := 0;
end;