Gelöst: Vierten Zeitstempel ermitteln

[nicodex]

Zitat von Garfield:

Dein Code funktioniert, aber meinem ist die Deklaration egal.

Ich verstehe nicht ganz, wo jetzt genau das Problem liegt.
In meinem Code steht {$ALIGN 8} und {$MINENUMSIZE 4}, um von den Compiler-Einstellungen unabhängig zu sein.
Und ich verstehe nicht ganz, warum du unbedingt NtQueryAttributesFile verwenden möchtest (und damit den Win32-Pfad in einen Objektnamen auflösen musst - was fehleranfällig ist, da nicht jeder Dateiname mit einem Laufwerksbuchstaben beginnt (UNC-Präfix, \\?\-Präfix, Volume-Präfix, usw...)).

[Garfield]

Wenn man sich ein Handle auf die Datei holt, wird die LastAccessTime geändert, was ich vermeiden möchte.

[Garfield]

Object_Attributes ist ja so deklariert:

Code:

typedef struct _OBJECT_ATTRIBUTES {
    ULONG  Length;
    HANDLE  RootDirectory;
    PUNICODE_STRING  ObjectName;
    ULONG  Attributes;
    PVOID  SecurityDescriptor;
    PVOID  SecurityQualityOfService;
} OBJECT_ATTRIBUTES, *POBJECT_ATTRIBUTES;
typedef CONST OBJECT_ATTRIBUTES *PCOBJECT_ATTRIBUTES;

Da ist ein Handle auf das RootDirectory und der PUNICODE_STRING für den Objektname. Der Dateiname samt Pfad als Object funktioniert nicht. Also müsste man es über das Handle versuchen. Wenn ich den Objektnamen leer lasse und das Handle auf die Datei verwende, funktioniert es:

Delphi-Quellcode:

function GetNTTime(fn: String; var FileInformation: FILE_BASIC_INFORMATION): Boolean;
const
  FILE_READ_ATTRIBUTES = $0080;
var
  strDosDeviceName : ANSI_STRING;
  RootDirectory    : THandle;
  FileName         : ANSI_STRING;
  szNtDeviceName   : array[0..MAX_PATH] of Char;
  ObjName          : UNICODE_STRING;
  ObjectAttributes : OBJECT_ATTRIBUTES;
  Buffer           : array of WideChar;
  Status           : NTSTATUS;
  DosErr           : DWORD;
  Error            : PChar;
begin
  Result := False;

  RtlZeroMemory(@strDosDeviceName, SizeOf(ANSI_STRING));
  RtlZeroMemory(@ObjName, SizeOf(UNICODE_STRING));
  RtlZeroMemory(@ObjectAttributes, SizeOf(OBJECT_ATTRIBUTES));
  RtlZeroMemory(@FileInformation, SizeOf(FILE_BASIC_INFORMATION));

  RootDirectory := CreateFile(PAnsiChar(fn), FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);

  InitializeObjectAttributes(@ObjectAttributes, @ObjName, OBJ_CASE_INSENSITIVE, RootDirectory, nil);

  Status := NtQueryAttributesFile(@ObjectAttributes, @FileInformation);

  Result := NT_SUCCESS(Status);

  if not Result
  then begin
    doserr := RtlNtStatusToDosError(Status);
    SetLastError(DosErr);
    GetMem(Error, 255);
    FormatMessage(FORMAT_MESSAGE_ALLOCATE_BUFFER or FORMAT_MESSAGE_FROM_SYSTEM, nil, GetLastError, 0, @Error, 255, nil);
    ShowMessage(Trim(Error));
  end;
end;

Jetzt wollte ich den Pfad aufteilen, damit ich kein Handle auf die Datei nehmen muss.
  RootDirectory := CreateFile(PAnsiChar(ExtractFileDrive(fn)), FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0); Ergibt ein ungültiges Handle. Deshalb

Delphi-Quellcode:

  QueryDosDevice(PAnsiChar(ExtractFileDrive(fn)), szNtDeviceName, MAX_PATH);
  RootDirectory := CreateFile(szNtDeviceName, FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);

Allerdings scheint es egal zu sein, wie ich den Dateinamen aufteile:

