Taskmanager ListView auslesen

[Neutral General]

Hi,

Ich versuche gerade den Text des markierte Items in der Prozess-ListView im Taskmanager zu erhalten.
Folgendes Vorgehen funktioniert auch im Explorer bei markierten Dateien. Wenn ich das hier ausführe, dann stürzt der Taskmanager ab.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var wnd,Button,ListView: hwnd;
    Item: TLVItemA;
    Buffer: PChar;
    Index: Integer;
begin
  wnd := FindWindow('#32770',nil);
  wnd := FindWindowEx(wnd,0,'#32770',nil);
  ListView := FindWindowEx(wnd,0,'SysListView32',nil);
  if ListView <> 0 then
  begin
    GetMem(Buffer,255);
    Index := SendMessage(ListView,LVM_GETSELECTIONMARK, 0, 0);
    with Item do
    begin
      mask := LVIF_TEXT;
      iItem := Index;
      iSubItem := 0;
      pszText := Buffer;
      cchTextMax := 256;
    end;
    ListView_GetItem(Listview,Item);
    ShowMessage(Buffer);
  end;
end;

Also die Handles stimmen. Ich kann sogar die Schrift und Hintergrundfarbe des Listviews ändern aber bei

ListView_GetItem(Listview,Item); stürzt mein Taskmanager immer ab

PS: @toms: Dein Winspy hat mir keinen funktionierenden Code ausgespuckt für die ListView!

Delphi-Quellcode:

var
  wnd: HWND;
begin
  wnd := FindWindow('#32770','');
  // da fehlt:
  // wnd := FindWindowEx(wnd,0,'#32770',nil);
  wnd := FindWindowEx(wnd, 0, 'SysListView32', nil);
  if wnd <> 0 then
  begin
   //  ShowMessage('Window found. Handle: ' + IntToStr(wnd));
     writeln('Window found. Handle: ' + IntToStr(wnd));
     FlashWindow(wnd);
  end;
end.

Gruß
Neutral General

[toms]

Zitat:

PS: @toms: Dein Winspy hat mir keinen funktionierenden Code ausgespuckt für die ListView!

Stimmt. Der alte WinSpy erzeugt den Code nicht korrekt.
Ein etwas abgeänderter Code von WinSpy 2008 (Download noch nicht verfügbar)

Delphi-Quellcode:

var
  wndTaskManager, wnd: HWND;
begin
  wndTaskManager := FindWindow('#32770','Windows Task Manager');
  if wndTaskManager <> 0 then
  begin
   wnd := FindWindowEx(wndTaskManager, 0, '#32770', nil);
   wnd := FindWindowEx(wnd, 0, 'SysListView32', nil);
   if wnd <> 0 then
   begin
      // ShowMessage('Window found. Handle: ' + IntToStr(wnd));
      writeln('Window found. Handle: ' + IntToStr(wnd));
      FlashControl(wnd); // internal function
   end;
  end;
end.

Zitat:

Ich versuche gerade den Text des markierte Items in der Prozess-ListView im Taskmanager zu erhalten.

Siehe http://www.delphipraxis.net/internal...ct.php?t=55569

[Neutral General]

Hi toms,

Danke für den Link. Und danke Luckie das du deine Luckie Dips OpenSource gestellt hast
Ich hab geguckt wies da gemacht wurde und hab mal PI x Daume versucht es hinzubekommen und hatte schon damit gerechnet das mir bei meinem ganzen gepointere mein PC um die Ohren fliegt wenn ich den Code teste, aber er hat auf Anhieb funktioniert !

Hier ist mal der Code (als allgemeine Funktion hingebogen)

Delphi-Quellcode:

// Index = -1 für das momentan selektierte Item übergeben
function GetTaskManagerItemText(Index: Integer = -1): String;
var wnd1,wnd2,ListView: hwnd;
    ItemLoc,ItemGlob: PLVItemA;
    pid: Cardinal;
    hProc: THandle;
    Buffer: Array[0..255] of Char;
    bw: Cardinal;
