Wörter in einem String isolieren

[Hansa]

Zitat von S20000:

das aufsplitten der Liste habe ich jetzt hinbekommen.
Ich hätte noch eine weitere Frage...

Toll. Nur wie ? Denkanstöße sind im Entwickler 4/2004 zu finden.

[S20000]

@everdream
Du meinst also meine Datei erst in Excel in xml bringen und dann
mit Delphi einlesen?

Sry, das aufspliten habe ich folgendermaßen gemacht

Delphi-Quellcode:

procedure Split(const aValue, aDelimiterChars: string; var Result: TStringList);
var
  p, len: integer;
  s: string;
begin
  if Result = nil then Result := TStringList.Create;
  Result.Clear;
  S := '';
  p := 1;
  len := Length(aValue);
  while p <= len do
    begin
    if Pos(aValue[p], aDelimiterChars) = 0 then
      begin
      s := s + aValue[p];
      Inc(p);
      end
    else
      begin
      Result.Add(s);
      s := '';
      Inc(p);
      while (Pos(aValue[p], aDelimiterChars) <> 0) and (p <= len) do Inc(p);
      end;
    end;
  if s <> '' then Result.Add(s);
end;

[mkinzler]

Die Verwendung eines Parameters mit der ezeichnung result ist gefährlich, da er in Funktionen automatsich für den Rückgabewert genommen wird.

[marabu]

Hallo Sebastian,

man kämpft eigentlich immer an zwei Fronten: Problemverständnis und Lösungsansatz. Hier mal deine Problembeschreibung nach meinem Verständnis:

Problem Statement

Gegeben ist ein ANSI kodierter String mit folgendem Aufbau: Substring *(Separator Substring). Einem Substring folgen beliebig viele weitere Substrings, die durch einen Separator vom vorhergehenden Substring abgesetzt sind, wobei der Separator wechseln kann und aus beliebig vielen Zeichen bestehen darf.

Das lässt sich wunderbar über Regular Expressions lösen, aber auch prozedural:

Delphi-Quellcode:

procedure Split(const line: string; const separators: array of string; strings: TStrings);
var
  iPos, iSep, iStart: Integer;
begin
  if Length(separators) = 0 then
    strings.Text := line else
  begin
    strings.Clear;
    iStart := 1;
    iSep := 0;
    while iStart <= Length(line) do
    begin
      if iSep < Length(separators)
        then iPos := PosEx(separators[iSep], line, iStart)
        else iPos := 0;
      if iPos = 0 then
      begin
        strings.Add(Trim(Copy(line, iStart, MaxInt)));
        iStart := Succ(Length(line));
      end else
      begin
        strings.Add(Trim(Copy(line, iStart, iPos - iStart)));
        iStart := iPos + Length(separators[iSep]);
        iSep := Succ(iSep);
      end;
    end;
  end;
end;

procedure TDemoForm.TestButtonClick(Sender: TObject);
begin
  Split(
    'von Kalkreuth   Elfi   Bad Salzuflen    An der Burg    42  [phone]',
    ['   ', '   ', '    ', '    ', '  '],
    Memo.Lines
  );
end;

Deine Funktion Split() macht etwas ganz anderes. Wenn du ein Problem nicht zweifelsfrei beschreiben kannst, dann sind repräsentative Daten oft sehr hilfreich.

Die von dir beschriebenen Trenner bergen die Gefahr, dass sie auch als Bestandteil eines Substring auftreten können, wenn keine Vorkehrungen getroffen werden, die das verhindern. Dieses Problem wird beim Format Comma Separated Values (CSV) u.a. durch Einführung eines Feldbegrenzungszeichens gelöst.

Grüße vom marabu

[S20000]

Hallo marabu,

danke für deine Erklärung.
Ich werde mir angewöhnen die Aufgabenstellung
klarer zu spezifizieren. (bin noch Einsteiger)

Das von dir beschriebene Problemstatement müßte noch
ergänzt werden. Mein Ziel ist es, jede Zeile
in einem Record zu speichern.

"von Kalkreuth Elfi Bad Salzuflen An der Burg 42 [phone]" würde
dann Person1.Nachname, Person1.Name, Person1.Wohnort, Person1.....
entsprechen.

Mit dem aufsplitten des Textes wollte ich mir das Erstellen der
Records vereinfachen.

Gruß
Sebastian

[marabu]

Hallo Sebastian,

Zitat von S20000:

... Ich werde mir angewöhnen die Aufgabenstellung klarer zu spezifizieren. (bin noch Einsteiger) ...

das wäre schön, wenn man sich das einfach angewöhnen könnte. Ich denke, es hat eher etwas mit Erfahrung (nicht nur im IT-Bereich) zu tun.

Zitat von S20000:

... Das von dir beschriebene Problemstatement müßte noch ergänzt werden. Mein Ziel ist es, jede Zeile in einem Record zu speichern. ...

Die Zerlegung eines Strings anhand eines Musters ist ein in sich abgeschlossenes Problem. Was du mit den auf diese Weise gewonnenen Substrings machst steht auf einem ganz anderen Blatt.

Zitat von S20000:

... Mit dem aufsplitten des Textes wollte ich mir das Erstellen der Records vereinfachen. ...

Deine Entscheidung war goldrichtig, es geht ja garnicht anders.

Freundliche Grüße