Set Property mit Subproperty

[sebi87]

Hallo Leute.

Weiß jemand von euch wie ich den Setter einer Property beim ändern einer Subproperty dieser Property auslösen kann?

Ich kann mir vorstellen das das mit Messages geht, weiß aber nicht wie.


Danke


Sebastian

[tomsel]

Mir sagt der Begriff "Subproperty" nix.

Und im Allgemeinen kann man Setter direkt aufrufen oder der entsprechenden Property einen Wert zuweisen.
Verstehe ich das Problem etwa falsch oder gar nicht?

[Jens Schumann]

Hallo,
ich vermute mal, das mit Subproperty eine Object gemeint ist.
Wenn eine Object Eigenschaft des "SubObjects" geändert wird,
soll in dem "Mutterobject" darauf reagiert werden.
Dafür lassen sich Events verwenden.

In dem Beispiel ist nur das nötigste wiedergegeben.
In TMyComp kann über das OnChange Event von TSub
auf die Änderung von TSub.Text reagiert werden.

Delphi-Quellcode:

Type

  TSub = class(TPersistent)
  private
    FOnChange: TNotifyEvent;
    FText: String;
    procedure SetText(const Value: String);
  protected
    procedure Change; virtual;
  public
    property OnChange : TNotifyEvent read FOnChange write FOnChange;
  published
    property Text     : String read FText write SetText;
  end;

  TMyComp = class(TComponent)
  private
    FSub : TSub;
    procedure SubChange(Sender : TObject);
  published
    constructor Create(AOwner : TComponent); override;
    property Sub : TSub read FSub;
  end;

implementation

{ TSub }

procedure TSub.Change;
begin
  If Assigned(FOnChange) then
    FOnChange(Self);
end;

procedure TSub.SetText(const Value: String);
begin
  FText:=Value;
  Change;
end;

{ TMyComp }

constructor TMyComp.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FSub:=TSub.Create;
  FSub.OnChange:=SubChange;
end;

procedure TMyComp.SubChange(Sender: TObject);
begin
  // Hier kann auf die Änderung der "Subproperty"
  // reagiert werden
end;

end.

[tomsel]

Ah, möglich. Der Suchbegriff "Callback" wäre da anzuraten.

[sebi87]

Danke mal für die Antworten, mit "Subproperty" meinte ich das ich als property ein Objetkt benutze.

z.B. Font also Property mit Color, Style, etc als "Subproperty".

[sebi87]

Vielen Dank für die schnellen Antworten.

Funktioniert jetzt ohne Probleme.


Danke

[himitsu]

statt 'ner CallBack-Funktion zum übergeordnetem Objekt, könnte man auch eine referenz auf dieses Objekt im SubObjekt hinterlassen und hatt dann ebenfalls Zugriff und kann somit über änderungen informieren.

z.B.:

> Parent/AOwner bei Create übergeben

Delphi-Quellcode:

Type

  TMyComp = class;  // forward

  TSub = class(TPersistent)
  private
    FParent: TMyComp;
    FText: String;
    procedure SetText(const Value: String);
  published
    constructor Create(AOwner : TMyComp); override;
    property Text : String read FText write SetText;
  end;

  TMyComp = class(TComponent)
  private
    FSub : TSub;
    procedure SubChange(Sender : TSub);
  published
    constructor Create(AOwner : TComponent); override;
    property Sub : TSub read FSub;
  end;

implementation

{ TSub }

constructor TMyComp.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FParent := AOwner;
end;

procedure TSub.SetText(const Value: String);
begin
  FText := Value;
  FParent.SubChange(Self);
end;

{ TMyComp }

constructor TMyComp.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FSub := TSub.Create(Self);
end;

procedure TMyComp.SubChange(Sender: TSub);
begin
  // Hier kann auf die Änderung der "Subproperty"
  // reagiert werden
end;

> Parent/AOwner von diesem übergeben (nach dem Erstellen)

Delphi-Quellcode:

Type

  TMyComp = class;  // forward

  TSub = class(TPersistent)
  private
    FParent: TMyComp;
    FText: String;
    procedure SetText(const Value: String);
  published
    property Text : String read FText write SetText;
  end;

  TMyComp = class(TComponent)
  private
    FSub : TSub;
    procedure SubChange(Sender : TSub);
  published
    constructor Create(AOwner : TComponent); override;
    property Sub : TSub read FSub;
  end;

implementation

{ TSub }

procedure TSub.SetText(const Value: String);
begin
  FText := Value;
  FParent.SubChange(Self);
end;

{ TMyComp }

constructor TMyComp.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FSub := TSub.Create;
  FSub.FParent := Self;
end;

procedure TMyComp.SubChange(Sender: TSub);
begin
  // Hier kann auf die Änderung der "Subproperty"
  // reagiert werden
end;

!! nur so dahingeschieben = ungetestet