Delphi-Quellcode:

  QueryDosDevice(PAnsiChar(ExtractFileDrive(fn)), szNtDeviceName, MAX_PATH);
  RootDirectory := CreateFile(PAnsiChar(szNtDeviceName + Copy(ExtractFilePath(fn), 3, Length(ExtractFilePath(fn)) - 2)), FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);
  RtlInitAnsiString(@FileName, PAnsiChar(ExtractFileName(fn)));
  RtlAnsiStringToUnicodeString(@ObjName, @FileName, True);

Delphi-Quellcode:

  QueryDosDevice(PAnsiChar(ExtractFileDrive(fn)), szNtDeviceName, MAX_PATH);
  RootDirectory := CreateFile(szNtDeviceName, FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);
  RtlInitAnsiString(@FileName, PAnsiChar(Copy(fn, 4, Length(fn) - 3)));
  RtlAnsiStringToUnicodeString(@ObjName, @FileName, True);

Es gibt immer diesen Fehler:

Code:

---------------------------
Filetime
---------------------------
Unzulässiger Zugriff auf einen Speicherbereich.
---------------------------
OK   
---------------------------

Nehme ich das Handle auf die Datei und die Datei als Object:

Delphi-Quellcode:

  RootDirectory := CreateFile(PAnsiChar(fn), FILE_READ_ATTRIBUTES, FILE_SHARE_READ, nil, OPEN_EXISTING, 0, 0);
  RtlInitAnsiString(@FileName, PAnsiChar(ExtractFileName(fn)));
  RtlAnsiStringToUnicodeString(@ObjName, @FileName, True);

bekomme ich den Fehler:

Code:

---------------------------
Filetime
---------------------------
Das System kann den angegebenen Pfad nicht finden.
---------------------------
OK   
---------------------------

[Garfield]

Gelöst!

Der Fehler

Code:

---------------------------
Filetime
---------------------------
Unzulässiger Zugriff auf einen Speicherbereich.
---------------------------
OK   
---------------------------

lag an
  QueryDosDevice(PAnsiChar(ExtractFileDrive(fn)), szNtDeviceName, MAX_PATH); Das ungültige Handle lag an falschen Parametern. Jetzt sieht es so aus:

Delphi-Quellcode:

function GetNTTime(fn: String; var FileInformation: FILE_BASIC_INFORMATION): Boolean;
const
  FILE_LIST_DIRECTORY = $0001;
var
  RootDirectory    : THandle;
  FileName         : ANSI_STRING;
  ObjName          : UNICODE_STRING;
  ObjectAttributes : OBJECT_ATTRIBUTES;
  Status           : NTSTATUS;
  DosErr           : DWORD;
  Error            : PChar;
begin
  Result      := False;

  RtlZeroMemory(@ObjName, SizeOf(UNICODE_STRING));
  RtlZeroMemory(@ObjectAttributes, SizeOf(OBJECT_ATTRIBUTES));
  RtlZeroMemory(@FileInformation, SizeOf(FILE_BASIC_INFORMATION));

  RootDirectory := CreateFile(PAnsiChar(ExtractFilePath(fn)), FILE_LIST_DIRECTORY, FILE_SHARE_READ, nil, OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
  RtlInitAnsiString(@FileName, PAnsiChar(ExtractFileName(fn)));
  RtlAnsiStringToUnicodeString(@ObjName, @FileName, True);

  InitializeObjectAttributes(@ObjectAttributes, @ObjName, OBJ_CASE_INSENSITIVE, RootDirectory, nil);

  Status := NtQueryAttributesFile(@ObjectAttributes, @FileInformation);

  Result := NT_SUCCESS(Status);

  if not Result
  then begin
    doserr := RtlNtStatusToDosError(Status);
    SetLastError(DosErr);
    GetMem(Error, 255);
    FormatMessage(FORMAT_MESSAGE_ALLOCATE_BUFFER or FORMAT_MESSAGE_FROM_SYSTEM, nil, GetLastError, 0, @Error, 255, nil);
    ShowMessage(Trim(Error));
  end;

  CloseHandle(RootDirectory);
end;

Das scheint auch ein Irrtum zu sein:

Zitat von Garfield:

Wenn man sich ein Handle auf die Datei holt, wird die LastAccessTime geändert, was ich vermeiden möchte.

Vielen Dank an nicodex. Durch ihn habe ich wieder einiges gelernt.