begin 
  Result := '[Error]';
  wnd1 := FindWindow('#32770',nil);
  wnd2 := FindWindowEx(wnd1,0,'#32770',nil);
  ListView := FindWindowEx(wnd2,0,'SysListView32',nil);
  if ListView <> 0 then
  begin
    GetWindowThreadProcessID(wnd1,pid);
    hProc := OpenProcess(PROCESS_VM_OPERATION or PROCESS_VM_READ or PROCESS_VM_WRITE,
                         false,pid);
    if hProc <> 0 then
    begin
      ItemLoc := VirtualAlloc(nil,SizeOf(TLVItemA),MEM_RESERVE or MEM_COMMIT,
                              PAGE_READWRITE);
      ItemGlob := VirtualAllocEx(hProc,nil,SizeOf(TLVITemA)+SizeOf(Buffer),
                                 MEM_RESERVE or MEM_COMMIT, PAGE_READWRITE);
    end
    else 
      exit;

    try
      if Index = -1 then
        Index := SendMessage(ListView,LVM_GETSELECTIONMARK, 0, 0);

      with ItemLoc^ do
      begin
        mask := LVIF_TEXT;
        iItem := Index;
        iSubItem := 0;
        pszText := PChar(Cardinal(ItemGlob)+SizeOf(TLVItemA));
        cchTextMax := SizeOf(Buffer);
      end;

      WriteProcessMemory(hProc,ItemGlob,ItemLoc,SizeOf(TLVITemA),bw);
      ListView_GetItem(Listview,ItemGlob^);
      ReadProcessMemory(hProc,Pointer(Cardinal(ItemGlob)+SizeOf(TLVItemA)),
                        @Buffer[0],SizeOf(Buffer),bw);
      Result := Buffer;
    finally
      VirtualFreeEx(hProc,ItemGlob,SizeOf(TLVITemA)+SizeOf(Buffer),MEM_RELEASE);
      VirtualFree(ItemLoc,SizeOf(TLVItemA),MEM_RELEASE);
      CloseHandle(hProc);
    end;
  end;
end;

Danke euch beiden

Nur das kleine Problem was ich noch habe: AntiVir(-Guard) erkennt mein Programm jetzt als Virus -.- (TR/Spy.Gen' [TR/Spy.Gen])
Kann man da was gegen tun?

Gruß
Neutral General

[toms]

Witzig ist dieBeschreibung der Auswirkungen von TR/Spy.Gen - Trojan:

Zitat:

Stiehlt Informationen

Ich habe eine Testexe mit deinem Code bei VirusTotal testen lassen.

Ergebnis: Nur ein Virusscanner (Panda) von 32 meldete meldete "Suspicious file"

[Neutral General]

Mh komisch. Vielleicht weil irgendwie der Debugger auch noch aktiv war und keine Ahnung. Also das AntiVir meines Vaters hat auch nicht angeschlagen..

Naja nochmal danke euch beiden

Gruß
Neutral General

[Die Muhkuh]

Zitat von Neutral General:

Mh komisch. Vielleicht weil irgendwie der Debugger auch noch aktiv war und keine Ahnung. Also das AntiVir meines Vaters hat auch nicht angeschlagen..

Meiner auch nicht.

[DeepCopy]

Hallo DP'ler

ich habe den Code von NeutralGeneral in meinem Programm funktionsfähig eingebaut, den Code und das Systemschema der getrennten Prozessverwaltung auch verstanden, aber wie erhalte ich den Text aller anderen Spalten des ListViews ?

Ich will z.B. alle Spalten des TaskManagers im Prozesse-Tab auslesen, dafür bietet die Struktur PLVItemA eine Eigenschaft mit dem Namen iSubItem das die Spalte bezeichnet (zero-based), doch woher bekomme ich die genaue Anzahl der Subitems? Eine Konstante mit dem Namen LVM_GETSUBITEMCOUNT o.ä. konnte ich nirgend wo finden, oder soll ich einfach mit try except eine schleife bauen?

Ich danke euch schon mal im voraus.

[toms]

Du könntest via ListView_GetColumn() die Anzahl Spalten herausfinden und dann so vorgehen, wie
in ForeignListViewToStream

[DeepCopy]

@toms

Vielen Dank!
Das werde ich mir gleich durcharbeiten!

[Daniel Schuhmann]

Bissel OT, aber...

wnd := FindWindow('#32770',nil); Vorsicht! Der Klassenname #32770 ist kein spezieller für den Taskmanager, sondern den bekommt JEDER vordefinierte Dialog, der über den Dialogmanager erzeugt wird. Einfach mal WinVer starten und überprüfen.

Wenn der Code so auf Anhieb funktioniert, war's einfach nur Glück. Zweckmäßig ist es, den Fenstertitel oder die zugrunde liegende Exe-Datei ebenfalls zu prüfen.

Gruß,
Daniel